10 REM ***** TMFCEV ***** ENGINEERING PROGRAM *****
20 REM ***** VERSION 1 ***** 7/31/69 *****
30 REM EVALUATES TIME FUNCTIONS
40 DIM X(200)
50 INPUT'ENTER THE NUMBER OF EXPONENTIAL TERMS';N1
51 INPUT'ENTER THE NUMER OF SIN-COSINE EXPONENTAIL TERMS';N2
52 INPUT'ENTER THE NUMBER OF POINTS FOR WHICH THE FUNCTION WILL BE COMPUTED';N
53 INPUT'ENTER THE STARTING TIME';T1
54 INPUT'ENTER THE TIME BETWEEN POINTS';T2
55 INPUT'ENTER THE STANDARD DEVIATION OF THE NOISE';C1
56 PRINT:PRINT:PRINT'NOW ENTER THE COEFFICIENTS OF THE EXPONENTIAL TERMS'
60 M=2*N1+4*N2
70 FOR J=1 TO M
80 INPUT X(J)
90 NEXT J
100 PRINT'   T I M E   F U N C T I O N'
110 PRINT
120 PRINT
130 PRINT'NOISE SIGMA =';C1
140 IF N1=0 THEN 230
150 PRINT
160 PRINT'TERMS OF FORM   C*EXP(-S*T)   ARE:'
170 PRINT
180 PRINT' ','    C','    S'
190 PRINT
200 FOR J=1 TO N1
210 PRINT' ',X(J),X(N1+J)
220 NEXT J
230 IF N2=0 THEN 320
240 PRINT
250 PRINT'TERMS OF FORM   (A*COS(W*T)+B*SIN(W*T))*EXP(-G*T)   ARE:'
260 PRINT
270 PRINT' ','    A','    B','    W','    G'
280 PRINT
290 FOR J=(2*N1+1) TO (2*N1+N2)
300 PRINT' ',X(J),X(N2+J),X(2*N2+J),X(3*N2+J)
310 NEXT J
320 PRINT
330 PRINT'FIRST POINT AT T=';T1,'SPACING DELTA-T=';T2
340 PRINT
350 PRINT'DATA POINTS ARE:'
360 PRINT
370 FOR I=1 TO N
380 D=0
390 T=T1+(I-1)*T2
400 FOR J=1 TO (N1+N2)
410 IF J>N1 THEN 440
420 D=D+X(J)*EXP(-X(N1+J)*T)
430 GOTO 480
440 L=N1+J
450 Y=(COS(X(2*N2+L)*T))*EXP(-X(3*N2+L)*T)
460 Z=(SIN(X(2*N2+L)*T))*EXP(-X(3*N2+L)*T)
470 D=D+X(L)*Y+X(N2+L)*Z
480 NEXT J
490 D=D+C1*(RND-.5)*SQR(12)
500 PRINTD,
510 NEXT I
520 GOTO 550
550 END