05 REM-PROGRAM NAME: "STU600"
06 REM-PROGRAM LISTS STUDENTS WITH 1 OR MORE CLASS CUTS
10 OPEN "DF:STUDNT.MST" AS FILE 1
20 DIM #1, S$(400)=511
30 OPEN "CR:" FOR INPUT AS FILE 2
40 FIELD #2, 80 AS C$
50 OPEN "LP:" FOR OUTPUT AS FILE 3
55 OPEN "DF:TEACHR.MST" AS FILE 4
56 DIM #4,T$(200)=16
57 INPUT "ENTER MARKING PERIOD"; K%
58 LET K9%=(2*K%)+68
60 ON ERROR GOTO 500
62 PRINT #3, "LISTING OF STUDENTS WITH 1 OR MORE CUTS";
63 PRINT #3, "DURING MARKING PERIOD # ";K%
64 PRINT #3, SPACE$(78)
65 PRINT #3," ID #    STUDENT NAME"+SPACE$(12)+
     "COURSE NAME"+SPACE$(14)+"TEACHER"+"    CUTS"
66 PRINT #3, SPACE$(78)
70 GET #2
80 LET I$=LEFT(C$,5)
90  IF I$<>I1$ GOTO 300
93 IF MID(C$,K9%,2)="00" OR MID(C$,K9%,2)="  " GOTO 70
94 IF MID(C$,58,1)="B" GOTO 120
96 IF MID(C$,58,1)="A" THEN LET K%=100+VAL(MID(C$,59,1)) ELSE
     LET K%=VAL(MID(C$,58,2))
97 LET T1$=T$(K%)
100 PRINT #3, I$+" "+N$+" "+MID(C$,31,26)+" "+T1$+" "+
     MID(C$,K9%,2)
110 GOTO 70
120 LET K%=110+VAL(MID(C$,59,1))
122 GOTO 97
300 LET J%=J%+1
310 IF LEFT(S$(J%),5)=I$ GOTO 370
320 GOTO 300
330 PRINT "CANT FIND MASTER FOR ";I$
340 GOTO 70
370 LET N$=MID(S$(J%),6,25)
375 LET I1$=LEFT(C$,5)
380 GOTO 93
500 IF ERR=11 GOTO 550
510 IF ERR=13 OR ERR=14 GOTO 530
520 PRINT "ERR0R =";ERR
525 STOP
530 SLEEP(5)
535 RESUME
550 CLOSE 1,2,3,4
560 END