12  REM      SCORES:  COMPUTES MEAN, STANDARD DEVIATION AND STANDARD
13  REM               SCORES FOR TEST SCORES
17  REM
18PRINT'THIS PROGRAM CALCULATES THE MEAN, STANDARD DEVIATION,'
19PRINT'Z-SCORE AND T-SCORE FOR A SET OF SCORES WHICH YOU '
20PRINT'ENTER. THE NUMBER OF SCORES MAY NOT EXCEED 250.'
21PRINT:PRINT
100  REM  STATISTICS PROGRAMS: MEAN, STANDARD DEVIATION, STANDARD SCORES
110DIMX(250),D(250),Z(250),T(250)
120  LET X=0
130INPUT 'PLEASE TYPED THE NUMBER OF SCORES YOU WANT TO ENTER';N
140  FOR I=1 TO N
150PRINT'SCORE NO. ';I;:INPUTX(I)
160  LET X=X+X(I)
170  NEXT I
180  LET M=X/N
185PRINT:PRINT
190  PRINT "MEAN = ";M
200  LET D=0
210  FOR I=1 TO N
220  LET D(I)=X(I)-M
230  LET D=D+D(I)^2
240  NEXT I
250  LET S=SQR(D/N)
260  PRINT "STANDARD DEVIATION = ";S
270  FOR I=1 TO N
280  LET Z(I)=D(I)/S
290T(I)=10*D(I)/S+50
300  NEXT I
310  PRINT
320  PRINT "SCORE", "DEVIATION","Z-SCORE","T-SCORE"
330  PRINT '-----', '---------','-------','-------'
340  FOR I=1 TO N
350  PRINT X(I),D(I),Z(I),T(I)
360  NEXT I
390  END