1 GO TO 605
300  LET H=0
305  PRINT 
310  PRINT 
315  PRINT "ARITHMETIC MEAN, VARIANCE, AND"
320  PRINT "      STANDARD DEVIATION"
325  PRINT 
330  READ C
335  LET H=H+1
340  IF C=1.70141E+38 THEN 835
345  LET S1=0
350  LET S2=0
355  IF C <> 0 THEN 435
360  PRINT 
365  PRINT "FOR GROUPED DATA SET";H
370  PRINT 
375  READ Q
380  LET N=0
385  PRINT "X-VALUE","FREQUENCY"
390  PRINT 
395  FOR P=1 TO Q
400  READ X,M
405  LET N=N+M
410  LET S1=S1+M*X
415  LET S2=S2+M*X*X
420  PRINT X,
425  NEXT P
430  GOTO 505
435  PRINT 
440  PRINT 
445  PRINT "INDIVIDUAL SET NUMBER";H
450  PRINT 
455  PRINT "SAMPLE VALUES:"
460  PRINT 
465  LET N=C
470  FOR P=1 TO N
475  READ X
480  LET S1=S1+X
485  LET S2=S2+X*X
490  PRINT X;
495  NEXT P
500  PRINT 
505  LET A=S1/N
510  LET V=(S2-A*S1)/N
515  LET V1=V*N/(N-1)
520  PRINT 
525  PRINT "MAXIMUM LIKELIHOOD";
530  GOSUB 601
535  PRINT "      NUMBER OF VALUES = ";N
540  PRINT "       ARITHMETIC MEAN = ";A
545  PRINT "    STANDARDEVIATION = ";SQR(V)
550  PRINT "       SAMPLE VARIANCE = ";V
555  PRINT 
560  PRINT "UNBIASED";
565  GOSUB 601
575  PRINT "       ARITHMETIC MEAN = ";A
580  PRINT "    STANDARD DEVIATION = ";SQR(V1)
585  PRINT "              VARIANCE = ";V1
590  PRINT 
595  PRINT 
600  GOTO 330
601  PRINT " ESTIMATES"
602  PRINT "OF POPULATION PARAMETERS"
603  PRINT 
604  RETURN 
605  PRINT 
610  PRINT "THIS PROGRAM CALCULATES THE MEAN, VARIANCE, AND STANDARD"
615  PRINT "DEVIATION FOR EACH OF SEVERAL SS OF INDIVIDUAL VALUES"
620  PRINT "OR FREQUENCY DISTRIBUTIONS."
625  PRINT 
630  PRINT "DATA FOR EACH SET OF INDIVIDUAL VALUES IS ENTERED INTO"
635  PRINT "THE PROGRAM AS FOLLOWS:"
640  PRINT 
645  PRINT "   1 DATA  N, X(1), X(2), X(3),....., X(N)"
650  PRINT 
655  PRINT "WHERE THE N VALUES OF THE SET ARE X(1) THRU X(N).  IF"
660  PRINT "NEEDED, ADDITIONAL DATA STATEMENTS MAY BE USED TO GIVE"
665  PRINT "THE ENTIRE LIST OF VALUES.   ADDITIONAL CASES MAY BE"
670  PRINT "GIVEN IN SUBSEQUENT DA STATEMENTS IN THE SAME FORMAT."
675  PRINT 
680  PRINT "THE INPUT FOR GROUPED VALUES HAS THE FOLLOWING FORMAT:"
685  PRINT 
690  PRINT "   1 DATA 0, N, X(1), F(1), X(2), F(2),..., X(N), F(N)"
695  PRINT 
700  PRINT "WHERE THE INITIAL ZERO SIGNALS GROUPED DATA, THE N IS"
705  PRINT "THE NUMBER OF DIFFERENT VALUES TO BE GIVEN, AND THE F(I)"
710  PRINT "ARE THE NUMBER OF TIMES THE X(I) OCCUR.  DATA STATEMENTS"
715  PRINT "FOLLOWING MAY BE USED TO EXTEND THE LIST AS NECESSARY,"
720  PRINT "AND BLKS OF GROUPED DATA MAY BE INTERMIXED FREELY"
725  PRINT "WITH STRAIGHT LISTS DESCRIBED ABOVE."
730  PRINT 
735  PRINT "AS AN EXAMPLE, SUPPOSE WE WERE INTERESTED IN THE MEAN"
740  PRINT "AND STANDARD DEVIATION OF THE NUMBERS 1,5,4,2,6,7,4,7"
745  PRINT "AND ALSO FOR THE DISTRIBUTION CONSISTING OF 5-1'S,"
750  PRINT "3-4'S, 6-7'S, AND 2-11'S.  THESE TWO CASES COULD BE RUN"
755  PRINT "BY TYPING THE FOLLOWING:"
760  PRINT 
765  PRINT "   1 DATA 8,1,5,4,2"
770  PRINT "   2 DATA 6,7,4,7"
775  PRIN"   3 DATA 0,4,1,5,4,3"
780  PRINT "   4 DATA 7,6,11,2"
785  PRINT "   RUN"
790  PRINT 
795  PRINT "OR EQUIVALENTLY:"
800  PRINT 
805  PRINT "   1 DATA 8,1,5,4,2,6,7,4,7,0,4,1,5,4,3,7,6,11,2"
810  PRINT "   RUN"
815  PRINT 
820  PRINT "NOTE THAT STATEMENT NUMBERS 1 THRU 299 ARE AVAILABLE"
825  PRINT "FOR CONTINUATION OF THE DATA FIELD."
830  DATA 1.70141E+38
835  END