10 REM -PROGRAM NAME:"STUXX2
20 REM-CREATES STUDENT MASTER FILE FROM CARD INPUT
30 OPEN "DF:STUDNT.MST" AS FILE 1
40 DIM #1,A$(500)=511
50 OPEN "CR:" FOR INPUT AS FILE 2
60 FIELD #2, 80 AS C$
65 LET J%=J%+1
66 ON ERROR GOTO 500
70 GET #2
80 LET I$=LEFT(C$,5)    !ID #
90 LET J$=MID(C$,6,25)    !STUDENTS NAME
100 LET O$=MID(C$,31,1)   !STUDENTS SEX
110 LET W3$=MID(C$,33,1)  !YR OF GRAD
120 IF MID(C$,34,2)<"10" THEN LET P0$=MID(C$,35,1)
130 IF MID(C$,34,2)="10" THEN LET P0$="A"
131 IF MID(C$,34,2)="11" THEN LET P0$="B"
132 IF MID(C$,34,2)="12" THEN LET P0$="C"
133 LET P$=P0$+MID(C$,36,4)  !BIRTHDAY
140 LET Q$=MID(C$,42,20)    !GUARDIAN
150 LET N$=MID(C$,64,7)    !PHONE
160 IF MID(C$,71,4)=SPACE$(4) GOTO 490
161 LET M$=" "
162 IF MID(C$,71,4)="NONR" THEN LET M$="0"
163 IF MID(C$,71,4)="NEWC" THEN LET M$="1"
165 IF MID(C$,71,4)="NPTT" THEN LET M$="2"
167 IF MID(C$,71,4)="CHAR" THEN LET M$="3"
168 IF MID(C$,71,4)="CVTY" THEN LET M$="4"
169 IF MID(C$,71,4)="HOLL" THEN LET M$="5"
170 IF MID(C$,71,4)="LOWL" THEN LET M$="6"
172 IF MID(C$,71,4)="WEST" THEN LET M$="7"
174 IF MID(C$,71,4)="DRBY" THEN LET M$="8"
176 IF MID(C$,71,4)="TROY" THEN LET M$="9"
178 IF MID(C$,71,4)="MORG" THEN LET M$="A"
179 IF MID(C$,71,4)="BRIT" THEN LET M$="B"
180 IF MID(C$,71,4)="JAY " THEN LET M$="C"
190 LET T1$=MID(C$,79,1)   !COUNSELOR
195 LET T2$=MID(C$,40,2)   !ADVISOR
200 GET #2
210 IF MID(C$,80,1)="5" GOTO 280
220 IF MID(C$,80,1)="1" GOTO 400
225 IF MID(C$,80,1)<>"3" THEN STOP
230 LET K$=MID(C$,6,20)    !STREET ADDRESS
240 GET #2
250 IF MID(C$,80,1)<>"5" THEN STOP
260 GOTO 290
280 LET K$=SPACE$(20)
290 LET L$=MID(C$,6,20)    !CITY/TOWN
300 LET R$=SPACE$(7)       !GUARDIANS PHONE
302 LET S1$=" "
303 LET S2$=" "            !DRIVER ED FLAG
310 LET U$=SPACE$(10)      !TWO WEEKS ATTEND PICTURE
320 LET V$="0000000000"    !CUMULATIVE ABSENCES
330 LET W0$="000"          !ACCUM CREDITS
340 LET W1$="0000"         !CURRENT RANK
350 LET W2$="0"            !RANKING WEIGHT
360 LET A$(J%)=I$+J$+K$+L$+M$+N$+O$+P$+Q$+R$+S1$+S2$+T1$+T2$+
     U$+V$+W0$+W1$+W2$+W3$+W4$+SPACE$(366)
365 IF MID(C$,80,1)="1" GOTO 80
370 GOTO 65
400 LET K$=SPACE$(20)       !NO STREET ADDR
405 LET L$=SPACE$(20)       !NO CITY
410 GOTO 300
490 PRINT "NO TOWN LISTED FOR STUDENT #";I$
491 LET M$=" "
495 GOTO 190
500 IF ERR=11 GOTO 560
510 IF ERR=13 OR ERR=14 GOTO 550
520 PRINT "ERROR =";ERR
530 STOP
550 SLEEP(2)
555 RESUME
560 LET A$(J%)="99999"+SPACE$(506)
565 CLOSE 1,2
570 END