10 OPEN "CR:" AS FILE 1
20 FIELD#1, 80 AS C$
30 OPEN "LP:" AS FILE 2
40 OPEN "DF:TEACHR.MST" AS FILE 3
50 DIM#3, T1$(150)=12
60 OPEN "DF:SCHED.MST" AS FILE 4
70 DIM#4, S1$(150)=255
80 OPEN "DF:STUDYH.MST" AS FILE 5
90 DIM#5, H1$(22)=46
100 ON ERROR GO TO 580
110 GET#1
120 IF MID(C$,80,1)="9" GO TO 150
130 GO TO 320
140 PRINT "INVALID CODE IN COLUMN 80": STOP
150 LET I$=MID(C$,1,5)                !ID #
160 LET J$=MID(C$,6,25)               !NAME
170 LET K$=MID(C$,31,4)               !COURSE #
180 LET L$=MID(C$,36,2)               !MOD
190 LET M$=MID(C$,38,20)              !COURSE NAME
200 LET N$=MID(C$,58,2)               !TEACHER #
210 LET N=VAL(RIGHT(N$,2))
220 IF LEFT(N$,1)<="9" GO TO 250
230 LET N=N+(100+(ASCII(LEFT(N$,1))-65)*10)
240 GO TO 260
250 LET N=N+VAL(LEFT(N$,1))*10
260 LET Q$=T1$(N)                     !TEACHER NAME
270 LET S$=S1$(N)
280 LET N1=(VAL(L$)-1)*8+1
290 LET P$=MID(S$,N1,3)              !ROOM #
300 LET O$=MID(S$,N1+3,5)             !DAYS
310 GO TO 450
320 LET I$=MID(C$,1,5)                !ID#
330 LET J$=MID(C$,6,24)+" "
340 LET K$=MID(C$,32,4)               !COURSE #
350 LET L$=MID(C$,40,2)               !MOD
360 LET O$=MID(C$,43,5)               !DAIS
370 LET P$=MID(C$,49,3)              !ROOM
380 LET Q$=MID(C$,55,20)              !TEACHER NAME
390 IF K$="9994"THEN LET M$="LUNCH"+SPACE$(15)
400 IF K$="9995" THEN LET M$="STUDY HALL"+SPACE$(10)
410 IF LEFT(K$,3)="ATT" THEN LET M$="ATTENDANCE MOD"+SPACE$(6)
415 IF LEFT(Q$,1)=" " THEN LET Q$=RIGHT(Q$,2)+" "
420 IF K$<>"9995" GO TO 450
430 LET H$=H1$(VAL(L$))
440 IF P$=LEFT(H$,3) THEN LET Q$=MID(H$,4,20)
     ELSE LET Q$=MID(H$,27,20)
450 IF I$<>I0$ GO TO 490
460 LET Q$=Q$+SPACE$(20-LEN(Q$))
465 PRINT#2," ";
470 PRINT#2, L$+" "+K$+" "+M$+" "+Q$+" "+P$+" "+O$
480 GO TO 110
490 PRINT#2, CHR$(12)
500 LET X=SQR(I) FOR I=1 TO 50        !TIME OUT!!!
510 PRINT#2, SPACE$(20)+"NORTH COUNTRY UNION HIGH SCHOOL"
520 PRINT#2, SPACE$(31)+"SCHEDULE"
530 PRINT#2
540 PRINT#2, I$+" "+J$+SPACE$(15)+"2ND QUARTER 1973-74"
550 PRINT#2
555 PRINT#2, "MOD"+SPACE$(6)+"COURSE"+SPACE$(15)+"TEACHER"+SPACE$(14)+
    "RM  DAYS"
560 LET I0$=I$
570 GO TO 120
580 IF ERR=11 GO TO 640
590 IF ERR=13 OR ERR=14 GO TO 620
600 PRINT USING"ERROR ### AT LINE ###",ERR,ERL
610 GO TO 640
620 SLEEP(2)
630 RESUME
640 CLOSE I FOR I=1 TO 5
650 END