05 REM- PROGRAM NAME "STU116"
07 REM- PROGRAM PRODUCES CLASS LISTS FOR JUNIOR HIGH
30 OPEN "DF:TEACHR.MST" AS FILE 2
40 DIM #2,T$(500)=16
50 OPEN "CR:" FOR INPUT AS FILE 3
60 FIELD #3,80 AS C$
70 OPEN "LP:" FOR OUTPUT AS FILE 4
80 ON ERROR GOTO 400
90 GET #3
95 LET I$=LEFT(C$,5)
100 LET N$=MID(C$,6,25)
200 LET L$=MID(C$,31,4)
210 LET M$=MID(C$,36,2)    !MOD
220 LET T1$=MID(C$,58,2)  !TEACR NUMBR
230 IF L$<>L1$ OR M$<>M1$ OR T1$<>T2$ GOTO 600
250 PRINT #4,I$+" "+N$+SPACE$(5)+
     MID(C$,60,1)+" "+MID(C$,61,1)+" "+MID(C$,62,1)+"      "+
     MID(C$,65,1)+" "+MID(C$,66,1)+" "+MID(C$,67,1)
255 PRINT #4, SPACE$(78)
270 GOTO 90
400 IF ERR=11 GOTO 800
410 IF ERR=13 OR ERR=14 GOTO 420
411 GOTO 480
420 SLEEP(5)
430 RESUME
480 PRINT "ERROR =";ERR
490 STOP
600 LET L1$=L$
605 LET M1$=M$
610 LET T2$=T1$
615 PRINT #4,CHR$(12)     !SKIP TO NEW PAGE
620 PRINT #4, SPACE$(20)+"NORTH COUNTRY UNION HIGH SCHOOL"
625 PRINT #4,SPACE$(31)+"CLASS LIST"
630 PRINT #4, SPACE$(78)
632 IF LEFT(T2$,1)="B" GOTO 710
635 IF LEFT(T2$,1)="A" THEN LET K=100+VAL(MID(T2$,2,1))
     ELSE LET K=VAL(T2$)
640 LET T9$=LEFT(T$(K),11)
650 PRINT #4,SPACE$(18)+"** "+L$+" "+MID(C$,38,20)+"MOD "+M$+
     " **"
651 PRINT #4, SPACE$(28)+"TEACHER: "+T9$
660 PRINT #4, SPACE$(78)
665 PRINT #4,SPACE$(38)+"GRADE"+SPACE$(6)+"EFFORT"+SPACE$(5)+
     "CLASS CUTS"
668 PRINT #4, " ID#     STUDENT NAME"+SPACE$(15)+
     "1 2 3 4 F  1 2 3 4 F  1  2  3  4  T"
670 PRINT #4, SPACE$(78)
700 GOTO 250
710 LET K=110+VAL(MID(T2$,2,1))
715 GOTO 640
800 CLOSE 1,3,4
810 END