10 REM - PROGRAM NAME: "STU800"
20 REM- PROGRAM COMPUTES GRADE POINT AVERAGE BASED ON
     NEW COURSE NUMBERING SYSTEM
30 OPEN "DF:STUDNT.MST" AS FILE 1
40 DIM #1, S1$(500)=511
50 OPEN "CR:" FOR INPUT AS FILE 2
60 FIELD #2, 80 AS C$
62 OPEN "LP:" FOR OUTPUT AS FILE 3
65 ON ERROR GOTO 800
75 LET I1$="     "
80 GET #2
81 LET I$=LEFT(C$,5)    !ID # FROM CARD
85 LET S$=S1$(J%)
90 IF I$>I1$ THEN GOSUB 400
100 IF I$<I1$ THEN GOTO 500
105 LET C=VAL(MID(C$,34,1))  !COURSE CREDITS
110 LET G$=MID(C$,64,1)   !FINAL GRADE
115 IF MID(C$,31,1)="E" OR MID(C$,31,1)="Z" THEN GOTO 200
118 IF G$=" " THEN GOTO 80
120 IF G$>="F" THEN GOTO 80    !NO CREDIT ,GET NXT CRD
125 IF G$="A" THEN GOTO 150
130 IF G$="B" THEN GOTO 155
140 IF G$="C" THEN GOTO 160
145 IF G$="D" THEN GOTO 165
147 STOP
148 GOTO 80
150 LET S=S+(C*4000)
151 GOTO 167
155 LET S=S+(C*3000)
157 GOTO 167
160 LET S=S+(C*2000)
162 GOTO 167
165 LET S=S+(C*1000)
167 LET N=N+C
169 GOTO 80
180 GOSUB 600
185 GOTO 120
200 IF MID(C$,34,1)="1" THEN GOTO 180
210 GOTO 118
400 IF I1$="     " THEN GOTO 415
403 IF S=0 GOTO 415
404 LET S=S/N
405 LET R=R+S
406 LET R%=R/W
408 GOSUB 700
415 LET J%=J%+1
417 LET S$=S1$(J%)
420 IF LEFT(S$,5)<I$ THEN GOTO 415
422 LET I1$=LEFT(S$,5)
425 LET R=VAL(MID(S$,140,4))*VAL(MID(S$,144,1))
426 LET N=0
427 LET S=0
428 LET W=VAL(MID(S$,144,1))+1    ! ADD 1 TO G.P. WT.
430 RETURN
500 PRINT "CANNOT FIND MASTER FOR # ";I$
510 GOTO 80
600 FOR N%=1 TO 4
605 LET M%=59+N%
608 IF MID(C$,M%,1)<>" " THEN GOTO 650
610 NEXT N%
615 STOP
616 GOTO 80
650 LET G$=MID(C$,M%,1)
655 RETURN
700 LET T$=NUM$(R%)
705 LET A=LEN(T$)
710 LET A=A-1
715 LET N5=1
720 IF A>4 GOTO 780
725 LET T1$=MID(T$,N5,A)
730 LET M=4-A
735 LET T$=SPACE$(M)+T1$
740 LET S1$(J%)=LEFT(S$,139)+T$+"7"+MID(S$,145,367)
745 PRINT #3, LEFT(S$,30)+"  "+T$
750 RETURN
780 LET N5=N5+1
785 LET A=A-1
790 GOTO 720
800 IF ERR=11 GOTO 850
805 IF ERR=14 GOTO 840
810 PRINT "ERROR= ";ERR
820 STOP
840 SLEEP(2)
845 RESUME
850 LET S=S/N
855 LET R=R+S
856 LET R%=R/W
860 GOSUB 700
870 CLOSE 1,2,3
1000 END