10 REM-PROGRAM NAME "STU535"
20 REM- PROGRAM GENERATES REPORT CARD FROM DISK REC
30 OPEN "DF:TEACHR.MST" AS FILE 3
40 DIM #3,T9$(150)=16
50 OPEN "DF:STUDNT.MST" AS FILE 5
60 DIM #5, S$(475)=511
70 OPEN "DF:COURSE.NAM" AS FILE 6
75 DIM #6, N9$(500)=32
130 OPEN "LP:" FOR OUTPUT AS FILE 2
135 FOR L%=1 TO 400
136 LET S9$=S$(L%)
138 IF MID(S9$,147,1)="D" GOTO 630
140 IF LEFT(S9$,5)="99999" GOTO 2000
141 IF LEFT(S9$,5)="     " GOTO 630
144 GOSUB 760
150 FOR G%=1 TO 16
152 LET M%=180+((G%-1)*20)
155 LET C$=MID(S9$,M%,20)
160 IF LEFT(C$,4)=SPACE$(4) GOTO 310
179 IF MID(C$,5,1)="B" THEN GOTO 385
180 IF MID(C$,5,1)="A" THEN LET J%=100+VAL(MID(C$,6,1))
     ELSE LET J%=VAL(MID(C$,5,2))
190 LET R$=LEFT(C$,4)
195 GOSUB 1000
250 PRINT #2, N$+" "+R$+"   "+T9$(J%)+"   "+MID(C$,7,1)+" "+
     MID(C$,8,1)+" "+MID(C$,9,1)+" "+MID(C$,10,1)+" "+
     MID(C$,11,1)+"  ";
253 PRINT #2, MID(C$,12,1)+" "+MID(C$,13,1)+" "+MID(C$,14,1)+
     " "+MID(C$,15,1)+" "+MID(C$,16,1)
310 NEXT G%
320 GOTO 390
385 LET J%=110+VAL(MID(C$,59,1))
386 GOTO 190
390 PRINT #2, SPACE$(78)
400 PRINT #2, SPACE$(78)
410 PRINT #2, SPACE$(78)
420 PRINT #2,"EXPLANATION OF GRADE CODES:    LETTER GRADES"+
     "        NUMERICAL GRADES"
430 PRINT #2, SPACE$(32)+"A-SUPERIOR      "+
     "    1-EXCELLENT AT ALL TIMES"
440 PRINT #2, SPACE$(32)+"B-VERY GOOD     "+
     "    2-G00D SUSTAINED EFFORT"
450 PRINT #2, SPACE$(32)+"C-SATISFACTORY      "+
     "3-SATISFACTORY EFFORT"
460 PRINT #2, SPACE$(32)+"D-PASSING           "+
     "4-UNSATISFACTORY EFFORT"
470 PRINT #2, SPACE$(32)+"F-FAILING           "+
     "5-PLEASE CALL GUIDANCE DEP"
480 PRINT #2, SPACE$(32)+"I-INCOMPLETE"
490 PRINT #2, SPACE$(32)+"X-EXCUSED"
500 PRINT #2, SPACE$(32)+"P-PASSED"
510 PRINT#2, SPACE$(78)
520 PRINT #2,
     "PARENTS: THE LETTER GRADE REPRESENTS AN EVALUATION OF THE "
530 PRINT #2,SPACE$(9)+
     "PUPILS ACTUAL PROGRESS IN THE SUBJECT. THE NUMERICAL "
540 PRINT #2, SPACE$(9)+
     "GRADE REPRESENTS THE EFFORT MADE IN ACHIEVING THE LETTER "
550 PRINT #2, SPACE$(9)+
     "GRADE. THE NUMBER UNDER CLASS CUTS IS THE RECORD OF "
560 PRINT #2, SPACE$(9)+
     "UNEXCUSED ABSENCES FROM THE SCHEDULED CLASS. THE "
570 PRINT #2, SPACE$(9)+
     "GUIDANCE DEPARTMENT WILL DISCUSS ANY PROBLEMS WITH YOU."
580 PRINT #2, SPACE$(7)+"JUNIOR HIGH TEL. 766-2430"+
     SPACE$(7)+"SENIOR HIGH TEL: 334-7921"
590 LET D9$=DATE$(0)
600 LET D8$=MID(D9$,4,6)
610 PRINT #2, SPACE$(60)+D8$
620 PRINT #2, CHR$(12)          !SKIP TO NEW PAGE
630 NEXT L%
720 LET O%=VAL(MID(S9$,127,2))+VAL(MID(S9$,129,2))+VAL(MID(S9$,131,2))+
     VAL(MID(S9$,133,2))+VAL(MID(S9$,135,2))
730 LET G9$=MID(S9$,114,1)   !COUNSELOR
740 LET G8$=MID(S9$,115,2)       !ADVISOR
750 LET I$=LEFT(S$(L%),5)
760 PRINT #2,G8$+SPACE$(18)+"NORTH COUNTRY UNION HIGH SCHOOL"+
     SPACE$(26)+G9$
770 PRINT #2, SPACE$(25)+"NEWPORT,VERMONT 05855"
780 PRINT #2, SPACE$(78)
790 PRINT #2, SPACE$(28)+"QUARTERLY REPORT"
800 PRINT #2, SPACE$(78)
810 PRINT #2, SPACE$(78)
820 IF LEFT(I$,1)<="3" THEN LET Y$="1973"
830 IF LEFT(I$,1)="4" THEN LET Y$="1974"
840 IF LEFT(I$,1)="5" THEN LET Y$="1975"
850 IF LEFT(I$,1)="6" THEN LET Y$="1976"
860 PRINT #2, "STUDENT NAME: "+MID(S$(L%),6,25)+SPACE$(10)+
     "YEAR OF GRADUATION: "+Y$
870 PRINT #2, "   STUDENT NUMBER: "+I$+SPACE$(25);
880 PRINT #2, USING "TOTAL DAYS ABSENT: ##",O%
890 PRINT #2, SPACE$(78)
900 PRINT #2, SPACE$(68)+"CLASS"
910 PRINT #2, SPACE$(5)+"SUBJECT"+SPACE$(16)+"TEACHER"+
     SPACE$(7)+"  GRADE     EFFORT        CUTS"
920 PRINT #2, SPACE$(42)+
     "1 2 3 4 F  1 2 3 4 F  1  2  3  4  F"
930 RETURN
980 CLOSE 1,2,3,5,6
990 STOP
1000 LET K9%=264
1001 LET K0%=1
1005 LET K%=((K9%-K0%)/2)+K0%
1006 IF K0%+1=K9% THEN GOTO 1070
1010 IF LEFT(N9$(K%),4)<R$ GOTO 1060
1020 IF LEFT(N9$(K%),4)>R$ GOTO 1040
1030 LET N$=MID(N9$(K%),5,20)
1035 RETURN
1040 LET K9%=K%
1043 GOTO 1005
1060 LET K0%=K%
1065 GOTO 1005
1070 PRINT "CANNOT FIND NAME FOR ";R$
1075 STOP
1080 RETURN
2000 END