10 REM- PROGRAM NAME"EXP043"
20 REM-PROGRAM ADDS NEW EMPLOYEES TO MASTER FILE
35 OPEN "DT1:EMPLOY.TMP" FOR OUTPUT AS FILE 4
40 OPEN "DF:EMPLOY.MST" AS FILE 2
50 DIM #2,E$(500)=256
55 OPEN "CR:" FOR INPUT AS FILE 3
56 FIELD #3, 80 AS F$
125 LET X%=1
135 ON ERROR GOTO 700
140 GOSUB 910
150 FOR N%=0 TO 255 STEP 255
153 FIELD #4, N% AS Z$, 255 AS C2$
155 IF E=1 GOTO 300
170 IF G$>MID(E$(X%),4,3) GOTO 300
180 IF G$<MID(E$(X%),4,3) GOTO 400
190 LSET C2$=MID(E$(X%),1,30)+J1$+J2$+J3$+
     MID(E$(X%),38,33)+M2$+M3$+MID(E$(X%),81,10)+
     M6$+MID(E$(X%),96,160)
195 GOSUB 910
200 GOTO 310
300 LSET C2$=E$(X%)
305 IF LEFT(E$(X%),6)="999999"GOTO 1010
310 LET X%=X%+1
320 NEXT N%
330 PUT #4
340 GOTO 150
342 INPUT "ENTER IF HOURLY(02) OR SALARY(01)";I$
343 GOTO 440
400 LET F1$=MID(F$,1,6)
410 LET G1$=MID(F$,7,15)
420 LET H$="0000000"
430 IF MID(F$,79,2)="  " THEN GOTO 342
435 LET I$=MID(F$,79,2)
440 LSET C2$=F1$+G1$+H$+I$+J1$+J2$+J3$+SPACE$(33)+M2$+M3$+
     SPACE$(10)+M6$+SPACE$(160)
450 GOSUB 910
460 GOTO 320
700 IF ERR=11 GO TO 708
701 IF ERR=14 GOTO 706
702 PRINT "ERROR =";ERR
703 STOP
706 SLEEP(2)
707 RESUME
708 LET E=1
710 RESUME 911
910 GET #3
911 IF E=1 GOTO 960
913 LET G$=MID(F$,4,3)
915 LET J1$=MID(F$,22,4)         !GET HOURLY RATE FROM CARD
920 LET J2$=MID(F$,27,2)         !GET # DEPENDENTS
925 LET J3$=MID(F$,26,1)         !GET MARITAL STATUS
930 LET M2$="0"+MID(F$,37,4)     !ANNUITY DEDUCTION
940 LET M3$="0"+MID(F$,33,4)     !CREDIT UNION DEDUCTION
950 LET M6$="0"+MID(F$,29,4)     !GET BLUE CROSS
960 RETURN
1010 PUT #4
1200 CLOSE 4 
1203 LET X%=0
1205 OPEN "DT1:EMPLOY.TMP" FOR INPUT AS FILE 1
1210 GET #1
1220 FOR N%=0 TO 255 STEP 255
1230 FIELD #1, N% AS Z$,255 AS C$
1240 LET X%=X%+1
1250 LET E$(X%)=C$
1260 IF LEFT(C$,6)="999999" GOTO 1290
1270 NEXT N%
1280 GOTO 1210
1290 CLOSE 1,2
1300 END