10 REM- PROGRAM NAME:"EXP030"
20 REM- PROGRAM CREATES MASTER EMPLOYEE FILE
30 OPEN "CR:" FOR INPUT AS FILE 1
35 FIELD #1, 80 AS A$
40 OPEN "DF:EMPLOY.MST" AS FILE 2
45 DIM #2,E$(500)=255
55 LET H$="0000000"
60 LET J0$="0000000"
70 LET K$="0000000"
80 LET M0$=SPACE$(35)
90 LET N0$=SPACE$(32)
100 LET O0$=SPACE$(42)
110 LET P$="00"
120 LET Q$="000"
130 LET R0$=SPACE$(38)
140 LET S0$=SPACE$(39)
150 LET T$=SPACE$(20)
151 LET X%=1: LET X1%=1
152 GET #1
161 ON ERROR GOTO 600
162 LET R1$=SPACE$(7): LET R2$="0000000"
163 LET R3$="00000"
164 LET S1$=SPACE$(7): LET S2$="0000000"
165 LET S3$="00000"
166 LET T1$=SPACE$(7): LET T2$="0000000"
167 LET T3$="00000"
168 LET U$=SPACE$(19)
170 LET I$=MID(A$,79,2)
180 LET F$=LEFT(A$,6)
181 LET F1$=MID(A$,4,3)
190 LET G$=MID(A$,7,15)       !EMPLOYEE NAME
200 LET L1$=MID(A$,29,6)      !GROSS CURRENT PAY
210 LET L2$=MID(A$,36,5)      !FED INCOME TAX
220 LET L3$=MID(A$,41,5)      !VT STATE TAX
225 LET L4$=MID(A$,46,5)       !FICA
227 GET #1                     !VOL DEDUCT CARD
228 LET M1$=MID(A$,36,5)       !HOSP BLDG FUND
229 LET M2$=MID(A$,41,5)       !ANNUITY
230 LET M3$=MID(A$,46,5)       !C U
231 LET M4$=MID(A$,51,5)       !RETIREMENT
232 LET M5$=MID(A$,57,5)       !WASH NAT
233 LET M6$=MID(A$,62,5)       !BC/BS
234 LET M7$=MID(A$,30,5)       !MISC
235 LET M0$=M1$+M2$+M3$+M4$+M5$+M6$+M7$
240 GET #1                     !ACCOUNT DISTRIB ACCT
250 IF MID(A$,4,3)<>F1$ GOTO 500
270 IF T1$=SPACE$(7) GOTO 350
290 PRINT "MORE THAN 3 ACCOUNTS FOR EMPLOYEE #";F$
300 GOTO 240
350 IF R1$<>SPACE$(7) GOTO 390
360 LET R1$=MID(A$,42,6)+" "   !ACCOUNT #
370 LET R3$=MID(A$,37,5)       !GROSS CURRENT AMOUNT
380 GOTO 240
390 IF S1$<>SPACE$(7) GOTO 450
400 LET S1$=MID(A$,42,6)+" "   !ACCOUNT #
410 LET S3$=MID(A$,37,5)       !GROSS CURRENT AMT
420 GOTO 240
450 LET T1$=MID(A$,42,6)+" "   !ACCOUNT #
460 LET T3$=MID(A$,37,5)       !GROSS CURRENT AMOUNT
470 GOTO 240
500 LET L1=VAL(L1$)+VAL(R2$)+VAL(S2$)+VAL(T2$)
510 LET T$=NUM$(L1)
520 GOSUB 1200
530 LET L1$=SPACE$(M)+X1$
540 GOTO 800
600 IF ERR=14 GOTO 630
610 IF ERR<>11 GOTO 900
611 LET E$(X1%)="999999"+SPACE$(249)   !EOF RECORD
623 CLOSE 1,2
625 STOP
630 SLEEP(15)
640 RESUME
800 LET L$=L1$+L2$+L3$+L4$
805 LET R$=R1$+R2$+R3$
806 LET S$=S1$+S2$+S3$
807 LET T$=T1$+T2$+T3$
809 LET E$(X1%)=F$+G$+H$+I$+J0$+K$+L$+M0$+N0$+O0$+
     P$+Q$+R$+S$+T$+U$
811 LET X1%=X1%+1
816 IF ERR =11 GOTO 623 
820 GOTO 162
900 PRINT "ERROR ="; ERR
910 STOP
1200 LET A=LEN(T$)
1210 LET A=A-1
1220 LET X1$=MID(T$,1,A)
1230 LET M=6-A
1240 RETURN 
1250 END