10 REM- PROGRAM NAME:"STU500"
20 REM PROGRAM GENERATES REPORT CARD FROM CARD DECK
30 OPEN "DF:TEACHR.MST" AS FILE 3
40 DIM #3,T9$(150)=16
50 OPEN "DF:STUDNT.MST" AS FILE 5
60 DIM #5, S$(475)=511
70 OPEN "DF:CLASS.HNR" AS FILE 6
80 DIM #6,R$(300)=32
90 LET I%=1
100 LET Z$=" "
110 OPEN "CR:" FOR INPUT AS FILE 1
120 FIELD #1, 80 AS C$
130 OPEN "LP:" FOR OUTPUT AS FILE 2
140 ON ERROR GOTO 320
150 GET #1
160 IF LEFT(C$,5)<>I$ THEN GOSUB 390
170 LET N$=MID(C$,38,20)        !COURSE NAME
179 IF MID(C$,58,1)="B" THEN GOTO 385
180 IF MID(C$,58,1)="A" THEN LET J%=100+VAL(MID(C$,59,1))
     ELSE LET J%=VAL(MID(C$,58,2))
190 LET R$=MID(C$,31,4)       !COURSE CODE
200 LET G$=MID(C$,K%,1)      !GET GRADE
210 LET E$=MID(C$,E%,1)     !GET EFFORT
220 REM**********THIS IS ONLY GOOD FOR 1ST MARKING PERIOD
230 LETF$=MID(C$,70,2)   !GET ABSENCES
240 IF F$="00" THEN LET F1$="  "ELSE LET F1$=F$
250 PRINT #2,N$+" "+R$+"   "+T9$(J%);"   "+MID(C$,60,1)+" "+
  MID(C$,61,1)+" "+MID(C$,62,1)+" "+MID(C$,63,1)+" "+
  MID(C$,64,1)+"  "+MID(C$,65,1)+" "+MID(C$,66,1)+" "+
  MID(C$,67,1)+" "+MID(C$,68,1)+" "+MID(C$,69,1);
251 LET X1$=MID(C$,72,2): LET X2$=MID(C$,74,2)
252 LET X3$=MID(C$,76,2): LET X4$=MID(C$,78,2)
253 IF X1$="00" THEN LET Y1$="  " ELSE LET Y1$=X1$
254 IF X2$="00" THEN LET Y2$="  " ELSE LET Y2$=X2$
255 IF X3$="00" THEN LET Y3$="  " ELSE LET Y3$=X3$
256 IF X4$="00" THEN LET Y4$="  " ELSE LET Y4$=X4$
260 PRINT #2, SPACE$(1)+F1$+" "+Y1$+" "+Y2$+" "+Y3$+
     " "+Y4$
270 IF G$="P" OR G$="I" GOTO 310:
    IF G$="B" AND Z$=" " THEN LET Z$="1"
280 IF G$="A" AND Z$=" " THEN LET Z$="2"
290 IF G$>"B" THEN LET Z$="0"  !IF C,D,OR F
300 IF G$="B" AND Z$="2" THEN LET Z$="1"
310 GOTO 150
320 IF ERR=11 GOTO 970
330 IF ERR=13 OR ERR=14 GOTO 370
340 PRINT "ERROR = ";ERR
350 STOP
360 GOTO 150
370 SLEEP(5)
380 RESUME
385 LET J%=110+VAL(MID(C$,59,1))
386 GOTO 190
390 PRINT #2, SPACE$(78)
400 PRINT #2, SPACE$(78)
410 PRINT #2, SPACE$(78)
420 PRINT #2,"EXPLANATION OF GRADE CODES:    LETTER GRADES"+
     "        NUMERICAL GRADES"
430 PRINT #2, SPACE$(32)+"A-SUPERIOR      "+
     "    1-EXCELLENT AT ALL TIMES"
440 PRINT #2, SPACE$(32)+"B-VERY GOOD     "+
     "    2-G00D SUSTAINED EFFORT"
450 PRINT #2, SPACE$(32)+"C-SATISFACTORY      "+
     "3-SATISFACTORY EFFORT"
460 PRINT #2, SPACE$(32)+"D-PASSING           "+
     "4-UNSATISFACTORY EFFORT"
