10 REM- PROGRAM NAME: "EXP048"
20 REM- PROGRAM PRODUCES PAYROLL REGISTER
30 OPEN "LP:" FOR OUTPUT AS FILE 2
40 OPEN "DF:EMPLOY.MST" AS FILE 1
41 DIM #1,E$(500)=255
43 INPUT "ENTER PAY PERIOD";P1$
44 INPUT "ENTER DATE PAID";P2$
45 INPUT "ENTER STARTING CHECK #";C9$
46 LET C9$=" "+C9$+" "
47 INPUT "SALARY OR HOURLY";E3$
51 PRINT #2, SPACE$(20)+"NORTH COUNTRY UNION HIGH SCHOOL"
52 PRINT #2, SPACE$(28)+"PAYROLL REGISTER"
54 PRINT #2, "PAY PERIOD: "+P1$+SPACE$(37)+
     "DATE PAID: "+P2$
55 PRINT #2, SPACE$(78)
56 PRINT #2, SPACE$(26)+"HOURS"+SPACE$(19)+"STATE "+
     "FEDERAL"
57 PRINT #2, "IDENT      NAME         REG  OVER   GROSS  "+
     "FICA    TAX    TAX"+SPACE$(13)+"NET"
58 PRINT #2,SPACE$(21)+"-----------------";
59 PRINT #2,"--------------------------------------"
60 PRINT #2, SPACE$(21);
61 PRINT #2,
  "ANNUITY  C.U. HOS-BLD RETIR WASH-NA BC/BS  MISC      NET"
62 PRINT #2, SPACE$(78)
63 FOR J%=1 TO 500
70 LET E1$=E$(J%)
80 IF LEFT(E1$,6)="999999" GOTO 805
90 IF MID(E1$,29,1)<>"1" GOTO 800
95 PRINT #2, LEFT(E1$,6)+" "+MID(E1$,7,15);
98 LET L1=VAL(MID(E1$,45,6))/100    !GROSS PAY
100 LET L4=VAL(MID(E1$,61,5))/100   !FICA
103 LET L2=VAL(MID(E1$,51,5))/100   !FEDERAL TAX
105 LET L3=VAL(MID(E1$,56,5))/100   !STATE TAX
110 LET L5=L1-(L2+L3+L4)            !FIRST NET
120 LET H1=VAL(MID(E1$,237,3))/10   ! # REG HOURS
121 LET H2=VAL(MID(E1$,240,3))/10   ! # OVERTIME HOURS
130 PRINT #2,
USING"###.#  ###.#  ####.## ###.## ###.## ###.##      ####.##",
   H1,H2,L1,L4,L3,L2,L5
131 LET X1=X1+L1               !TOTAL GROSS PAY
132 LET X4=X4+L4               !TOTAL FICA DEDUCTIONS
133 LET X3=X3+L3               !TOTAL STATE TAX DED
134 LET X2=X2+L2               !TOTAL FED TAX DEDUCTIONS
135 LET X5=X5+L5               !TOTAL FIRST NET PAY
137 IF MID(E1$,30,1)="1" AND E3$="HOURLY" GO TO 410
140 LET M2=VAL(MID(E1$,71,5))/100   !ANNUITY
145 LET M6=VAL(MID(E1$,91,5))/100   !BC/BS
150 LET M1=VAL(MID(E1$,66,5))/100   !HOSP-BLDG FUND
160 LET M4=VAL(MID(E1$,81,5))/100   !RETIREMENT
170 LET M5=VAL(MID(E1$,86,5))/100   !WASH NATNL
180 LET M3=VAL(MID(E1$,76,5))/100   !CREDIT UNION
190 LET M7=VAL(MID(E1$,96,5))/100   !MISC
200 LET P9=L5-(M1+M2+M3+M4+M5+M6+M7)
210 PRINT #2,"  CK # "+C9$+SPACE$(7);
220 PRINT #2,
 USING"###.## ###.## ###.## ###.## ###.## ###.## ###.##  ####.##",
     M2,M3,M1,M4,M5,M6,M7,P9
225 PRINT #2
270 LET Z9=Z9+P9    !TOTAL SECOND NET
300 LET C9=VAL(C9$)
305 LET C9=C9+1
310 LET C9$=NUM$(C9)
400 GO TO 800
410 LET M1,M2,M3,M4,M5,M6,M7=0
420 GO TO 200
800 NEXT J%
805 PRINT #2, SPACE$(78)
810 PRINT #2,"TOTAL GROSS,FICA,STATE,FED       ";
815 PRINT #2,
 USING"#####.## ####.## ####.## #####.##",X1,X4,X3,X2
820 PRINT #2, USING "TOTAL NET AMT = ###,###.##",Z9
1340 CLOSE 1,2
1350 END