3 !      LABOR:  LABOR/MANAGEMENT BARGAINING
4 !
10 OPEN "STRIKE.LBR" AS FILE 1%
11 OPEN "LABOR.MAT" AS FILE 2%
12 DEF FNR(R$,R%)=CVT$F(MID(R$,4%*R%-3%,4%))
13 DEF FNR$(R$,R)=R$+CVTF$(R)
15 FIELD #1%,36% AS F1$,36% AS G1$,36% AS A1$,36% AS B1$,16% AS C1$,
   2% AS V$,4% AS T$,4% AS I5$,4% AS A6$,4% AS A5$,4% AS X2$,
   4% AS C9$,2% AS W5$,2% AS C3$,2% AS A$,2% AS B$
20 DIM #2%,A$(41%)=64%,A(9%),B(9%),C(4%),D(9%),F(9%),G(9%),E(9%)
30 DATA 5,1,5,7
40 READ W5%,C3%,A%,B%
50 INPUT "FIRM #";F%
80 FOR C7%=1% TO C3%
85 ON ERROR GOTO 100
90 GET #1%, RECORD F%:GOTO 110
100 IF ERR=11% THEN RESUME 135 ELSE PRINT "ERR.";ERR;"AT";ERL:STOP
110 FOR S6%=1% TO 9%
112 F(S6%)=FNR(F1$,S6%):G(S6%)=FNR(G1$,S6%):A(S6%)=FNR(A1$,S6%)
114 B(S6%)=FNR(B1$,S6%):IF S6%<5% THEN C(S6%)=FNR(C1$,S6%)
116 NEXT S6%
118 V%=CVT$%(V$):T=CVT$F(T$):I5=CVT$F(I5$):A6=CVT$F(A6$):A5=CVT$F(A5$)
120 X2=CVT$F(X2$):C9=CVT$F(C9$):W5%=CVT$%(W5$):C3%=CVT$%(C3$)
122 A%=CVT$%(A$):B%=CVT$%(B$)
130 GOTO 1160
135 PRINT CHR$(11%)
140 PRINT,"COLLECTIVE BARGAINING SIMULATION"
160 V%=0%:T,I5,A6,A5,X2,C9=0
170 MAT F=ZER:MAT G=ZER
190 PRINT ":::::FIRM";F%,":::::COPY #";C7%
200 U,C9=0:Q3%=0%
210 A(1%)=(A%+B%)/2.-3%:A(2%)=A%*B%*.15
230 U8=.08+((A%*B%)/4%)/100.:IF U8<.14 THEN A(3%)=U8 ELSE A(3%)=.14
240 U8%=INT(575%-10%*(A(2%)+1%)^2%)
245 IF U8%>328% THEN A(4%)=U8% ELSE A(4%)=328%
250 T=A(4%)
260 U8=1.5*(A%+B%)*10000%
265 IF U8>182000 THEN A(5%)=U8 ELSE A(5%)=182000
270 I5=A(5%)
280 A(6%)=A(4%)*40%
290 A6=A(6%)
300 A(7%)=6.5E6+125000.*(A%+2%*B%)
310 U8=(A%+B%)*A(7%)*.007:IF U8<425000 THEN U8=425000
315 IF U8>957000 THEN U8=957000
317 A(8%)=U8
320 A5=A(7%)/52.
330 A(9%)=INT(A(8%)/A(4%))
340 B(1%)=12:V%=1%
360 B(2%)=INT(A%*B%*.1)/100.+2.2
370 B(3%)=1%+(A%+B%)/5%
380 B(4%)=5%+A%
390 B(5%)=40%+(A%+B%)/5%
400 B(6%)=(A%+B%)/2%
410 B(7%)=350%+10%*A%+B%
420 B(8%)=3%
425 B(9%)=1.5*B(2%)
430 B(9%)=INT(B(9%)*100%+.5)/100.
450 C(1%)=(A%*B%)/20.+2%
460 C(2%)=INT((A%+B%)/3*100%)/100.+.2
470 C(3%)=8%-C(1%)
480 C(4%)=(11%-A%)*.1*(B%+1%)
490 PRINT "THE LAST LABOR MANAGEMENT CONTRACT IS EXPIRING TONIGHT."
500 PRINT " THE UNION IS EXTREMELY DISSATISFIED WITH IT AND HAS DECIDED"
510 PRINT "TO GO ON STRIKE.";CHR$(11%)
520 PRINT "*** INFORMATION CONCERNING :"
530 PRINT
570 PRINT "THE FIRM (SINCE LAST CONTRACT)","THE LAST CONTRACT"
580 PRINT
590 A7=A(7%):A(7%)=INT(A(7%)/1.E6)
600 PRINT A$(X%);A((X%+1%)/2%),A$(X%+1%);B((X%+1%)/2%)
    FOR X%=1% TO 17% STEP 2%
