5 PRINT
10 DEF FNF(Y)=-X/Y
20 REM ***** DE-1OR  *****  MATHEMATICS PROGRAM  *****
30 REM ***** VERSION 1 *****  7/31/69  *****
40 REM SOLVES A FIRST ORDER DIFFERENTIAL EQUATION
50 INPUT'HAVE YOU ENTERED YOUR FUNCTION YET';K1$
51 IF K1$='YES' THEN 60
52 PRINT'ENTER YOUR FUNCTION IN THE FOLLOWING MANNER. '
53 PRINT'10 DEF FNF(Y)=***YOUR FUNCTION***'
54 PRINT'THEN TYPE RUN'
55 GOTO 440
60 INPUT 'INITIAL X VALUE';X0
61 PRINT 'INITIAL Y VALUE AT ';X0;:INPUT Y
62 INPUT'STEP SIZE FOR INTEGRATION';H
63 INPUT'UPPER LIMIT FOR INTEGRATION';B
64 INPUT'STEP SIZE OF X FOR PRINT OUT';L
65 PRINT
70 X=X0
80 E=1/L
90 IF (B-X0)*H>0 THEN 110
100 H=-H
110 IF(B-X0)*L>0 THEN 130
120 L=-L
130 PRINT'VALUE OF X','VALUE OF Y'
140 PRINT
150 PRINTX,Y
160 GOTO 200
170 P=Y+H*FNF(Y)
180 X=X+H
190 Y=(Y+P)/2+H/2*FNF(P)
200 IF(X+H-B)*SGN(L)+1.E-07>=0 THEN 230
210 R=X+H
220 GOTO 240
230 R=B
240 A=INT(E*R)/E+L*(SGN(H)-1)/2
250 IF(A+L-R)*SGN(L)-1.E-07>=0 THEN 270
260 A=A+L
270 IF(X-A)*SGN(L)+1.E-07>=0 THEN 300
280 Q=A
290 GOSUB 360
300 IF R=B THEN 320
310 GOTO 170
320 IF ABS(R-A)<.5*.000001 THEN 350
330 Q=R
340 GOSUB 360
350 GOTO 440
360 P1=Y+(Q-X)*FNF(Y)
370 X1=X
380 X=Q
390 Y1=(Y+P1)/2+(Q-X1)/2*FNF(P1)
400 X=X1
410 PRINTQ,Y1
420 RETURN
440 END