10 REM PROGRAM NAME:"STU050"
20 REM- PROGRAM GENERATES TRANSCRIPT FROM CARD DECK
30 REM- CLASS RANK MAY BE IN STUDNT RECORD ON DISK OR ENTERED FROM
40 REM- KEYBOARD.
50 OPEN "LP:" FOR OUTPUT AS FILE 1
60 OPEN "CR:" FOR INPUT AS FILE 2
70 OPEN "DF:STUDNT.MST" AS FILE 3
80 DIM#3,X1$(500)=511
90 FIELD #2, 80 AS C$
95 DIM X$(10)
100 LET L$="-----------------------------------------------"
105 INPUT "NUMBER OF STUDENTS IN CLASS";R3$
110 LET J1%=1
120 GET#2
130 LET J$=LEFT(C$,5)
135 IF Z9%=1 GO TO 1110
140 LET I$=MID(C$,6,25)
150 FOR J%=J1% TO 500%
160 LET X$=X1$(J%)
170 IF LEFT(X$,5)="99999" GO TO 270
180 IF LEFT(X$,5)>J$ GO TO 260
190 IF LEFT(X$,5)=J$ GO TO 210
200 NEXT J%
210 LET R1$=MID(X$,137,3)
215 LET R2$=MID(X$,144,1)
220 LET J1%=J%
230 IF R1$<>"   " AND R1$<>"000" GO TO 280
240 PRINT "CLASS RANK FOR "+I$
250 INPUT R1$
253 INPUT "# OF SEMESTERS";R2$
255 GO TO 280
260 LET J1%=J%-1%: GO TO 240
270 LET J1%=1%: GO TO 240
280 PRINT#1,SPACE$(22)+"SECONDARY SCHOOL RECORD-TRANSCRIPT"
290 PRINT #1
300 PRINT #1,SPACE$(8)+"STUDENT INFORMATION"+SPACE$(27)+
     "SCHOOL INFORMATION"
310 PRINT #1
320 LET P$=MID(C$,42,22): LET B$=MID(C$,34,6)
330 LET G$=MID(C$,42,22): LET S1$=MID(C$,31,1)
340 LET Y$=MID(C$,32,2)
350 PRINT #1, I$;
360 PRINT #1, SPACE$(22)+"NORTH COUNTRY UNION HIGH SCHOOL"
370 PRINT #1, "ADDRESS:"+SPACE$(39)+"VETERANS AVENUE"
380 GET #2
390 LET C1$=MID(C$,6,25)
400 IF MID(C$,80,1)="5" THEN  430
410 GET #2
420 LET C2$=MID(C$,6,25)
430 PRINT#1,"   "+C1$+SPACE$(19)+"NEWPORT, VT. 05855"
440 PRINT #1, "   "+C2$
450 PRINT #1,"PARENT OR GUARDIAN:"
460 PRINT #1,"   "+G$+SPACE$(22)+"SCHOOL PHONE NUMBER: 334-7921"
470 PRINT #1
480 PRINT #1,"PREVIOUS SECONDARY SCHOOL ATTENDED:"+SPACE$(12)+
     "SCHOOL ACCREDITED BY:"
490 PRINT #1, SPACE$(49)+"STATE SYSTEM AND"
500 PRINT #1, SPACE$(47)+"    REGIONAL ACCREDITING ASSOC."
510 PRINT #1
520 PRINT #1, "DATE OF BIRTH:"+SPACE$(33)+
     "A PUBLIC SCHOOL WITH AN"
530 LET S$="      "
540 PRINT #1,"   "+LEFT(B$,2)+"-"+MID(B$,3,2)+"-"+MID(B$,5,2)+
     SPACE$(39)+"ENROLLMENT OF 1100 STUDENTS"
550 PRINT #1, SPACE$(50)+"IN GRADES 9-12"
560 IF S1$="M" THEN LET S$="MALE"
570 IF S1$="F" THEN LET S$="FEMALE"
580 PRINT #1, "SEX: "+S$
590 PRINT #1, "WAS OR WILL BE GRADUATED:"+SPACE$(22)+
     "% OF GRADS ENTERING COLLEGE:"
