10 INPUT "DEV:FILNAM.EXT"; I$
20 OPEN I$ AS FILE 1
25 IF I$="END" GO TO 750
30 FIELD#1, 510 AS S$
40 OPEN "LP:" AS FILE 2
61 DIM U$(19)
62 FOR I=1 TO 19
63 READ U$(I)
64 NEXT I
65 FOR I=2 TO 9
66 READ T$(I)
67 NEXT I
70 GET#1
75 IF LEFT(S$,5)="99999" GO TO 10
80 LET A=VAL(MID(S$,127,2))+VAL(MID(S$,129,2))+VAL(MID(S$,131,2))+
   VAL(MID(S$,133,2))+VAL(MID(S$,135,2))
90 IF A<10 GO TO 70
92 IF MID(S$,146,1)="D" OR MID(S$,146,1)="V" GO TO 70
95 PRINT LEFT(S$,5)
100 PRINT#2, CHR$(12)
110 LET X=SQR(I) FOR I=1 TO 25
120 PRINT#2, SPACE$(23)+"NORTH COUNTRY UNION HIGH SCHOOL"
130 PRINT#2
140 PRINT#2, SPACE$(31)+"VETERANS AVENUE"
150 PRINT#2, SPACE$(31)+"NEWPORT, VERMONT"
160 PRINT#2: PRINT#2
170 IF MID(S$,85,20)<>SPACE$(20) GOTO 210
180 PRINT#2, "TO THE PARENT OF:"
190 PRINT#2, MID(S$,6,25)
200 GO TO 220
210 PRINT#2, MID(S$,85,20)
220 PRINT#2, MID(S$,31,20)
230 PRINT#2, MID(S$,51,20)
240 PRINT#2
250 PRINT#2, "DEAR PARENT,"
260 LET N$=MID(S$,21,9)
270 FOR I=9 TO 1 STEP -1
280 IF MID(N$,I,1)<>" " GO TO 310
290 LET N$=LEFT(N$,I-1)
300 NEXT I
310 IF A>19 GO TO 340
320 LET A$=U$(A)
330 GO TO 400
340 LET A1=INT(A/10)
350 LET A$=T$(A1)
360 LET A2=A-A1*10
370 IF A2=0 GO TO 400
390 LET A$=A$+"-"+U$(A2)
400PRINT#2, "     THIS IS TO INFORM YOU OF MY INCREASING CONCERN WITH THE"
410 PRINT#2, "FACT THAT "+N$+" HAS MISSED A TOTAL OF "+A$+" SCHOOL DAYS THUS FAR"
420 PRINT#2, "IN THE SCHOOL YEAR."
430 PRINT#2
440 PRINT#2, "     WHILE WE AT NORTH COUNTRY REALIZE AND UNDERSTAND THAT ABSENCE"
450 PRINT#2, "IS OCCASIONALLY NECESSITATED DUE TO PERSONAL OR HEALTH"
460 PRINT#2, "CONSIDERATIONS, WE NEVERTHELESS REALIZE, TOO, THAT A STUDENT'S"
470 PRINT#2, "ATTENDANCE HAS A DIRECT BEARING ON HIS OR HER ACADEMIC"
480 PRINT#2, "PERFORMANCE."
490 PRINT#2
500 PRINT#2,"     I WOULD ENCOURAGE YOU TO DISCUSS THIS PROBLEM WITH "+N$
510 PRINT#2, "WITH THE HOPE OF ELIMINATING ANY FUTURE ABSENCES WHICH ARE "
520 PRINT#2, "NOT OF AN ABSOLUTELY NECESSARY NATURE."
530 PRINT#2
540 PRINT#2, "     FINALLY, I WOULD LIKE TO THANK YOU IN ADVANCE FOR YOUR"
550 PRINT#2, "HELP AND COOPERATION IN HELPING US TO REMEDY THIS SITUATION"
560 PRINT#2, "AND THUS ENABLING "+N$+" TO GAIN THE GREATEST BENEFIT POSSIBLE"
570 PRINT#2, "FROM THE EDUCATIONAL EXPERIENCE OFFERED BY NORTH COUNTRY UNION"
580 PRINT#2, "HIGH SCHOOL."
590 PRINT#2:PRINT#2
600 PRINT#2, SPACE$(50)+"SINCERELY YOURS,"
610 PRINT#2: PRINT#2: PRINT#2
620 PRINT#2, SPACE$(50)+"LEO J. SULLIVAN"
630 PRINT#2, SPACE$(50)+"ASSOCIATE PRINCIPAL"
640 GO TO 70
700 DATA ONE,TWO,THREE,FOUR,FIVE,SIX,SEVEN,EIGHT,NINE,TEN,ELEVEN
710 DATA TWELVE,THIRTEEN,FOURTEEN,FIFTEEN,SIXTEEN,SEVENTEEN
720 DATA EIGHTEEN,NINETEEN,TWENTY,THIRTY,FORTY,FIFTY,SIXTY,SEVENTY
730 DATA EIGHTY,NINETY
750 CLOSE 1,2
760 END