5	! BULL- ADD CLASSES TO CLASS FILE
8 OPEN "**MASTER" AS FILE  3  : DIM# 3 ,M%(100)
10 OPEN "**CLINF" AS FILE  1  : DIM# 1 ,C$( 2222 )=128
12 OPEN "**TIME" AS FILE  7  : DIM# 7 ,T3%( 2222 )
15 OPEN "**SCLINF" AS FILE  2  : DIM# 2 ,C2$( 2222 )=16
25 OPEN "**STATUS" AS FILE  4  : DIM# 4 ,E9%( 2222 ,2)
26 OPEN "**EXTRA" AS FILE  6  : DIM# 6 ,E7%( 2222 )
30 OPEN "**ESTAT" AS FILE  5  : DIM# 5 ,E8%( 2222 ,2)
32 OPEN "**HOURS" AS FILE  9  : DIM# 9 ,H%( 2222 )
35 OPEN "**PRESTS" AS FILE  10  : DIM# 10 ,M3%( 2222 ,2)
37 DIM T$(10),Y3(10)
38	READ Y3(I) FOR I=1 TO 10
39	DATA 4,4,25,2,15,5,5,4,1,1
40	DEF FNA$(A$)
41 X=LEN(A$)
42 FNA$=MID(A$,1,X-2)
43 FNEND
80	!*******GET STARTED******
81 PRINT "DO YOU WANT TO ADD CLASSES OR MAKE CORRECTIONS"
82 INPUT " ENTER A TO ADD CLASSES OR C TO CORRECT CLASSES";R5$
84		IF R5$="C" THEN 10001
510	& "ENTER TITLE,NUM,DES,SEC,INSTR,ROOM,DAYS,TIME,NUM,SPECIAL"
600	E8%(0,0)=E8%(0,0)+1%
604	PRINT "ENTER NEXT CLASS-" : INPUT LINE L$
605 L1$=FNA$(L$): B$=","
607	IF L1$="END" THEN E8%(0,0)=E8%(0,0)-1% : GOTO 8999
609	I=E8%(0,0)
610	Z2=10 ! # OF FIELDS
611	X1=1  ! START OFF
615 FOR Z=1 TO 9
620	X2=INSTR(X1,L1$,B$)
625		IF X2=0 THEN PRINT "INVALID ENTRY---" : GOTO 604
630	T$(Z)=MID(L1$,X1,X2-X1)
632	IF Z=3 THEN GOSUB 2000	!HANDLE DESCRIPTION
633	IF Z=8 THEN GOSUB 3000	!HANDLE TIME
635	X3=X2-X1   ! LEN OF THE FIELD
640	X1=X2+1  ! START OF NEXT FIELD
645	IF Z=4 THEN IF Y3(4)>X3 THEN T$(4)=SPACE$(2-X3)+T$(4) : GOTO 660
650		IF Y3(Z)>X3 THEN T$(Z)=T$(Z)+SPACE$(Y3(Z)-X3)
660		NEXT Z
665	X3=LEN(L1$)-X1+1 : T$(10)=MID(L1$,X1,X3) ! CLASS STATUS
670	!*****SET ANY NUMBERS************
680	S$=T$(4) : X0=VAL(S$) : E9%(I,2)=X0 ! SEC #
690	 M1$=T$(9) : X0=VAL(M1$) : E8%(I,1)=X0 ! # OF STUDENTS
695	M3%(I,1)=X0 
700	M2$=T$(10) : X0=VAL(M2$) ! SPECIAL STATUS
710	IF E7%(I)=1 THEN E$=E$+SPACE$(32-LEN(E$))
720	IF T3%(I)=1 THEN E1$=E1$+SPACE$(16-LEN(E1$))
740	E9%(I,1)=X0
745	C$(I)=T$(1)+T$(2)+T$(4)+T$(5)+T$(3)+T$(6)+T$(8)+T$(7)
746	C$(I)=C$(I)+E$+E1$+SPACE$(16)  !ADD EXTRA DESCRIPTION AND TIME
750	C2$(I)=T$(1)+T$(2)+T$(4)+" "+T$(8)
760	H%(I)=INT(VAL(MID(C2$(I),8,1)))
770		IF R5$="C" THEN 10010
780	GOTO 600
2000	!***HANDLE DESCRIPTION****
2005	E$=SPACE$(32)
2010	L3=LEN(T$(3))
2020	IF L3<Y3(3) THEN RETURN
2030	L4=INSTR(1,T$(3),"/") ! SEARCH FOR BREAK POINT
2035	IF L4=0 THEN IF L3=Y3(3) THEN RETURN
2040		IF L4=0 THEN PRINT "INVALID DESCRIPTION":GO TO 2100
2050	E$=MID(T$(3),L4+1,LEN(T$(3))-L4) : E7%(I)=1
2060	T$(3)=MID(T$(3),1,L4-1)+SPACE$(25-L4+1)
2070	RETURN
2100	PRINT "REENTER DESCRIPTION";
2110	INPUT LINE T$(3) : T$(3)=LEFT(T$(3),LEN(T$(3))-2)
2120	GO TO 2000	!TRY AGAIN
3000	!****HANDLE TIME*****
3005	E1$=SPACE$(16)
3010	L3=LEN(T$(8))
3020	IF L3<Y3(8) THEN RETURN
3040	L4=INSTR(1,T$(8),"/")	!SEARCH FOR BREAK POINT
3045	IF L4=0 THEN IF L3=Y3(8) THEN RETURN
3050	IF L4=0 THEN PRINT "INVALID TIME" : GO TO 3100
3055	E1$=MID(T$(8),L4+1,LEN(T$(8))-L4) : T3%(I)=1
3060	T$(8)=MID(T$(8),1,L4-1)+SPACE$(4-L4+1)
3080	RETURN
3100	PRINT "RE-ENTER TIME";
3110	INPUT LINE T$(8) : T$(8)=LEFT(T$(8),LEN(T$(8))-2)
3120	GO TO 3000
8999 !*******************************
9000 !*******
9010	M%(1%)=E8%(0,0) ! SET NUMBER OF CLASSES
9999	CLOSE 1,2,3,4,5,6,7,8,9,10
10000	GOTO 10060
10001 ! THIS SECTION CORRECTS ERRORS
10005 PRINT " INPUT A 0 TO TERMINATE THE PROGRAM"
10010 INPUT "CLASS #";I1
10015 IF I1=0 THEN 10050
10020 PRINT "CLASS NOW READS:":PRINT
10025 PRINT " ";C$(I1)
10027 INPUT LINE L$
10028 IF MID(L$,1,2)="OK" THEN 10010
10029	I=I1 : L1$=FNA$(L$) : B$=","
10030	E7%(I)=0%   : T3%(I)=0%
10035 	GOTO 610
10050 GOTO 9000
10060 END