600 PRINT#1, "    19"+Y$+SPACE$(42)+"27% INTO A 4 YR COLLEGE"
620 PRINT#1, SPACE$(50)+" 3% INTO A 2 YR COLLEGE AND"
621 PRINT#1, SPACE$(50)+"10% INTO BUSINESS, TRADE, AND"
622 PRINT#1, SPACE$(54)+"HEALTH CAREER SCHOOLS."
623 FOR I=0 TO 10
624 LET X$(I)=SPACE$(50)
626 NEXT I
627 PRINT#1
628 LET X=0: LET X1=0
630 GET#2
632 IF MID(C$,6,2)="19" GO TO 656
634 IF X>0 GO TO 638
636 LET X$(X)="APTITUDE TEST SCORES"+SPACE$(30)
638 LET X=X+1
640 IF MID(C$,6,3)="ACH" GO TO 646
642 LET X$(X)=MID(C$,6,4)+"   "+MID(C$,11,2)+"-"+MID(C$,13,2)+
    "   V-"+MID(C$,15,3)+"  M-"+MID(C$,18,3)+SPACE$(23)
644 GO TO 630
646 IF X1>0 THEN 652
648 LET X$(X)="ACHIEVEMENT TESTS"+SPACE$(37)
650 LET X=X+1: LET X1=1
652 LET X$(X)=MID(C$,9,2)+"     "+MID(C$,11,2)+"-"+MID(C$,13,2)+
    "     "+MID(C$,15,3)+SPACE$(37)
654 GO TO 630
656 PRINT#1, X$(0)+"PASSING GRADE IS D"
658 PRINT#1, X$(1)+"ALL SUBJECTS GIVEN CREDIT"
660 FOR I=2 TO 10
662 IF X$(I)=SPACE$(50) GO TO 710
663 PRINT#1,X$(I)
664 NEXT I
710 PRINT#1
730 PRINT#1,"RANK IN CLASS BASED ON "+R2$+" SEMESTERS:"
740 PRINT#1, "APPROXIMATELY "+R1$+" IN CLASS OF "+R3$
741 FOR I=1 TO 5
742 PRINT#1:PRINT#1
743 NEXT I
744 PRINT#1, SPACE$(70)+DATE$(0)
746 PRINT#1, SPACE$(40)+LEFT(L$,25)
748 PRINT#1, SPACE$(40)+"DIRECTOR OF PUPIL PERSONNEL"
750 PRINT#1,CHR$(12)
755 LET S5$=S5$+"X" FOR S5=1 TO 10  !TIMING LOOP
760 PRINT#1,SPACE$(5)+"CLASS RECORD OF "+I$
770 PRINT#1,L$
780 PRINT#1,"YEAR       SUBJECT"+SPACE$(16)+"GRADE CREDIT"
790 PRINT#1,L$
800 ON ERROR GO TO 1030
805 GO TO 820
810 GET #2
820 IF LEFT(C$,5)<>J$ GO TO 1010
830 IF MID(C$,6,5)="     " GO TO 870
840 IF MID(C$,6,5)="ACTIV" GO TO 900
850 PRINT#1,MID(C$,6,30)
860 GO TO 810
870 PRINT#1,SPACE$(9)+MID(C$,23,22)+SPACE$(6)+MID(C$,50,1)+
    SPACE$(6)+MID(C$,51,1)
880 GO TO 810
890 PRINT#1
900 PRINT#1,L$
910 PRINT#1,SPACE$(5)+"EXTRACURRICULAR ACTIVITIES"+SPACE$(10)
    +"YEARS"
920 PRINT#1,L$
930 GET#2
940 IF LEFT(C$,5)<>J$ THEN 1010
950 PRINT#1,SPACE$(9)+MID(C$,23,27)+SPACE$(5)+MID(C$,50,10)
960 GO TO 930
1010 PRINT#1, CHR$(12)
1020 GO TO 130
1030 IF ERR<>11 GO TO 1060
1035 IF Z9%=1 THEN GOTO 1110
1040 LET Z9%=1
1050 GO TO 1010
1060 IF ERR<>14 GO TO 1100
1070 IF Z9%=1 GO TO 1110
1080 SLEEP(3)
1090 RESUME
1100 PRINT "ERROR ";ERR" AT LINE ";ERL
1110 CLOSE 1,2,3
1120 END