10 REM - PROGRAM NAME: "EXP050"
20 REM - PRODUCES VENDOR CHECKS
30 OPEN "TRANS.NEW" AS FILE 1
40 DIM #1,T1$(1000)=46
50 OPEN "DF:VENDOR" AS FILE 3
60 DIM #3,V$(2000)=118
70 OPEN "LP:" FOR OUTPUT AS FILE 2
80 ON ERROR GOTO 1150
90 INPUT "PRINTER LINED UP" I9$
100 IF I9$="YES" GOTO 130
110 PRINT #2,SPACE$(78)
120 GOTO 90
130 OPEN "DF:CHECKS.VEN" AS FILE 5
131 DIM #5, C9$(1000)=32
132 LET Y%=Y%+1
133 IF LEFT(C9$(Y%),7)="9999999" GOTO 135
134 GOTO 132
135 INPUT "ENTER NUMBER OF STARTING CHECK"; C5$
136 LET C5=VAL(C5$)
137 LET Y%=Y%-1       !TO WRITE OVER "9999999"
138 GOSUB 990
140 FOR X%=1 TO 1000
150 LET A$=T1$(X%)
160 IF MID(A$,42,4)="9999" GOTO 550
170 IF MID(A$,12,1)<>"1" GOTO 540
180 IF MID(A$,46,1)="3" GOTO 540
190 IF U$<>MID(A$,42,4) AND I%<>0 GOTO 560
200 IF Z9=1 GOTO 530
210 LET I%=I%+1
220 LET U$=MID(A$,42,4)             !VENDOR NUMBER
230 FOR J%=1 TO 3000
240 LET V1$=V$(J%)          !GET VENDOR RECORD
250 IF MID(V1$,1,4)="9999" GOTO 510
260 IF U$<>MID(V1$,1,4) GOTO 500
270 LET J$=MID(V1$,1,4)      !VENDOR NUMBER
280 LET K$=MID(V1$,5,21)      !NAME 1
290 LET L$=MID(V1$,26,21)       !NAME 2
300 LET M$=MID(V1$,47,21)       !VENDOR STREET ADDR
310 LET N$=MID(V1$,68,21)       !CITY STATE
320 LET O$=MID(V1$,89,21)
330 LET P$=MID(V1$,110,9)       !YTD TOTAL
340 LET S$=MID(A$,35,7)         !CURRENT INVOICE
350 LET S=S+VAL(S$)             !ADD TO ACCUM 
360 LET D$=MID(A$,13,8)         !INVOICE NUMBER
370 LET D1$=MID(A$,21,2)        !MONTH
380 LET D2$=MID(A$,23,2)        !DAY
390 LET D3$=MID(A$,25,2)        !YEAR
400 LET S1=S1+VAL(S$)
410 LET S2=VAL(S$)
420 LET S2=S2/100
430 PRINT #2,D1$+" "+D2$+" "+D3$+"   "+D$+SPACE$(38);
440 PRINT #2, USING "###,###.##", S2
450 IF MID(A$,46,1)="2" THEN LET X$="8" 
     ELSE LET X$="3"
455 LET T1$(X%)=LEFT(A$,45)+X$
460 LET C%=C%+1
470 IF C%<20 GOTO 540
480 LET Z9=1
490 GOTO 560
500 NEXT J%
510 PRINT "CANNOT FIND VENDOR FOR "; U$
520 LET I%=0
530 LET Z9=0
540 NEXT X%
550 LET E9%=1
560 IF C%=27 GOTO 600
570 PRINT #2,SPACE$(78)
580 LET C%=C%+1
590 GOTO 560
600 PRINT #2,DATE$(0)
610 LET C%=C%+1
620 PRINT #2,SPACE$(78)
630 LET C%=C%+1
640 IF C%<33 GOTO 620
700 LET V$(J%)=J$+K$+L$+M$+N$+O$+P$
710 LET Z$=SPACE$(M)+X1$          !VENDOR AMOUNT
720 LET Y%=Y%+1
721 LET C5$=NUM$(C5)
723 LET C6$=FNK$(S1)
724 LET L%=9-LEN(C6$)
725 LET C9$(Y%)=C5$+" "+U$+" "+SPACE$(L%)+C6$+DATE$(0)+"0"
726 LET C5=C5+1
729 LET S1=S1/100
730 PRINT #2,SPACE$(6);K$;SPACE$(28);
740 PRINT #2,USING "$$###,###.##",S1
750 LET C%=C%+1
760 IF L$=SPACE$(21) GOTO 790
770 PRINT #2, SPACE$(6);L$
780 LET C%=C%+1
790 IF M$=SPACE$(21) GOTO 820
800 PRINT #2,SPACE$(6);M$
810 LET C%=C%+1
820 IF N$=SPACE$(21) GOTO 850
830 PRINT #2, SPACE$(6);N$
840 LET C%=C%+1
850 IF O$=SPACE$(21) GOTO 880
860 PRINT #2, SPACE$(6);O$
870 LET C%=C%+1
880 LET S3=S3+S1
890 IF E9%=1 GOTO 1110
900 LET S1=0
910 IF C%=42 GOTO 950
920 PRINT #2,SPACE$(78)
930 LET C%=C%+1
940 GOTO 910
950 GOSUB 990
960 GOTO 200
970 PRINT #2,SPACE$(6);O$
980 GOTO 840
990 PRINT #2,SPACE$(78)
1000 PRINT #2, SPACE$(78)
1010 PRINT #2,SPACE$(78)
1020 PRINT #2,SPACE$(78)
1030 LET C%=4
1040 RETURN
1050 REM - SUBROUTINE TO FORMAT RESULT OF NUM$
1060 LET A=LEN(T$)
1070 LET A=A-1
1080 LET X1$=MID(T$,1,A)
1090 LET M=9-A
1100 RETURN
1110 PRINT "TOTAL AMOUNT PAID BY CHECKS=";
1120 PRINT USING "$$###,###.##",S3
1125 LET Y%=Y%+1
1126 LET C9$(Y%)="9999999"+SPACE$(24)
1130 CLOSE 1,2,3,5
1140 STOP
1150 SLEEP(10)
1160 RESUME
1200 DEF FNK$(S7)
1210 LET S6=INT(S7/1000)
1220 LET S5=S7-S6*1000
1230 LET S6$=NUM$(S6)
1240 LET S5$=NUM$(S5)
1250 LET S5$=MID(S5$,2,LEN(S5$)-1)
1260 IF LEN(S5$)=4 GO TO 1290
1270 LET S5$="0"+S5$
1280 GO TO 1260
1290 LET FNK$=LEFT(S6$,LEN(S6$)-1)+S5$
1300 FNEND
1310 END