1000 E$="#### ####":
     D$="#### ####^":
     P1$="PLTL":
     P2$="PLTT":
     P3$="PLTP"
1010 D2$="DK0:"
1020 A$="[1,51]"
1030 V$=SYS(CHR$(0)+CHR$(-7))
1040 ON ERROR GOTO 2100 
1050 INPUT "DO YOU ALREADY HAVE A DATA FILE NO(0), YES(1)"; T1%
1060 IF T1%<>1% THEN 1150 
1070 OPEN D2$+"DATA.FIL" AS FILE 5%
1080 OPEN "DATA.FIL" AS FILE 1%
1090 GOSUB 2140 
1100 DIM#5%, F(1023%), G(1023%)
1110 MAT A=F:
     MAT B=G
1120 CLOSE 5%
1130 OPEN "KB:" AS FILE 2%
1140 GO TO 1280 
1150 OPEN "DATA.FIL" AS FILE 1%
1160 OPEN "KB:" AS FILE 2%
1170 GO SUB 2140
1180 A(1023%)=0:
     B(1023%)=0
1190 MAT A=ZER:
     MAT B=ZER
1200 D%=2%
1210 &'INPUT DATA PAIRS IN AN "X,Y" FORMAT'
1220 &'AFTER ALL DATA HAS BEEN ENTERED TYPE A "CTRL Z"'
1230 &"  X,Y  ";
1240 INPUT #2%,A(D%),B(D%)
1250 D%=1%+D%
1260 GOTO 1230
1280 M1,L1=A(2%):
     M2,L2=B(2%)
1281 &"INITIAL DATA SURVEY"
1290 &"PLEASE BE PATIENT!!"
1300 D%=D%-1%
1310 FOR T%=2%TO INT(A(1%))
1320 IF M1<A(T%) THEN M1=A(T%)
1330 IF L1>A(T%) THEN L1=A(T%)
1340 IF M2<B(T%) THEN M2=B(T%)
1350 IF L2>B(T%) THEN L2=B(T%)
1360 NEXT T%
1370 &"THE MININUM X VALUE IS ";L1"
1380 &"DO YOU WISH A DIFFERENT LOWER LIMIT NO(0), YES (1)?";
1390 INPUT#2%,T1%
1400 IF T1%=1% THEN INPUT "NEW LOWER LIMIT(X)";L1
1410 &"THE MAXIMUM X VALUE IS";M1
1420 &"DO YOU WISH A DIFFERENT UPPER LIMIT NO(0), YES(1)?";
1430 INPUT #2%,T1%
1440 IF T1%=1% THEN INPUT"NEW UPPER LIMIT(X)";M1
1450 &"THE MINIMUM Y VALUE IS";L2
1460 &"DO YOU WISH A DIFFERENT LOWER LIMIT NO(0), YES(1)?";
1470 INPUT #2%,T1%
1480 IF T1%=1% THEN INPUT"NEW LOWER LIMIT (Y)";L2
1490 &"THE MAXIMUM Y VALUE IS";M2
1500 &"DO YOU WISH A DIFFERENT UPPER LIMITN0(0), YES(1)?";
1510 INPUT #2%, T1%
1520 IF T1%=1% THEN INPUT "NEW UPPER LIMIT (Y)";M2
1530 S1=(M1-L1):
     S2=(M2-L2)
1540 &"DO YOU WISH TO HAVE AXIS ON YOUR GRAPH;(ONLY VALID IF YOU HAVE A"
1550 INPUT "ZERO X OR Y VALUE NO(0); YES(1)";T1%
1560 IF T1%=1% THEN GOSUB 1730
1570 &P3$
1580 FOR T%= 2% TO INT(A(1%))
1590 IF A(T%)<L1 OR A(T%)>M1 OR B(T%)<L2 OR B(T%)>M2 THEN 1630
1600 X%=(INT(((A(T%)-L1)*9000/S1)+500))
1610 Y%=(INT(((B(T%)-L2)*9000/S2)+500))
1620 &USING E$,X%;Y%
1630 NEXT T%
1640 &USING E$, 0,0
1650 &P2$
1660 &"DO YOU WISH TO SAVE YOUR DATA FILE NO(0), YES(1)";
1670 INPUT T1%:&:&
1680 IF T1%=1% THEN 1690 ELSE KILL"DATA.FIL":STOP
1690 OPEN D2$+"DATA.FIL" AS FILE 3%
1700 DIM #3%,C(1023%),D(1023%)
1710 MAT C=A:
     MAT D=B
1715 CLOSE 1%,2%,3%,4%,5%
1720 KILL "DATA.FIL":
     STOP
1730 INPUT "WHAT STEP OF MARKS ON X AXIS";E1
1740 INPUT "STARTING POINT FOR MARKS ON X AXIS";L
1750 INPUT "WHAT STEP OF MARKS ON Y AXIS";E2
1760 INPUT "STARTING POINT FOR MARKS ON Y AXIS";L3
1770 & P1$
1780 FOR X=500 TO 9500 STEP 9000
1790 Y=((-L2/S2)*9000)+500
1800 &USING E$, X;Y
1810 NEXT X
1820 &P2$
1830 & P1$
1840 FOR Y=500 TO 9500 STEP 9000
1850 X=((-L1/S1)*9000)+500
1860 &USING E$, X;Y
1870 NEXT Y
1880 &P2$
1890 & P1$
1900 FOR W=L TO M1 STEP E1
1910 X=(((W-L1)/S1)*9000)+500
1920 FOR Q=-50 TO 50 STEP 100
1930 Y=((-L2/S2)*9000)+500+(Q)
1940 IF Q=50 THEN & USING E$, X;Y: GOTO 1960 
1950 & USING D$,X;Y
1960 NEXT Q
1970 NEXT W
1980 &P2$
1990 & P1$
2000 FOR J=L3 TO M2 STEP E2
2010 Y=(((J-L2)/S2)*9000)+500
2020 FOR G=-50 TO 50 STEP 100
2030 X=((-L1/S1)*9000)+500+G
2040 IF G=50 THEN & USING E$, X;Y:GO TO 2060 
2050 & USING D$,X;Y
2060 NEXT G
2070 NEXT J
2080 &P2$
2090 RETURN
2100 IF ERR=28% THEN V$=SYS(CHR$(0)):&"READY":
     KILL"DATA.FIL":V$=SYS(CHR$(5)):STOP
2110 IF ERR=11 AND ERL= 1240 THEN A(1%)=D%-1%:RESUME 1280 
2120 IF ERR=59% THEN &"INVALID DATA POINT";: ONERROR GOTO 2100:
     RESUME 1230
2130 STOP
2140 DIM#1%, A(1023%), B(1023%)
2150 RETURN 
2160 END