470 PRINT #2, SPACE$(32)+"F-FAILING           "+
     "5-PLEASE CALL GUIDANCE DEP"
480 PRINT #2, SPACE$(32)+"I-INCOMPLETE"
490 PRINT #2, SPACE$(32)+"X-EXCUSED"
500 PRINT #2, SPACE$(32)+"P-PASSED"
510 PRINT#2, SPACE$(78)
520 PRINT #2,
     "PARENTS: THE LETTER GRADE REPRESENTS AN EVALUATION OF THE "
530 PRINT #2,SPACE$(9)+
     "PUPILS ACTUAL PROGRESS IN THE SUBJECT. THE NUMERICAL "
540 PRINT #2, SPACE$(9)+
     "GRADE REPRESENTS THE EFFORT MADE IN ACHIEVING THE LETTER "
550 PRINT #2, SPACE$(9)+
     "GRADE. THE NUMBER UNDER CLASS CUTS IS THE RECORD OF "
560 PRINT #2, SPACE$(9)+
     "UNEXCUSED ABSENCES FROM THE SCHEDULED CLASS. THE "
570 PRINT #2, SPACE$(9)+
     "GUIDANCE DEPARTMENT WILL DISCUSS ANY PROBLEMS WITH YOU."
580 PRINT #2, SPACE$(7)+"JUNIOR HIGH TEL. 766-2430"+
     SPACE$(7)+"SENIOR HIGH TEL: 334-7921"
590 LET D9$=DATE$(0)
600 LET D8$=MID(D9$,4,6)
610 PRINT #2, SPACE$(60)+D8$
620 PRINT #2, CHR$(12)          !SKIP TO NEW PAGE
630 IF Z$="0" GOTO 670
640 IF Z$=" " GOTO 680
650 LET R$(I%)=I$+MID(S9$,6,25)+Z$
660 LET I%=I%+1
670 LET Z$=" "
680 LET L%=L%+1
690 IF LEFT(S$(L%),5)="99999" GOTO 940
700 IF LEFT(S$(L%),5)<>LEFT(C$,5) GOTO 680
710 LET S9$=S$(L%)
720 LET O%=VAL(MID(S9$,127,2))+VAL(MID(S9$,129,2))+VAL(MID(S9$,131,2))+
     VAL(MID(S9$,133,2))+VAL(MID(S9$,135,2))
730 LET G9$=MID(S9$,114,1)   !COUNSELOR
740 LET G8$=MID(S9$,115,2)       !ADVISOR
750 LET I$=LEFT(S$(L%),5)
760 PRINT #2,G8$+SPACE$(18)+"NORTH COUNTRY UNION HIGH SCHOOL"+
     SPACE$(26)+G9$
770 PRINT #2, SPACE$(25)+"NEWPORT,VERMONT 05855"
780 PRINT #2, SPACE$(78)
790 PRINT #2, SPACE$(28)+"QUARTERLY REPORT"
800 PRINT #2, SPACE$(78)
810 PRINT #2, SPACE$(78)
820 IF LEFT(I$,1)<="3" THEN LET Y$="1973"
830 IF LEFT(I$,1)="4" THEN LET Y$="1974"
840 IF LEFT(I$,1)="5" THEN LET Y$="1975"
850 IF LEFT(I$,1)="6" THEN LET Y$="1976"
860 PRINT #2, "STUDENT NAME: "+MID(S$(L%),6,25)+SPACE$(10)+
     "YEAR OF GRADUATION: "+Y$
870 PRINT #2, "   STUDENT NUMBER: "+I$+SPACE$(25);
880 PRINT #2, USING "TOTAL DAYS ABSENT: ##",O%
890 PRINT #2, SPACE$(78)
900 PRINT #2, SPACE$(68)+"CLASS"
910 PRINT #2, SPACE$(5)+"SUBJECT"+SPACE$(16)+"TEACHER"+
     SPACE$(7)+"  GRADE     EFFORT        CUTS"
920 PRINT #2, SPACE$(42)+
     "1 2 3 4 F  1 2 3 4 F  1  2  3  4  F"
930 RETURN
940 PRINT "CANT FIND MASTER FOR ";LEFT(C$,5)
950 LET L%=1
960 GOTO 690
970 GOSUB 390
980 CLOSE 1,2,3,5,6
990 END