10 REM-PROGRAM NAME: "EXP016"
20 REM-PROGRAM REMOVES ENCUM BAL FOR P.O.S WHICH ARE INACTIVE
25 OPEN "CR:" FOR INPUT AS FILE 5
30 OPEN "LP:" FOR OUTPUT AS FILE 3
60 OPEN "DF:TRANS.NEW" AS FILE 1
70 DIM #1,S$(1000)=46
80 OPEN "DF:LEDGER.MST" AS FILE 4
90 DIM #4,V$(5000)=61
100 LET X=1: LET J=1
110 INPUT LINE #5, A$
112 ON ERROR GOTO 600 
113 LET Y$=MID(A$,42,7)            !ACCT NO
114 LET Z$=MID(A$,3,4): LET W$=Y$+Z$
115 LET B$=S$(J)
116 LET C$=V$(X)
117 IF MID(A$,80,1)<>"0" GOTO 280
120 IF W$>MID(B$,1,11) GOTO 300
130 IF W$<MID(B$,1,11) GOTO 350
140 IF MID(B$,1,7)>MID(C$,1,7) GOTO 400
150 IF MID(B$,1,7)<MID(C$,1,7) GOTO 450
160 LET X3$=MID(B$,28,7): LET R$=MID(B$,46,1)
170 LET H$=MID(C$,53,9)
180 LET R1$=MID(B$,1,45)
190 LET R$="8"
200 IF H$="000000000" GOTO 250
205 LET H=VAL(H$)
210 LET X3=VAL(X3$)
220 IF X3>H GOTO 270
230 LET H=H-X3            !REDUCE ENCUMBERENCE
240LET T$=NUM$(H)
245 GOSUB 500
247 LET H$=SPACE$(M)+X1$
248 LET C$=MID(C$,1,52)+H$
249 LET V$(X)=C$
250 LET S$(J)=R1$+R$
260 GOTO 110
270 LET H$="000000000"
275 GOTO 248
280 PRINT "CARD IS NOT A P.O. -";A$
290 GOTO 110
300 LET J=J+1: LET B$=S$(J)
310 GOTO 120
350 PRINT #3,"TRANSACTION CANNOT BE FOUND FOR ";A$
360 GOTO 110
400 LET X=X+1: LET C$=V$(X)
410 GOTO 140
450 PRINT #3,"LEDGER MASTER CANT BE FOUND FOR ";B$
460 GOTO 110
500 LET A=LEN(T$)
510 LET A=A-1
520 LET X1$=MID(T$,1,A)
530 LET M=9-A
540 RETURN
600 IF ERR=11 GOTO 800
610 IF ERR=13 GOTO 750
620 IF ERR=14 GOTO 750
630 PRINT "ERROR =";ERR
750 STOP
760 GOTO 110
800 CLOSE 1,3,4,5
810 STOP
820 END