3  REM       LEASIN:    LEASE INCOME
10  PRINT "ON AN ANNUAL BASIS OF SHIPMENTS OVER 'Y' YEARS, THIS PROGRAM"
15 PRINT "WILL CALCULATE LEASE INCOME BASED ON A VARIABLE-LENGTH"
20 PRINT 'PRODUCT LIFE (LEASE PERIOD).     ....R.T. BARCK 5/17/71'
30 PRINT "LEASE PERIOD IN YEARS IS";
35 DIM R(50), S(50),  A(50), X(50), U(50)
40 INPUT L
42 PRINT "WE WILL MANUFACTURE PRODUCTS FOR Y YEARS; Y =";
43 INPUT Y
45 PRINT "ANNUAL SHIPMENTS IN UNITS BY YEAR FOR YEARS 1 TO";
46 PRINT Y;
47 PRINT "ARE"
50 FOR I=1 TO Y
60 PRINT I,
90 INPUT U(I)
100 NEXT I
110 PRINT "ENTER AVG  SALES PRICE IN $ 000 FOR EACH YEAR SYSTEMS ARE"
112 PRINT "INSTALLED AND FOR ALL YEARS SYSTEMS REMAIN ON LEASE"
114 PRINT "YEAR","SALES PRICE"
116 FOR I=1 TO (Y+L)
118 PRINT I,
120 INPUT S(I)
123 NEXT I
125 PRINT "ENTER AVG LEASE RATE IN % OF SALES PRICE PER MONTH (W/O SERVICE)"
127 PRINT "FOR EACH YEAR SYSTEMS ARE INSTALLED AND REMAIN ON LEASE"
129 PRINT "YEAR","LEASE RATE"
130 FOR I=1 TO (Y+L)
135 PRINT I,
140 INPUT R(I)
145 NEXT I
167 GOSUB 500
170 FOR I=1 TO  (Y+L)
175 A(I)=R(I)*S(I)*12/100*X(I)
180 NEXT I
181 PRINT
182 PRINT "ANNUAL INCOME FOR THIS PRODUCT WILL BE:"
185 PRINT "YEAR","INCOME"
190 FOR I=1 TO (Y+L)
200 PRINT I,A(I)
210 NEXT I
220 GOTO 600
500 FOR I=1 TO Y+L
505 B=I
510 IF I<Y THEN 520
515 B=Y
520 L1=I-L+1
525 IF L1>0 THEN 550
530 L1=1
550X(I)=0
560 FOR C=L1 TO B
570 X(I)=U(C)+X(I)
575 NEXT C
580 NEXT I
590 RETURN
600 END