10 REM-PROGRAM NAME*STU606
20 REM-PROGRAM PRODUCES ELIGIBILITY LIST
30 OPEN "DF:STUDNT.MST" AS FILE 1
40 DIM #1,S$(500)=511
50 OPEN "CR:" FOR INPUT AS FILE 2
60 FIELD #2, 80 AS C$
70 OPEN "LP:" FOR OUTPUT AS FILE 4
80 ON ERROR GOTO 550
90 INPUT "ENTER QUARTER"; Q%
100 LET Q9%=59+Q%  !TO GET PROPER QUARTER
110 PRINT #4,SPACE$(30)+"INELIGIBILITY LIST"
120 PRINT #4,SPACE$(34)+DATE$(0)
130 PRINT #4, SPACE$(78)
140 GET #2
150 LET I$=LEFT(C$,5)
160 IF I$<>I1$ GOTO 320
170 IF MID(C$,31,1)="P" GOTO 140    !DONT COUNT PHYS ED
180 LET G1$=MID(C$,34,1)   !COURSE CREDIT
190 IF MID(C$,31,1)="E" AND MID(C$,34,1)="1" THEN LET
     G1$="4"
200 IF MID(C$,31,1)="Z" AND MID(C$,34,1)="1" THEN LET
     G1$="4"
210 IF MID(C$,31,4)="Z732" THEN LET G1$="4"
220 IF MID(C$,31,4)="Z642" THEN LET G1$="4"
230 IF MID(C$,31,4)="BT01" THEN LET G1$="2"
240 IF MID(C$,31,1)="T" THEN LET G1$="2"
250 IF MID(C$,31,4)="BT11" THEN LET G1$="2"
260 IF MID(C$,31,4)="BT12" THEN LET G1$="4"
270 IF MID(C$,31,4)="Z991" THEN LET G1$="1"
280 LET G$=MID(C$,Q9%,1)
290 IF G$=" " THEN GOTO 140
300 IF G$<="D" OR G$="P" THEN LET E=E+VAL(G1$)
310 GOTO 140
320 IF X=0 GOTO 360
330 IF E>=12 GOTO 360
340 PRINT #4, LEFT(S$(J%),5)+" "+MID(S$(J%),6,25)+"       ";
350 PRINT #4, E
360 LET J%=J%+1
370 IF LEFT(S$(J%),5)=I$ GOTO 400
380 IF LEFT(S$(J%),5)="99999" GOTO 520
390 GOTO 360
400 IF MID(S$(J%),146,1)="D" THEN GOTO 430
410 IF MID(S$(J%),146,1)="V" THEN GOTO 430
420 GOTO 470
430 GET #2
440 IF LEFT(C$,5)=I$ GOTO 430
450 LET I$=LEFT(C$,5)
460 GOTO 360
470 LET I1$=LEFT(S$(J%),5)
480 LET X=X+1
490 LET E=0
500 LET I1$=I$
510 GOTO 170
520 PRINT "CANNOT FIND MASTER FOR ID# ";I$
530 LET J%=0
540 GO TO 430
550 IF ERR=11 GOTO 610
560 IF ERR=13 OR ERR=14 GOTO 590
570 PRINT "ERR0R =";ERR
580 STOP
590 SLEEP(5)
600 RESUME
610 CLOSE 1,2,4
620 END