10 REM***********LAWRENCE A. DZIEGIELEWSKI********************
20 REM                   ACCMAT.BAS
30 REM              ACCOUNT MAINTENCE FILE
40 REM******************PROJECT DELTA*************************
50 PRINT 'ACCMAT VER 4-C'
60 PRINT '           ACCMAT-ACCOUNT MAINTENCE FILE'
70 INPUT'WHAT IS YOUR USER NUMBER';X,X1
80 INPUT'INSTRUCTIONS';G$
90 IF G$='YES' GOTO 100 ELSE 200
100 PRINT '		P-CHANGES PROTECTION CODES'
110 PRINT '		R-RENAMES THE INDICATED FILE'
120 PRINT '		D-KILLS THE INDICATED FILE'
130 PRINT '		T-TRANSFERS THE INDICATED FILE TO AN'
140 PRINT '		  OUTPUT FILE WITHOUT KILLING THE'
150 PRINT '		  SOURCE FILE'
160 PRINT '		L-LISTS THE INDICATED FILE'
170 INPUT'DO YOU NEED FURTHER INSTRUCTIONS';B3$
180 IF B3$='YES' THEN GOTO 190 ELSE 200
190 PRINT 'FURTHER INSTRUCTIONS CAN BE FOUND IN ACCMAT.DOC'
200 OPEN 'KB:' FOR INPUT AS FILE 1%
210 ON ERROR GOTO 730
220 DIM A%(30)
230 DEF FNA $(A$)=RAD$(SWAP%(CVT$%(A$)))
240 FOR A%=0 TO 1000
250 A$=SYS(CHR$(6)+CHR$(15)+CHR$(A%))
260 CHANGE A$ TO A%
270 A1$=FNA$(CHR$(A%(7))+CHR$(A%(8)))+FNA$(CHR$(A%(9))+CHR$(A%(10)))+
    '.'+FNA$(CHR$(A%(11))+CHR$(A%(12)))
280 PRINT A1$,A%(13),'<'A%(15)'>'
290 PRINT 'OPTION:';:INPUT#1%,A2$
300 IF CHR$(ASCII(A2$))='T' GOTO390
310 IF CHR$(ASCII(A2$))='L' GOTO 510
320 IF CHR$(ASCII(A2$))='R' GOTO 650
330 IF CHR$(ASCII(A2$))='D' GOTO 340 ELSE 350
340 KILL A1$ UNLESS A1$='ACCMAT.BAS':A%=A%-1:GOTO 700
350 IF CHR$(ASCII(A2$))='D' THEN KILL A1$ UNLESS A1$='ACCMAT.BAS':
    A%=A%-1: GOTO 700
360 IF CHR$(ASCII(A2$))='P' GOTO 610
370 GOTO700
380 REM************TRANSFER***********
390 PRINT 'FILE TO OUTPUT TO:';:INPUT#1%,B$
400 OPEN A1$ FOR INPUT AS FILE 2%
410 OPEN B$ FOR OUTPUT AS FILE 3%
420 FOR B%= 1 TO 32767
430 INPUT LINE #2%,D$
440 PRINT #3%;D$;
450 NEXTB%
460 Z$=SYS(CHR$(0))
470 PRINT ' TOTAL OF 'B%-1%' LINES TRANSFERED FROM 'A1$' TO 'B$'
480 CLOSE2%,3%
490 GOTO 290
500 REM***************LIST************
510 OPEN A1$ FOR INPUT AS FILE 2%
520 FOR B%= 1 TO 32767
530 INPUT LINE#2%,B$
540 PRINT  B$;
550 NEXTB%
560 Z$=SYS(CHR$(0))
570 PRINT 'TOTAL OF 'B%-1%' LINES IN 'A1$
580 CLOSE2%
590 GOTO290
600 REM***************PROTECTION*************
610 PRINT 'PROTECTION DESIRED:';:INPUT#1%,B%
620 NAME A1$ AS A1$+'<'+MID(NUM$(B%),2%,LEN(NUM$(B%))-1%)+'>'
630 PRINT A1$' PROTECTED AT <'B%'>'
640 GOTO 290
650 REM*********RENAMES**********
660 PRINT 'RENAME (INCLUDE NAME.EXT):';:INPUT#1%,Z1$
670 NAME A1$ AS Z1$
680 PRINT A1$ ' RENAMED AS 'Z1$
690 GOTO 290
700 Z%=Z%+1
710 NEXT A%
720 REM*********ERROR HANDLING ROUTINE********
730 IF ERR=11 AND ERL<500 THEN RESUME 470
740 IF ERR= 2 AND ERL=660 THEN PRINT 'ILLEGAL FILE NAME':RESUME 290
750 IF ERR=52 AND ERL<690 THEN RESUME 290
760 IF ERR=11 AND ERL>500 THEN RESUME 570
770 IF ERR=47 AND ERL=530 THEN RESUME 290
780 IF ERR= 5 AND ERL<450 THEN RESUME 830
790 IF ERR= 5 AND ERL=850 THEN RESUME 870
800 IF ERR=10 GOTO 810 ELSE 820
810 PRINT SYS(CHR$(6)+CHR$(9)+CHR$(ERR)):RESUME 290
820 PRINT SYS(CHR$(6)+CHR$(9)+CHR$(ERR)):RESUME 700
830 PRINT 'TOTAL OF 'Z%' FILES WORKED ON'
840 FORB%=0 TO 1000
850 A$=SYS(CHR$(6)+CHR$(15)+CHR$(B%))
860 NEXTB%
870 PRINT ' TOTAL OF 'B%' FILES LEFT ON USER ACCOUNT ['X','X1']'
880 CLOSE1%
890 END
KEY