10 REM COMPUTER DATING PROGRAM (DECUS 11-56) BY DAVID CORBISHLEY
20 REM 4/21/72.  REVISED 10/26/74.
30 PRINT "COMPUTER DATING (DECUS 11-56) V02-02 "DATE$(0%)" "TIME$(0%)
40 OPEN "KB:" FOR INPUT AS FILE 1%
50 INPUT #1%,"NAME OF MALE DATA FILE:"A$
60 INPUT #1%,"NAME OF FEMALE DATA FILE:"B$
70 INPUT #1%,"OUTPUT FILE OR DEVICE:"C$
80 INPUT #1%,"NUMBER OF QUESTIONS ON QUESTIONAIRE:"A%
90 INPUT #1%,"NUMBER OF MALES:"B%
100 INPUT #1%,"NUMBER OF FEMALES:"C%
110 INPUT #1%,"PERCENTAGE FOR SELECTIVE PRINTING:"D%
120 INPUT #1%,"COMPARE MALES TO FEMALES?(YES OR NO)"D$
130 CLOSE 1%
140 DIM F%(12%),G%(12%)
150 OPEN A$ FOR INPUT AS FILE 2%
160 OPEN B$ FOR INPUT AS FILE 3%
170 OPEN C$ FOR OUTPUT AS FILE 4%
180 IF D$="YES" THEN 260
190 Z%=B%
200 B%=C%
210 C%=Z%
220 CLOSE 2%
230 CLOSE 3%
240 OPEN A$ FOR INPUT AS FILE 3%
250 OPEN B$ FOR INPUT AS FILE 2%
260 FOR H%=1% TO B%
270 INPUT LINE #2%,E$
280 CHANGE E$ TO F%
290 FOR I%=1% TO C%
300 INPUT LINE #3%,F$
310 CHANGE F$ TO G%
320 J%=0%
330 FOR K%=1% TO A%
340 IF F%(K%)=G%(K%) THEN J%=J%+1%
350 IF F%(K%)=32% AND G%(K%)=32% THEN 370
360 IF F%(K%)=32% OR G%(K%)=32% THEN J%=J%+1%
370 NEXT K%
380 M=J%:N=A%
390 L%=M/N*100
400 IF L%<D% THEN 450
410 IF D$="YES" THEN 440
420 PRINT #4%,"FEMALE# "H%" HAS A COMPATABLITY OF "L%" WITH MALE# "I%
430 GO TO 450
440 PRINT #4%,"MALE "H%" HAS A COMPATABILITY OF "L%" WITH FEMALE# "I%
450 NEXT I%
460 CLOSE 3%
470 IF D$="YES" THEN OPEN B$ FOR INPUT AS FILE 3% ELSE OPEN A$ AS FILE
    3%
480 NEXT H%
490 PRINT "DONE"
500 CLOSE 2%,3%,4%
510 END
KEY