10 REM - PROGRAM NAME:"EXP022"
20 REM- CHANGES BUDGET APPROP AMOUNT OF ACCOUNTS
     IN LEDGER FILE
30 ! "C" IN COLUMN 80 CAUSES APPROPRIATION CHANGE
40 ! "R" IN COLUMN 80 CAUSES NAME FIELD CHANGE ALSO.
50 OPEN "CR:" FOR INPUT AS FILE 1
60 OPEN "DF:LEDGER.MST" AS FILE 2
70 DIM #2,B$(1000)=61
80 DIM A(82)
90 OPEN "LP:" FOR OUTPUT AS FILE 3
100 LET X=1
110 LET S=0.0
120 LET Z=0.0
130 INPUT LINE #1, A$
140 ON ERROR GOTO 430
150 LET K=LEN(A$)
160 CHANGE A$ TO A
170 LET A(K)=32
180 LET K=K-1
190 LET A(K)=32           ! BLANK OUT CR
200 CHANGE A TO A$
210 LET W$=MID(A$,5,27)
220 LET X$=MID(A$,42,7)          !GET ACCOUNT NUMBER
230 LET Y$=MID(A$,34,8)          !GET NEW BUDGET FIGURE
240 LET A1$=MID(A$,80,1)
250 LET Z$=B$(X)
260 LET D$=MID(Z$,1,7)
270 LET E$=MID(Z$,8,27)
275 LET F$=MID(Z$,35,9)
280 LET G$=MID(Z$,44,9)         !YTD AMT
290 LET H$=MID(Z$,53,9)         !OUTSTANDING PO
300 IF MID(Z$,1,9)="999999999" THEN GOTO 420
310 IF MID(Z$,1,7)>X$ THEN GOTO 350
320 IF MID(Z$,1,7)=X$ THEN GOTO 370
330 LET X=X+1
340 GOTO 250
350 PRINT "CANNOT FIND MASTER FOR ";X$
360 GOTO 130
370 IF A1$="R" GO TO 400
375 IF A1$="1" GO TO 413
380 LET B$(X)=D$+E$+" "+Y$+G$+H$
390 GOTO 130
400 LET B$(X)=D$+W$+" "+Y$+G$+H$
410 GO TO 130
413 LET B$(X)=D$+E$+F$+" "+Y$+H$
417 GO TO 130
420 GOTO 350
430 IF ERR=11 GOTO 500
440 IF ERR=13 GOTO 480
450 IF ERR=14 GOTO 480
460 PRINT "ERROR =";ERR
470 STOP
480 STOP
490 GOTO 130
500 INPUT "PRINT ACCOUNTS";S0$
505 IF S0$="NO" GO TO 610
507 FOR X=1 TO 1000
510 LET Z$=B$(X)
520 LET F$=MID(Z$,35,9):LET U=VAL(F$):LET U=U/100
530 LET Z=Z+U:  LET Y$=MID(Z$,44,9)
540 LET T=VAL(Y$): LET T=T/100
550 LET S=S+T
560 IF MID(Z$,1,9)="999999999" THEN 590
570 PRINT #3,B$(X)
580 NEXT X
590 PRINT #3,USING"TOTAL YTD = ##,###,###.##",S
600 PRINT #3,USING "TOTAL APPROP= ##,###,###.##",Z
610 CLOSE 1,2,3
620 STOP
630 END