610 A(7%)=A7:A7=0
770 PRINT CHR$(11%)
790 PRINT "GENERAL INFORMATION"
800 PRINT
820 PRINT A$(X%+18%);C(X%) FOR X%=1% TO 4%
880 PRINT CHR$(11%)
900 MAT F=B:MAT B=ZER(9%):GOSUB 2880
930 MAT B=F
940 PRINT "COST OF THE OLD CONTRACT -PER WORKER- :"
950 GOSUB 1610:PRINT
980 REM   EXTRA PROFIT
990 U8=(((A(2%)-C(2%))*A(9%))/A(2%))/2.
995 IF U8>0 THEN X2=U8 ELSE X2=0
1000 REM   INFLATION
1010 X3=.01*C(1%)*K9%
1020 PRINT "IN VIEW OF THE COMING STRIKE, IT WAS DECIDED AT THE LAST"
1030 PRINT "MEETING OF THE BOARD OF DIRECTORS THAT THE COMPANY COULD"
1040 PRINT "SUPPORT AN INCREASE IN THE WORKERS' PAYROLL."
1060 IF X2>X3 THEN 1100 ELSE X2=X3
1080 PRINT "DUE TO THE RELATIVELY IMPORTANT INFLATION RATE,"
1090 GOTO 1110
1100 PRINT "THE BOARD IS WILLING TO SHARE THE FIRM'S PROFITS, AND"
1110 &"THE MAXIMUM DOLLAR AMOUNT PROPOSED -PER WORKER-PER YEAR- IS: $";
1120 PRINT INT(X2+.5):PRINT CHR$(11%)
1140 NEXT C7%
1150 IF W5%=5% THEN 1970
1160 C%=0%
1170 PRINT CHR$(11%)
1180 PRINT "***CONTRACT PROPOSAL: WEEK";V%
1200 IF V%=1% THEN 1240
1210 INPUT "ARBITRATION ANYONE";A9$:IF ASCII(A9$)=89% THEN 3040
1240 PRINT "INPUT LABOR'S 9 DECISIONS";:MAT INPUT F
1260 PRINT "INPUT MANAGEMENT'S 9 DECISIONS";:MAT INPUT G
1290 GOSUB 2880
1310 D=(K9%-INT(K9%/10.)*10%)/10.
1320 IF D<1 THEN D=1
1330 A(4%)=A(4%)-INT(T*D*.1)
1340 A(6%)=INT(A(6%)-A(4%)*8%)
1350 A(5%)=INT(A(5%)-A5*D)
1360 PRINT CHR$(11%)
1370 FOR C7%=1% TO C3%
1380 PRINT "*****FIRM";F%,"COPY#";C7%,"WEEK";V%
1390 PRINT CHR$(11%)
1400 PRINT "*****BARGAINING : CONTRACT PROPOSAL"
1410 PRINT:GOSUB 2880
1440 T5%=K9%
1450 PRINT A$(32%)
1460 Q3%=-1%:PRINT:GOSUB 1610:MAT D=F:MAT E=G:MAT F=G:GOSUB 2880
1530 T6%=K9%:PRINT:PRINT
1560 PRINT A$(33%)
1570 PRINT:Q3%=-1%:GOSUB 1610:GOTO 1750
1580 Q3%=-1%:GOSUB 1610:GOTO 1750
1610 PRINT:PRINT A$(34%);:IF Q3% THEN PRINT " INCREASE";
1650 PRINT TAB(30%);"$";K7%
1660 PRINT A$(35%);:IF Q3% THEN PRINT " INCREASE";
1690 PRINT TAB(30%);"$";K9%-K7%
1700 PRINT:PRINT A$(36%);TAB(30%);"$";K9%:PRINT:Q3%=0%:RETURN
1750 MAT F=D:MAT G=E:GOTO 2250
1780 PRINT
1790 IF F(1%)>G(1%) THEN F(1%)=G(1%)
1800 IF F(5%)>G(5%) THEN F(5%)=G(5%)
1810 FOR I%=2% TO 9%:IF I%=5% THEN 1840
1830 IF F(I%)<G(I%) THEN F(I%)=G(I%)
1840 NEXT I%
1850 PRINT TAB(28%);"LABOR","MANAGEMENT":PRINT
1870 FOR I%=1% TO 9%
1880 PRINT A$(I%+22%),
1890 PRINT F(I%),G(I%);:IF F(I%)=G(I%) THEN 2030 ELSE PRINT
1920 NEXT I%
1930 IF C%=9% THEN 2680
1940 PRINT CHR$(11%)
1950 NEXT C7%:V%=V%+1%
1967 F2$,G2$,A2$,B2$,C2$=""
1970 FOR S9%=1% TO 9%
1975 F2$=FNR$(F2$,F(S9%)):G2$=FNR$(G2$,G(S9%)):A2$=FNR$(A2$,A(S9%))
1980 B2$=FNR$(B2$,B(S9%)):IF S9%<5% THEN C2$=FNR$(C2$,C(S9%))
1981 NEXT S9%
1982 LSET F1$=F2$:LSET G1$=G2$:LSET A1$=A2$:LSET B1$=B2$:LSET C1$=C2$
1983 LSET V$=CVT%$(V%):LSET T$=CVTF$(T):LsET I5$=CVTF$(I5)
1984 LSET A6$=CVTF$(A6):LSET A5$=CVTF$(A5):LSET X2$=CVTF$(X2)
1985 LSET C9$=CVTF$(C9):LSET W5$=CVT%$(W5%):LSET C3$=CVT%$(C3%)
1986 LSET A$=CVT%$(A%):LSET B$=CVT%$(B%)
1987 F2$,G2$,A2$,B2$,C2$=""
1990 PUT #1%,RECORD F%
2000 IF W5%=5% THEN 3130 ELSE 50
2030 PRINT,"***AGREEMENT":C%=C%+1%:GOTO 1920
2250 PRINT CHR$(11%)
2260 PRINT "***INFORMATION ON THE CURRENT SITUATION :"
2270 PRINT
2290 PRINT A$(37%),A(4%),"DOWN";
2295 pRINT INT((T-A(4%))/T*100%+.5);"%"
2300 PRINT A$(38%),A(6%),"DOWN";
2310 PRINT INT((A6-A(6%))/A6*100%+.5);"%":PRINT
2320 PRINT A$(39%),"$";
2325 IF A(5%)>0 THEN U8=A(5%) ELSE U8=0
2327 PRINT INT(U8/T+.5)
2330 IF A(5%)<0% THEN U=ABS(A(5%)) ELSE U=0
2340 PRINT A$(40%),,"$";INT(U/T+.5):PRINT
2360 PRINT A$(41%);
2370 C8%=INT((A(8%)*A5*D)/A(7%)+.5)
2380 C9=C9+C8%:C8%=INT(C8%/T)
2400 PRINT "      $";C8%
2410 IF V%<>5% THEN 2450
2420 PRINT "WARNING TO LABOR!  WORKERS ARE GETTING TIRED OF"
2430 PRINT "THE STRIKE AND MIGHT SOON VOTE TO END IT.":GOTO 2490
2450 IF V%<>4% THEN 2490
2460 PRINT "WARNING TO MANAGEMENT! THE STRIKE IS GETTING"
2470 PRINT "REALLY EXPENSIVE, THE BOARD OF DIRECTORS MIGHT GIVE IN SOON"
2490 PRINT
2500 IF V%<=5% THEN 2520
2510 IF (T-A(4%))/T>.2 THEN 2550
2520 IF T5%<X2 THEN 2760
2530 IF A(6%)<A(4%)*6% THEN 2580
2540 GOTO 2810
2550 PRINT "LABOR'S MEMBERSHIP LOSSES HAVE REACHED";(T-A(4%))/T
2560 PRINT "THE UNION CANNOT CONTINUE THE STRIKE.":GOTO 2600
2580 PRINT "THE UNION STRIKE FUND IS TOO LOW !!! THERE IS NO OTHER"
2590 PRINT "ALTERNATIVE :"
2600 PRINT "LABOR ACCEPTS MANAGEMENT'S OFFER, AND THE NEW CONTRACT IS:"
2605 MAT F=G
2610 Q3%=-1%
2620 FOR I%=1% TO 9%
2630 PRINT A$(I%+22%),
2640 PRINT F(I%)
2650 NEXT I%
2660 GOSUB 2880:GOSUB 1610
2690 PRINT "THE STRIKE IS ENDED AFTER";V%;"WEEKS. CONGRATULATIONS!"
2700 PRINT "THE STRIKE HAS BEEN EXPENSIVE!"
2710 IF A(5%)<0% THEN U=ABS(A(5%)) ELSE U=0
2720 PRINT "IT HAS COST MANAGEMENT $";C9;" AND $";INT(U);"IN UNFILLED"
2730 PRINT "ORDERS. LABOR HAS PAID $"A6-A(6%);"AND HAS SUFFERED"
2740 PRINT INT((T-A(4%))/T*100%+.5);"% OF MEMBERSHIP LOSSES...."
2750 CLOSE 1%,2%
2755 GOTO 3140
2760 PRINT "UNION'S DEMANDS ARE WITHIN THE AMOUNT THAT MANAGEMENT"
2770 PRINT "IS WILLING TO OFFER :"
2780 PRINT "MANAGEMENT ACCEPTS LABOR'S DEMANDS. THE NEW CONTRACT IS :"
2790 GOTO 2610
2810 PRINT "THE STRIKE HAS BEEN ON FOR";V%;"WEEK";
2820 IF V%>1% THEN PRINT "S." ELSE PRINT "."
2830 GOTO 1780
2880 K1=F(2%)-B(2%)
2890 K2=B(5%)-F(5%)
2900 IF ABS(K2)>30% THEN K2=K2*-1%
2910 K4=F(4%)+F(8%)-B(4%)-B(8%)
2920 K5=(365%-F(4%)-F(6%)-F(8%))/7.
2930 K3=((F(3%)-B(3%))*F(9%)+B(3%)*(F(9%)-B(9%)))*K5
2940 K6=F(7%)-B(7%)
2950 K7%=INT((K1*F(5%)+F(2%)*K2)*K5)
2970 K8=K4*F(5%)/7.*F(2%)
2980 K9%=INT(K3+K6+K7%+K8+.5)
3000 RETURN
3010 PRINT "LABOR AND MANAGEMENT HAVE AGREED ON ALL ISSUES. THE STRIKE"
3020 PRINT "IS OVER AND THE NEW CONTRACT IS :":GOTO 2610
3040 PRINT "ARBITRATOR ";
3050 PRINT "DECISIONS ARE FINAL AND MUST BE ACCEPTED BY BOTH PARTIES..."
3060 PRINT,"THE NEW CONTRACT IS"
3070 FOR I%=1% TO 9%:U6%,U7%,U8%,U9%=0%
3080 IF F(I%)<=G(I%) THEN U9%=1%
3082 IF I%<>2% AND I%<>9% THEN U8%=1%
3084 IF U8%=0% THEN U7%=1%
3086 IF U9%=0% THEN U6%=1%
3088 U5=G(I%)*(1%+X2/C9)*U6%:IF U5>F(I%) THEN U5=F(I%)
3090 U5=U5+F(I%)*U9%:F(I%)=U5:U5=0
3092 F(I%)=INT(F(I%)+.5)*U8%+INT(F(I%)*100%+.5)/100.*U7%
3094 U6%,U7%,U8%,U9%=0%
3100 NEXT I%
3110 F(5%)=G(5%)
3120 GOTO 2610
3130 CLOSE 1%,2%
3140 END