5 ! BATCHES CASH RECEIPTS OR BANK DEPOSITS AND CREATES OR ADDS TO FILES.
8 ! PROGRAM NAME:"BATCB" - BY JAC
10 OPEN "CR:" FOR INPUT AS FILE 1%:M%=0%
15 OPEN "LP:" FOR OUTPUT AS FILE 2%,MODE 66%
20 K%=1%:GET #1%:FIELD #1%,RECOUNT-2% AS A$
40 IF LEFT(A$,3%)="END" THEN 500
50 IF MID(A$,20%,12%)="BANK DEPOSIT" THEN 100
60 OPEN "DK1:ACCREC.CSH" AS FILE 3%  ! BATCH CASH RECEIPTS
80 M%=-1%:DIM #3%,C1$(500%)=64%,C%(0%):C%=C%(0%)
95 GOTO 140
100 OPEN "DK1:ACCREC.BNK" AS FILE 3%      ! BATCH BANK DEPOSITS
120 DIM #3%,B1$(250%)=64%,B%(0%):B%=B%(0%)
140 J%=1%:L%=0%:Q$="#,###,###.##":GOSUB400
141 DEF FNZ$(A,B%)
142 IF ABS(A)<1E+6 THEN FNZ$=LEFT(NUM$(A)+SPACE$(B%-LEN(NUM$(A))),B%):GOTO 148
143 A1=FIX(A/1E+6):A2=((A/1E+6)-A1)*1E+6:A3$=NUM$(A1):A4$=RIGHT(NUM$(A2),2%)
144 IF LEN(A4$)<7% THEN A4$="0"+A4$:GOTO 144
145 A3$=LEFT(A3$,INSTR(2%,A3$," ")-1%)+A4$:FNZ$=LEFT(A3$+SPACE$(B%-LEN(A3$)),B%)
148 FNEND
150 D1$=MID(A$,3%,2%)+"-"+MID(A$,5%,2%)+"-7"+MID(A$,7%,1%)
170 D$=MID(A$,14%,20%):A1$=MID(A$,40%,7%):A2$=MID(A$,47%,1%)
180 ON ERROR GOTO 700
185 N%=1%
190 A=(VAL(A1$)*10%+VAL(A2$))*N%
200 B2$=MID(A$,76%,4%):F$=MID(A$,51%,2%):B$=MID(A$,58%,6%)
210 C$=MID(A$,48%,3%)+"-"+F$+"-"+MID(A$,53%,1%)+"-"+MID(A$,54%,4%)+"-"
220 C$=C$+LEFT(B$,4%)+"."+RIGHT(B$,5%):R$=MID(A$,64%,5%)
230 T1=T1+A:T2=T2+VAL(F$):T3=T3+VAL(B$)
240 IF B$="223000" THEN T4=T4+A
250 PRINT #2%,TAB(11%);D1$;"  ";D$;TAB(56%);
260 PRINT #2%,USING Q$,ABS(A)/100%;
265 IF A<0% THEN PRINT #2%,"CR";
280 PRINT #2%,TAB(73%);R$;TAB(91%);C$;"  ";B2$
290 T$=MID(A$,3%,5%)+D$+FNZ$(A,9%)+MID(A$,48%,16%)+R$+B2$+MID(A$,80%,1%)
300 IF M% THEN 320
310 B%=B%+1%:B1$(B%)=T$:GOTO 330
320 C%=C%+1%:C1$(C%)=T$
330 L%=L%+1%:IF L%<52% THEN 350
340 J%=J%+1%:L%=0%:GOSUB 400
350 K%=K%+1%:GET #1%:FIELD #1%,RECOUNT-2% AS A$
370 IF LEFT(A$,3%)="END" THEN 500 ELSE 150
400 PRINT #2%,CHR$(128%+1%)      ! HEADING ROUTING
410 PRINT #2%,TAB(11%);"SCHOOL DISTRICT NO. 91";TAB(51%);
420 IF M%<>-1% THEN 440
430 X$="RECEIPT":PRINT #2%,"CASH RECEIPTS";:GOTO 450
440 X$="REFERENCE":PRINT #2%,"BANK DEPOSITS";
450 PRINT #2%,TAB(86%);DATE$(0%),TAB(111%);"PAGE ";J%:PRINT #2%
470 PRINT #2%,TAB(11%);"  DATE";TAB(71%);X$;TAB(114);"BATCH"
475 PRINT #2%,TAB(11%);"MO-DY-YR  D E S C R I P T I O N";TAB(61%);
478 PRINT #2%,"AMOUNT";TAB(72%);"NUMBER";TAB(99%);"CODE";
480 PRINT #2%,TAB(113%);"NUMBER":PRINT #2%
490 RETURN
500 R$="##,###,###":PRINT #2%,TAB(56%);
510 PRINT #2%,USING Q$,ABS(T1)/100%;
520 IF T1<0% THEN PRINT #2%,"CR*" ELSE PRINT #2%,"  *"
530 PRINT #2%:PRINT #2%,TAB(41%);"HASH FUND TOTAL     ";
550 PRINT #2%,USING R$,T2
560 PRINT #2%,TAB(41%);"HASH CODE TOTAL     ";
570 PRINT #2%,USING R$,T3
580 PRINT #2%,TAB(44%);"TOTAL 223000  ";
590 PRINT #2%,USING Q$,ABS(T4)/100%;:IF T4<0% THEN PRINT #2,"CR";
610 PRINT #2%,TAB(91%);"CARD COUNT",K%-1%:CLOSE 1%,2%
666 INPUT "IS THIS BATCH FILE OK? - Y OR N";B$:IF B$="N" THEN 670
667 IF B$<>"Y" THEN 666
668 IF M% THEN C%(0%)=C% ELSE B%(0%)=B%
670 CLOSE 3%:STOP
700 ! ERROR-HANDLES CREDIT PUNCH
710 IF ERR<>52% THEN ON ERROR GOTO 0
715 IF ASCII(A2$)=125% THEN A2$="I"
720 A2$=CHR$(ASCII(A2$)-25%):N%=-1%
730 RESUME 190
740 END