5 PRINT
10 DEF FNF(Y)=3*X+2*Y-Z
20 REM *****  DE2OR  *****  MATHEMATICS PROGRAM  *****
30 REM *****  VERSION 1  *****  7/31/69  *****
40 REM INITIAL VAUE PROBLEM
45 INPUT'HAVE YOU ENTERED YOUR FUNCTION YET';V1$
46 IF V1$='YES' THEN50
47 PRINT'ENTER YOUR FUNCTION IN THE FOLLOWING MANNER.'
48 PRINT'10 DEF FNF(X)=***YOUR FUNCTION***
49 GOTO 570
50 INPUT 'INITIAL X VALUE';X0
51 INPUT'VALUE OF Y AT INITIAL X';Y
52 INPUT'VAULE OF DERIVATIVE AT INITIAL X';Z
53 INPUT'UPPER LIMIT OF INTEGRATION';B
54 INPUT'INTEGRATION STEP SIZE';H
55 INPUT'STEP SIZE OF X FOR PRINT OUT';L
59 PRINT
60 X=X0
70 E=1/L
80 IF(B-X0)*H>0 THEN 100
90 H=-H
100 IF (B-X0)*L>0 THEN 120
110 L=-L
120 REM
130 PRINT"VALUE OF X","VALUE OF Y","VALUE OF Y'"
140 PRINT
150 PRINTX,Y,Z
160 GOTO 270
170 P1=Y+H*Z
180 Q1=Z+H*FNF(X)
190 Y=(Y+P1)/2+.5*H*Q1
200 Y1=Y
210 Z1=Z
220 Y=P1
230 Z=Q1
240 X=X+H
250 Z=(Z1+Q1)/2+H/2*FNF(X)
260 Y=Y1
270 IF(X+H-B)*SGN(L)+1.E-07>=0 THEN 300
280 R=X+H
290 GOTO 310
300 R=B
310 A=INT(E*R)/E+L*(SGN(H)-1)/2
320 IF (A+L-R)*SGN(L)-1.E-07>=0 THEN 340
330 A=A+L
340 IF(X-A)*SGN(L)+1.E-07>=0 THEN 370
350 Q=A
360 GOSUB 430
370 IF R=B THEN 390
380 GOTO 170
390 IF ABS(R-A)<.5*.000001 THEN 420
400 Q=R
410 GOSUB 430
420 GOTO 570
430 P2=Y+(Q-X)*Z
440 Q2=Z+(Q-X)*FNF(X)
450 Y2=(Y+P2)/2+.5*(Q-X)*Q2
460 Y1=Y
470 Z1=Z
480 Y=P2
490 Z=Q2
500 Z2=(Z1+Q2)/2+(Q-X)/2*FNF(Q)
510 Y=Y1
520 Z=Z1
530 PRINT Q,Y2,Z2
540 RETURN
550 GOTO 570
570 END