5	! ADLIST - LIST STUDENT NAMES AND ADDRESSES
10	!	   WRITTEN BY R. BRANTON
100 OPEN "**MASTER" AS FILE  1  : DIM# 1 ,M%(100)
110 OPEN "**MAILER" AS FILE  2  : DIM# 2 ,M$( 1111 )=32
120 OPEN "**SWITCH" AS FILE  3  : DIM# 3 ,S%( 1111 )
130 OPEN "**STINF" AS FILE  4  : DIM# 4 ,S$( 1111 )=32
140 OPEN "**STUDF" AS FILE  5  : DIM# 5 ,L%( 1111 ,2),S1%( 1111 ,10),N( 1111 )
200	& "DO YOU WANT: 1 -A COMPLETE LIST OF NAMES AND ADDRESSES"
210	& "             2 -A LIST OF ADDRESSES RECORDED"
220	& "             3 -A LIST OF ADDRESSES NOT RECORDED"
230	INPUT I% : INPUT "ENTER DEVICE TO PRINT ON";A$
240	OPEN  A$ AS FILE 12
250	B$(1)="ADDRESS LIST" : B$(2)="ADDRESSES RECORDED" : B$(3)="ADDRESSES NOT RECORDED"
300	& #12 : & #12 :& #12,TAB(40);DATE$(0);" ";TIME$(0) : & #12
310	& #12,TAB(30);B$(I%) : & #12
320	& #12," DP#   ST#         NAME                   ADDRESS"
330	& #12,"---- -------- ------------------- -------------------------------"
500	!***** PRINT THE LIST *****
540	K%=M%(3%) ! FIRST POINTER
550		FOR J%=1% TO M%(2%)
560		  IF S1%(K%,1%)=0% THEN 690% ! NOT IN ANY CLASSES
570		    IF I%=2% AND S%(K%)=0% THEN 690% ! ADDR NOT RECORDED
580		      IF I%=3% AND S%(K%)=1% THEN 690% ! ADDR RECORDED
600		& #12 USING "#### ######## ",K%,N(K%);
610		& #12,LEFT(S$(K%),20%);" ";M$(K%)
690		K%=L%(K%,1%)  ! NEXT POINTER
700		NEXT J%
32000	CLOSE 1,2,3,4,5,12
32500	END