01 ! PROGRAM WRITES LETTER TO PARENTS OF STUDENTS WITH MORE THAN
      TEN CLASS CUTS IN A QUARTER.
10 OPEN "CR:" AS FILE 1
15 FIELD#1, 80 AS C$
20 OPEN "LP:" AS FILE 2
23 OPEN "TEACHR.MST" AS FILE 4
27 DIM#4, T1$(200)=16
30 OPEN "DF:STUDNT.MST" AS FILE 3
35 DIM#3, S1$(500)=510
40 ON ERROR GO TO 830
45 INPUT "WHICH QUARTER";Q
50 GET#1
60 IF LEFT(C$,5)<>I$ GO TO 190
70 LET C1=VAL(MID(C$,68+Q*2,2))
80 IF C1=0 GO TO 50
90 LET I=I+1
100 LET A$(I)=MID(C$,38,20)
110 IF MID(C$,58,1)<="9" GO TO 150
120 IF MID(C$,58,1)="A" THEN LET T=100+VAL(MID(C$,59,1))
130 IF MID(C$,58,1)="B" THEN LET T=110+VAL(MID(C$,59,1))
140 GO TO 160
150 LET T=VAL(MID(C$,58,2))
160 LET T$(I)=T1$(T)
170 LET C(I)=C1
180 GO TO 50
190 IF E1=1 GO TO 196
192 LET E1=1
194 GO TO 800
196 LET S=0
199 FOR J=1 TO I
200 LET S=S+C(J)
210 NEXT J
220 IF S<10 GO TO 800
230 PRINT#2, CHR$(12)
240 LET M$=SPACE$(0)
250 LET M$=M$+"XX" FOR J=1 TO 20
260 PRINT#2, SPACE$(25)+"NORTH COUNTRY UNION HIGH SCHOOL"
270 PRINT#2
280 PRINT#2, SPACE$(32)+"VETERANS AVENUE"
290 PRINT#2, SPACE$(32)+"NEWPORT, VERMONT"
300 PRINT#2, SPACE$(36)+DATE$(0)
310 PRINT#2: PRINT#2
330 LET Z=Z+1
340 LET S$=S1$(Z)
350 IF LEFT(S$,5)="99999" GO TO 380
360 IF LEFT(S$,5)=I$ GO TO 400
370 GO TO 330
380 PRINT "CAN'T FIND MASTER FOR "+I$
385 LET Z=0
390 GO TO 800
400 IF MID(S$,85,20)<>SPACE$(20) GO TO 408
402 PRINT#2, "TO THE PARENT OF:"
404 PRINT#2, MID(S$,6,25)
406 GO TO 410
408 PRINT#2, MID(S$,85,20)
410 PRINT#2, MID(S$,31,20)
420 PRINT#2, MID(S$,51,20)
430 PRINT#2: PRINT#2
440 PRINT#2, "DEAR PARENT,"
460 IF MID(S$,79,1)="M" THEN LET S1$="SON'S" ELSE LET S1$="DAUGHTER'S"
470 LET N$=MID(S$,21,10)
480 FOR J=1 TO 10
490 IF MID(N$,J,1)=" " GO TO 510
500 NEXT J
510 LET N$=LEFT(N$,J-1)
520 PRINT#2, "     RECENTLY YOU RECEIVED YOUR "+S1$+" REPORT CARD.  AMONG"
530 PRINT#2, "THE INFORMATION RECORDED ON THIS REPORT WAS THE NUMBER OF CLASS CUTS"
540 PRINT#2, "WHICH WERE UNEXCUSED."
550 PRINT#2
560 PRINT#2, "     WE AT NORTH COUNTRY, WHO ARE DEEPLY CONCERNED WITH "+N$+"'S"
570 PRINT#2, "PERFORMANCE, FEEL THAT THESE CUTS WERE EXCESSIVE AND DETRIMENTAL"
580 PRINT#2, "TO ANY CHANCES OF SUCCESS NOW OR IN THE FUTURE.  WE FEEL TOO"
590 PRINT#2, "THAT SINCE "+N$+" WAS AMONG THAT PERCENTAGE OF OUR STUDENT BODY"
600 PRINT#2, "WHO ARE CONSIDERED SERIOUS CUT PROBLEMS BY THE STAFF YOU SHOULD"
610 PRINT#2, "DISCUSS THIS PROBLEM AT HOME AND TRY TO REMEDY IT."
620 PRINT#2
630 PRINT#2, "     THE CUTS, AS YOU KNOW, WERE AS FOLLOWS:"
640 PRINT#2, "      CLASS"+SPACE$(10)+"TEACHER"+SPACE$(11)+"NUMBER"
650 FOR J=1 TO I
660 PRINT#2, A$(J)+"   "+T$(J)+"        ";
670 PRINT#2, USING "##",C(J)
680 NEXT J
690 PRINT#2
700 PRINT#2, "     AS INDICATED, WE ARE EXTREMELY CONCERNED ABOUT THE"
710 PRINT#2, "FUTURE OF OUR STUDENTS, YET WITHOUT CLOSE PARENTAL SUPPORT AND"
720 PRINT#2, "COOPERATION WE ARE LIMITED IN OUR CHANCES TO SUCCEED.  PLEASE GIVE"
730 PRINT#2, "US YOUR HELP SO THAT "+N$;"'S EDUCATIONAL EXPERIENCE AT NORTH"
740 PRINT#2, "COUNTRY WILL PROVE TO BE BOTH BENEFICIAL AND WORTHWHILE."
750 PRINT#2: PRINT#2
760 PRINT#2, SPACE$(39)+"SINCERELY YOURS,"
770 PRINT#2: PRINT#2
780 PRINT#2, SPACE$(39)+"LEO J. SULLIVAN"
790 PRINT#2, SPACE$(39)+"ASSOCIATE PRINCIPAL"
800 LET I$=LEFT(C$,5)
810 LET I=0
820 GO TO 70
830 IF ERR=11 AND E=1 GO TO 920
840 IF ERR<>11 GOTO 870
850 LET E=1
860 GO TO 190
870 IF ERR=13 OR ERR=14 GO TO 900
880 PRINT USING "ERROR ### AT LINE ###",ERR,ERL
890 STOP
900 SLEEP (2)
910 RESUME
920 CLOSE 1,2,3,4
930 END