2 ! PRINTS REVENUE AND EXPENDITURE REPORT!
5 ! PROGRAM NAME:"PRTREX" - BY JAC.
10 INPUT "MONTH NUMBER";M;"INPUT DATE";:INPUT LINE D1$:M%=2%:W%=1%:T0%=100%:
	D1$=LEFT(D1$,LEN(D1$)-2%):Q1$="#,###,###.##\ \   ":IF M<7 THEN M=6+M 
	ELSE M=M-6
15 OPEN "LP:" FOR OUTPUT AS FILE W%,MODE 66%:Q$=SPACE$(10%)+"\  \    \"+
	SPACE$(19%)+"\         "+Q1$+Q1$+Q1$+Q1$+"  ###.#%":M=(M/12%)*T0%
20 OPEN "DK1:GLFILE.MBK" AS FILE M%,RECORDSIZE 1024%:GET #M%,RECORD 500%:
	FIELD #M%,576% AS E$,M% AS G$:G%=SWAP%(CVT$%(G$)):B%=500%
25 OPEN "DK1:GLFILE.FND" AS FILE 3%:GET #3%,RECORD M%:FIELD #3%,160% AS E$,
	M% AS F1$:F%=SWAP%(CVT$%(F1$)):B2%=M%
30 OPEN "DK1:GLFILE.BDT" AS FILE 4%:GET #4%,RECORD 38%:FIELD #4%,288% AS E$,
	M% AS B$:N%=SWAP%(CVT$%(B$)):B4%=38%:A$="CR ":A1$="   ":
	U$="CR*":U1$="  *"
35 FOR K0%=W% TO 4%:J%=0%:H%=W%:FOR K%=W% TO G%:GOSUB 300:GOTO 90 IF B$>="1800":
	FOR I%=H% TO F%:B3%=I%/16%+W%:IFB2%<>B3% THEN GET #3%,RECORD B3%:B2%=B3%
40 O1%=(I%-(B2%-W%)*16%)*32%:FIELD #3%,O1% AS E$,M% AS F1$,30% AS D2$:GOTO 45
	IF F$=F1$:NEXT I%:D2$="FUND "+F$:I%=W%
45 H%=I%:H1%=W%:GOSUB 400:GOTO 65 IF B$>="0100":PRINT #W%,TAB(20%);"REVENUES":
	PRINT #W%:GOSUB 320:B1,E1,O1,B,E,O,R=0:Z%=W%:Z1%=-W%
50 GOSUB 290:K%=K%+W%:GOTO 55 IF K%>G%:B2$=B1$+"":GOSUB 300:GOTO 55 IF F$<>F1$: 
	GOTO 50 IF LEFT(B$,3%)=B2$
55 B4$=B2$+"0":GOSUB 200:GOSUB 350:GOSUB 340:B,E=0:GOTO 60 IF K%>G% OR F$<>F1$:
	GOTO 50 IF B$<"0100"
60 GOSUB 250:GOSUB 340:PRINT #W%:PRINT #W%:R=E:E=0:GOSUB 320:GOTO 85
	IF B$>="1800" OR K%>G% OR F$<>F1$
65 PRINT #W%,TAB(20%);"EXPENDITURES":PRINT #W%:GOSUB 320:B1,E1,O1,B,E,O=0:
	Z%=0%:Z1%=W%
70 GOSUB 290:O=O+VAL(O$):K%=K%+W%:GOTO 75 IF K%>G%:B2$=B1$+"":GOSUB 300:GOTO 75 
	IF F$<>F1$:GOTO 70 IF LEFT(B$,M%)=B2$
75 B4$=B2$+"00":O1=O1+O:GOSUB 200:GOSUB 350:GOSUB 340:B,O,E=0:GOTO 80 IF K%>G%
	OR F$<>F1$:GOTO 70 IF B$<"1800"
80 GOSUB 250:GOSUB 340
85 PRINT #W%:PRINT #W%,TAB(79%);"SUMMARY CASH BASIS:  REVENUES";TAB(114%);:C=-R:
	GOSUB 380:PRINT #W%,TAB(T0%);"EXPENDITURES  ";:C=E:GOSUB 380:PRINT #W%,
	TAB(114%);"--------------":PRINT #W%,TAB(90%);"**OPERATIONAL RESULTS** "
	;:C=-R-E:GOSUB 380
