2 ! FIXES INVOICES, G.J., OR P.O.!
5 ! PROGRAM NAME:"FIXIPG" - BY JAC
10 INPUT "WHICH FILE DO YOU WANT TO FIX? - INV, GJ, OR PO";F$:IF F$<>"INV"
	AND F$<>"GJ" AND F$<>"PO" THEN 10
15 OPEN "DK1:ACCPAY."+F$ AS FILE 1%:L%=512%
20 IF F$="INV" THEN F%=151%:O2%=128%:P%=128%:GOTO 35
25 IF F$="GJ" THEN F%=13%:P%=128%:O2%=384%:GOTO 35
30 F%=126%:P%=64%:O2%=64%
35 GET #1%,RECORD F%:FIELD #1%,O2% AS E$,2% AS N$:N%=SWAP%(CVT$%(N$)):
	PRINT "TOTAL ENTRIES IN ";F$,N%
40 INPUT "INDEX";I%:IF I%<0% OR I%>N% THEN 40 ELSE IF I%=0% THEN 70 ELSE
	B%=I%/(L%/P%):O%=(I%-B%*(L%/P%))*P%:B%=B%+1%:W%=0%:GET #1%,RECORD B%:
	FIELD #1%,O% AS E$,P% AS D$:PRINT D$
45 INPUT "ITEM";I$:IF I$="" THEN IF NOT W% THEN 40 ELSE PUT #1%,RECORD B%:
	GOTO 40
50 M%=(INSTR(1%,"VD #PO #CODEDELT",I$)+3%)/4%+1%:ON M% GOTO 45,55,60,65,150
55 O1%=O%+5%:L1%=6%:GOSUB 100:GOTO 45
60 O1%=O%+53%:L1%=5%:GOSUB 100:GOTO 45
65 O1%=O%+37%:L1%=16%:GOSUB 100:GOTO 45
70 GET #1%,RECORD F%:FIELD #1%,O2% AS E$,2% AS N$:LSET N$=CVT%$(SWAP%(N%))
	:PUT #1%,RECORD F%:CLOSE 1%:PRINT "THERE ARE NOW";N%;
	"ENTRIES IN ";F$
75 INPUT "MORE UPDATES? - Y OR N";B$:IF B$="Y" THEN 10 ELSE STOP
100 FIELD #1%,O1% AS E$,L1% AS V$:PRINT I$,V$,:INPUT V1$:IF V1$="" THEN 105
	ELSE LSET V$=V1$:W%=-1%
105 PRINT ,V$:RETURN
150 N%=N%-1%:FOR J%=I% TO N%:B%=J%/(L%/P%)+1%:GET #1%,RECORD B%
155 O%=(J%-(B%-1%)*(L%/P%))*P%:IF O%<L%-P% THEN FIELD #1%,O% AS E$,P% AS V$,
	P% AS V1$:LSET V$=V1$:J%=J%+1%:IF J%<=N% THEN 155 ELSE 165
160 PUT #1%,RECORD B%:GET #1%,RECORD B%+1%:FIELD #1%,P% AS V1$:V2$=V1$+"":
	GET #1%,RECORD B%:FIELD #1%,O% AS E$,P% AS V$:LSET V$=V2$
165 PUT #1%,RECORD B%:NEXT J%:GOTO 40
170 END