30 REM      AVERG1:  AVERAGES AND CURVES GRADES
80 REM AVERG1 - COPYRIGHT 1971, POLYTECHNIC INSTITUTE OF BROOKLYN
100 REM COURT, G.M., WALT WHITMAN H.S., REVISED 8/69
105 REM  REVISED BY C. LOSIK   8-26-70
110 REM
120 REM PROGRAM AVERAGES ANY NUMBER OF GRADES, FOR CURVING PURPOSES
130 REM YOU ARE ASKED FOR A PASSING GRADE. IF THE AVERAGE FALLS BELOW
140 REM THAT THE DIFFERENCE WILL BE PRINTED OUT AS WELL AS NEWLY CAL-
150 REM CULATED GRADES FOR EACH STUDENT, REMEMBER THAT THIS TYPE OF
160 REM CURVING IS VALID ONLY IF THE ORIGINAL GRADE DISTRIBUTION
170 REM SHOWED A BELL CURVE.
180 REM
190 REM ENTER GRADES ON DATA LINES 600-_-700
200 N=0
220 READ X
230 IF X=9999 THEN 260
240 N=N+1
250 GOTO 220
260 RESTORE
270 G=0
280 PRINT'PASSING GRADE FOR THIS TEST IS ';
290 INPUT P
300 FOR T=1 TO N
310 READ A
320 G=G+A
330 NEXT T
340 M=G/N
350 PRINT
360 PRINT'THE AVERAGE OF ALL GRADES ENTERED IS 'M'.'
365 D=0
370 IF M>=P THEN 410
380 PRINT
390 D=INT(P-M+.5)
400 PRINT"THE AVERAGE FALLS BELOW THE PASSING GRADE BY "D" POINTS."
405 PRINT'(ROUNDED TO NEAREST WHOLE NUMBER.)'
410 RESTORE
415 PRINT
417 PRINT'ADJUSTED GRADE = ORIGINAL GRADE +'D
420 PRINT
430 PRINT'STUDENT','ORIGINAL','ADJUSTED'
435 PRINT'NUMBER',' GRADE ',' GRADE'
440 PRINT'-------','--------','--------'
460 FOR X=1 TO N
470 READ A
490 PRINT X,A,A+D
500 NEXT X
600 DATA 65,78,76,48,65,78,82,69,71,56,90,67,59,60,70,74,62,57,66
601 DATA 64,63,65,59,60,56,48,66
701 DATA 9999
999 END