86 R,E=0:K%=K%-W% IF F$<>F1$ OR K%>G%
90 NEXT K%:NEXT K0%:CLOSE 1%,2%,3%,4%:STOP
200 B1=B1+B:E1=E1+E:IF Z1%*E<0 THEN C1$=A$ ELSE C1$=A1$
202 IF O<0 THEN C3$=A$ ELSE C3$=A1$
205 IF B=0 THEN P=0:A=0:C$=A1$:C2$=A1$:GOTO 220
210 A=B*T0%-E-O:IF Z1%*A<0 THEN C2$=A$ ELSE C2$=A1$
215 P=(E+O)/(B*T0%)*T0%:IF Z1%*B<0 THEN C$=A$ ELSE C$=A1$
220 RETURN
250 E=E1:B=B1:O=O1:IF Z1%*E<0 THEN C1$=U$ ELSE C1$=U1$
252 IF O<0 THEN C3$=U$ ELSE C3$=U1$
255 IF B=0 THEN P=0:A=0:C$=U1$:C2$=U1$:GOTO 270
260 A=B*T0%-E-O:IF Z1%*A<0 THEN C2$=U$ ELSE C2$=U1$
265 P=(E+O)/(B*T0%)*T0%:IF Z1%*B<0 THEN C$=U$ ELSE C$=U1$
270 B4$="    ":D$=SPACE$(21%):RETURN
290 FIELD #M%,O%+3% AS E$,M% AS F$,5% AS E$,M%+Z% AS B1$,M%-Z%+23% AS E$,
	10% AS E1$,8% AS O$,8% AS B3$:B=B+VAL(B3$):E=E+VAL(E1$):RETURN
300 B1%=K%/16%+W%:IF B1%<>B% THEN GET #M%,RECORD M%*B1%-W%:B%=B1%
305 O%=(K%-(B%-W%)*16%)*64%:FIELD #M%,O%+3% AS E$,M% AS F$,5% AS E$,
	4% AS B$:RETURN
320 L%=L%+M%:GOSUB 400 IF L%>54%:RETURN
340 PRINT #W%,USING Q$,B4$,D$,ABS(B),C$,ABS(E)/T0%,C1$,ABS(O)/T0%,C3$,
	ABS(A)/T0%,C2$,P:PRINT #W%:GOSUB 320:RETURN
350 B5$=B4$+"00":FOR I%=H1% TO N%:B5%=I%/16%+W%:IF B5%<>B4% THEN GET #4%,
	RECORD B5%:B4%=B5%
355 O2%=(I%-(B4%-W%)*16%)*32%:FIELD #4%,O2% AS E$,6% AS B6$,21% AS D$:GOTO 360
	IF B6$=B5$:NEXT I%:D$=SPACE$(21%):I%=W%
360 H1%=I%:RETURN
380 IF C<0 THEN C$=U$ ELSE C$=U1$
385 PRINT #W%,USING Q1$,ABS(C)/T0%,C$:RETURN
400 PRINT #W%,CHR$(130%):J%=J%+W%:L%=0%
405 PRINT #W%,TAB(5%);D2$;TAB(50%);"REVENUE AND EXPENDITURE REPORT";TAB(90%);D1$
	;TAB(115%);"PAGE ";J%:PRINT #W%,TAB(54%);"SCHOOL DISTRICT NO. 91":
	PRINT #W%,USING SPACE$(52%)+"###.#% FISCAL YEAR EXPIRED",M
410 PRINT #W%,TAB(9%);"BUDGET";TAB(54%);"BUDGET";TAB(70%);"RECEIVED/";TAB(104%);
	"BALANCE DUE"
415 PRINT #W%,TAB(10%);"CODE    D E S C R I P T I O N";TAB(54%);"AMOUNT";
	TAB(70%);"EXPENDED";TAB(85%);"OBLIGATIONS";TAB(103%);"OR EXPENDABLE";
	"     PERCENT":PRINT #W%:RETURN
420 END