05 REM-PROGRAM NAME:"EXP095"
06 REM- PROGRAM PRINTS "W2" FORMS
10 OPEN "DF:EMPLOY.MST" AS FILE 1
20 DIM #1, E1$(600)=255
30 OPEN "LP:" FOR OUTPUT AS FILE 2
35 OPEN "CR:" FOR INPUT AS FILE 3
37 FIELD #3, 80 AS C$
38 ON ERROR GOTO 400
40 INPUT "PRINTER LINED UP";I$
50 IF I$="YES" GOTO 75
60 PRINT #2, SPACE$(78)
70 GOTO 40
75 LET J%=1
78 GET#3
80 FOR C%=1 TO 10
90 PRINT #2, SPACE$(78)
100 NEXT C%
120 LET E$=E1$(J%)
121 IF LEFT(E$,6)="999999" GOTO 500
125 IF VAL(MID(E$,101,7))=0 GOTO 370
130 IF MID(E$,4,3)>MID(C$,4,3) THEN GOTO 300
140 IF MID(E$,4,3)<MID(C$,4,3) THEN GOTO 350
150 LET F=VAL(MID(E$,115,6))/100
151 LET W1=VAL(MID(E$,101,7))/100
152 LET W=(VAL(MID(E$,101,7))-VAL(MID(E$,139,6)))/100
155 LET S=VAL(MID(E$,127,6))/100  !FICA
157 LET V=VAL(MID(E$,121,6))/100   !STATE TAX
159 IF W>10800 THEN LET S1=10800 ELSE LET S1=W
160 PRINT#2, USING
   " ######.##  ######.##  ###.##  #####.##  #####.##  #####.##  VERMONT",
   F,W,S,S1,V,W
165 LET F1=F1+F: W2=W2+W: S2=S2+S: V1=V1+V
167 LET D7%=D7%+1
170 PRINT#2, SPACE$(18)+MID(E$,243,3)+" "+MID(E$,246,2)+" "+MID(E$,248,4)
180 PRINT#2, SPACE$(78): PRINT#2, SPACE$(78)
185 LET K%=1
190 PRINT#2, "   "+MID(C$,7,25);
200 IF K%=3 GOTO 250
205 PRINT#2
210 IF MID(C$,80,1)="5" GOTO 270
220 LET K%=K%+1
230 GET#3
240 GOTO 190
250 IF MID(E$,37,1)="S" THEN LET M$="1"
252 IF MID(E$,37,1)="M" THEN LET M$="2"
254 IF MID(E$,37,1)<>"M" AND MID(E$,37,1)<>"S" THEN LET M$=LEFT(E$,1)
260 PRINT#2, "     "+M$
265 GOTO 210
270 LET K%=K%+1
271 IF K%=3 THEN PRINT#2, SPACE$(28);
272 IF K%=3 GOTO 250
275 PRINT#2, SPACE$(78)
280 IF K%>=7 GOTO 360
285 GOTO 270
300 GET #3
305 GOTO 130
350 PRINT "CANNOT FIND ADDRESS CARD FOR "; MID(E$,7,15)
355 STOP
360 LET J%=J%+1
362 GET#3
363 GOTO 80
370 LET J%=J%+1
380 GOTO 120
400 IF ERR=13 OR ERR=14 GOTO 450
405 IF ERR=11 GO TO 500
410 PRINT "ERR=";ERR
411 STOP
450 SLEEP(5)
455 RESUME
500 CLOSE 1,2,3
501 PRINT USING 'TOTAL "NET" GROSS #,###,###.##',W2
503 PRINT USING "TOTAL FEDERAL TAX   ###,###.##",F1
505 PRINT USING "TOTAL STATE TAX     ###,###.##",V1
507 PRINT USING "TOTAL FICA          ###,###.##",S2
509 PRINT USING "TOTAL W2'S WRITTEN      ##,###",D7%
510 END