5   PRINT :PRINT:PRINT "LIST THIS PROGRAM FOR INSTRUCTIONS":
     PRINT:PRINT
10  REM-STATISTICS PROGRAM
20  REM-TREND ANALYSIS USING THE EXPONENTIAL LEAST SQUARES METHOD
30  REM-REQUIRED INPUT
40  REM-              1) YEAR OF BEGINNING DATA
50  REM-              2) YEAR OF ENDING DATA
60  REM-              3) DATA FOR THE YEARS OF ANALYSIS
70  REM-
80  REM-
90  REM-MATRIX T CONTAINS THE FOLLOWING:
100  REM-               T(1) CONTAINS THE SUM OF THE X'S
110  REM-               T(2) CONTAINTHE SUM OF THE LOGY'S
120  REM-               T(3) CONTAINS THE SUM OF THE X^2'S
130  REM-               T(4) CONTAINS THE SUM OF THE XLOGY'S
140  REM-
150  REM-
160  REM-MATRIX A CONTAINS THE FOLLOWING:
170  REM-               A(Z,1) CONTAINS THE ASSIGNED X VALUES
180  REM-               A(Z,2) CONTAINS THE INPUTTED Y VALUES
190  REM-               A(Z,3) CONTAINS LOGY
200  REM-               A(Z,4) CONTAINS X SQUARED
210  REM-               A(5,5) CONTIANS XLOGY
220  REM-               A(Z, CONTAINS THE EXPECTED VALUES OF Y (Y')
230  REM-                       USING THE EQUATION Y'=A*B^X
240  REM-
250  REM-
260  DIM T(4),A(200,6)
270  MAT T=ZER
280  PRINT 
290  PRINT 
300  PRINT "WHAT IS THE BEGINNING YEAR OF YOUR DATA";
310  INPUT B3
320  PRINT "WHAT IS THE ENDING YEAR";
330  INPUT E
340  REM-CALCULATE NUMBER OF PERIODS OF DATA
350  N=ABS(E-B3+1)
360  B1=B3
370  REM-IS THERE AN EVEN NUMBER OF YEARS (YES THEN GO TO LINE#460)
380  IF N/2=INT(N/2) THEN 460
390  REM-ASSIGN VUES TO X FOR ODD  NUMBER OF YEARS
400  X=-(N-1)/2
410  FOR Z=1 TO N
420  A(Z,1)=X
430  X=X+1
440  NEXT Z
450  GOTO 520
460  REM-ASSIGN VALUES TO X FOR EVEN NUMBER OF YEARS
470  X=-(N-1)
480  FOR Z=1 TO N
490  A(Z,1)=X
500  X=X+2
510  NEXT Z
520  PRINT 
530  PRINT 
540  PRINT 
550  PRINT 
560  PRINT "YEAR        YVALUE"
570  PRINT "====        ======"
580  FOR Z=1 TO N
590  PRINT B1;
600  REM-INPUT THE VALUE OF Y FOR EACH PERIOD
610  INPUT A(Z,2)
620  B1=B1+1
630  REM-FIND THE VAL OF LOGY
640  A(Z,3)=LOG(A(Z,2))/LOG(10)
650  A(Z,3)=INT(A(Z,3)*10000+.5)/10000
660  REM-FIND THE VALUE OF X SQUARED AND ROUND TO THE NEAREST 100TH
670  A(Z,4)=INT(A(Z,1)^2*100+.5)/100
680  REM-FIND THE VALUE OF XLOGY AND ROUND TO THE NEAREST 10,000TH
690  A(Z,5)=INT(A(Z,1)*A(Z,3)*10000+.5)/10000
700  REM-TOTAL THE X'S, LOGY'S, X^2'S, AND THE XLOGY'S
710  T(1)=T(1)+A(Z,1)
720  T(2)=T(2)+A(Z,3)
730  T(3)=T(3)+A(Z,4)
740  T(4)=T(4)+A(Z,5)
750  NEXT Z
760  REM-CALCULATE THE LOG OF A (BASE TEN)770  REM-      FORMULA FOR A IS
780  REM-              A=SUM OF THE LOGY'S DIVIDED BY N(NUMBER OF PERIODS)
790  A=T(2)/N
800  REM-CALCULATE THE  LOG OF B (BASE TEN)
810  REM-      FORMULA FOR B IS
820  REM-              B=SUM OF XLOGY'S DIVIDED BY SUM OF X^2'S
830  B=T(4)/T(3)
840  PRINT 
850  PRINT 
860  PRINT 
870  PRINT "********************************************************";
880  PRINT "***************"
890  PRINT " YEAR";TAB(11);"X";TAB(18);"Y";TAB(27);"LOGY";TAB(41);"X^2";
900  PRI TAB(48);"XLOGY";TAB(62);"Y'"
910  PRINT "********************************************************";
920  PRINT "***************"
930  FOR Z=1 TO N
940  REM-CALCULATE Y' FOR THE PERIOD
950  A(Z,6)=A+A(Z,1)*B
960  A(Z,6)=INT(10^A(Z,6)*10000+.5)/10000
970  PRINT B3;TAB(10);A(Z,1);TAB(16);A(Z,2);TAB(25);A(Z,3);TAB(40);
980  PRINT A(Z,4);TAB(46);A(Z,5);TAB(58);A(Z,6)
990  B3=B3+1
1000  NEXT Z
1010  PRINT "********************************************************";
1020  PRINT "***************"
10  PRINT "TOTALS";TAB(10);T(1);TAB(25);T(2);TAB(40);T(3);TAB(46);T(4)
1040  PRINT "********************************************************";
1050  PRINT "***************"
1060  PRINT 
1070  PRINT 
1080  PRINT "THE EQUATION FOR YOUR DATA IS:"
1090  PRINT "      Y'=A*B^X"
1100  REM-FIND THE ANTI-LOG OF A
1110  A=10^A
1120  REM-FIND THE ANTI-LOG OF B
1130  B=10^B
1140  PRINT "WITH  A EQUAL TO "A
1150  PRINT "      B EQUAL TO "B
1160  END