5   ! GRADER - GRADE RECORDING PROGRAM
100   !**************OPEN DISK FILES**************************
110   !   PRESENT FILES DESIGNED FOR 4000 STUDENTS  JAN 12, 1972
130 OPEN "**SCLINF" AS FILE  2  : DIM# 2 ,C1$( 2222 )=16
140 OPEN "**STINF" AS FILE  3  : DIM# 3 ,S$( 1111 )=32
150 OPEN "**CLASF" AS FILE  4  : DIM# 4 ,E%( 2222 ,64)
160 OPEN "**STUDF" AS FILE  5  : DIM# 5 ,L%( 1111 ,2),S%( 1111 ,10),N( 1111 )
170 OPEN "**OVERF" AS FILE  6  : DIM# 6 ,S0%( 33 ,5)
180 OPEN "**GRADES" AS FILE  10  : DIM# 10 ,G%( 1111 ,10),G0%( 33 ,5),C%( 2222 )
210 C$=SPACE$(64)
260 OPEN "**CLASSO" AS FILE  7  : DIM# 7 ,E0%( 44 ,64)
299   !*******************************************************
300	G1$="ABCDFPWWIHNE"
405	DIM Y%(240),X%(240),Z%(240)
1280 INPUT "ENTER CLASS# OR 0 TO STOP";I1%
1281 PRINT : PRINT
1285	IFI1%=0% GOTO 9000
1289	C$=C1$(I1%)
1290	PRINT C$
1295 	IF E%(I1%,2)=0% THEN PRINT "NO STUDENTS ENROLLED" :GOTO1280
1300	INPUT "IS THIS THE CORRECT CLASS";Z8$
1310 IF Z8$<>"YES" GOTO 1280
1311 PRINT : PRINT
1340 GOSUB 1500
1341		IF G$="GOOF" THEN 1280 ! CLASS MUST BE REDONE
1342	  IF C%(I1%)=1% THEN 1350 !ALL READY SET
1345	C%(I1%)=1%  !SET FLAG CLASS #I1 IS DONE
1346	C%(0)=C%(0)+1% ! ADD ONE TO CLASS COUNT
1350 GOTO 1280
1500	!
1505	!**SUBROUTINE TO PRINT ONE CLASS LIST
1510	!
1515	!HOW MANY OVERFLOWS DOES THIS CLASS HAVE
1520	IF E%(I1%,2)=E%(I1%,2)/60%*60% THEN 1530
1525	P%=E%(I1%,2)/60%  :GOTO 1535
1530	P%=E%(I1%,2)/60%-1%	!P% IS # OF CLASS OVERFLOWS
1535	!
1540	!BRING IN STDS TO SORT ARRAY
1545	!C1=STD#   C2=STD SORT #
1550	K%=E%(I1%,2)		!K% IS # OF STD IN CLASS
1551	D0%=K%  :K9%=0
1552	IF K%>240% THEN PRINT "CLASS IS TO LARGE";I1%,K% : RETURN
1555	IF P%>0% THEN D0%=60% : K9%=1%
1560		FOR B%=1% TO D0%
1565	C1%=E%(I1%,B%+4)  :C2%=L%(C1%,2)
1570	X%(B%)=C1%  :Y%(B%)=C2%
1575		NEXT B%
1576    IF K9%=0% THEN 1655
1580	J%=E%(I1%,4)
1590		FOR J1%=1% TO P%
1595	B1%=J1%*60%+1%
1600	IF K%>B1%+59% THEN B2%=B1%+59% ELSE B2%=K%
1610		FOR C6%=B1% TO B2%
1615		M1%=C6%-(60%*J1%)
1620		C1%=E0%(J%,M1%+4%) : C2%=L%(C1%,2)
1625		X%(C6%)=C1% : Y%(C6%)=C2%
1630		NEXT C6%
1635	J%=E0%(J%,4)
1640		NEXT J1%
1650	!
1655	!SORT STDS
1665		FOR I%=1% TO K%
1670	G2%=Y%(1) : G1%=1%
1675		FOR H%=2% TO K%
1680	IF Y%(H%)<G2% THEN G2%=Y%(H%)  :G1%=H%
1685		NEXT H%
1690	Z%(I%)=X%(G1%)  :Y%(G1%)=9999  !Z% HOLDS SORTED STDS
1695		NEXT I%
1700	!
1705	!STD SORTED -- EVERYTHING READY -- PRINT LIST
1710 IF K%=(K%/46%)*46% THEN B7%=K%/46% ELSE B7%=K%/46%+1%
1720 IF K%<=46% THEN B2%=K% ELSE B2%=46%
1726	B1%=1%
1730		FOR I%=1% TO B7%
1740 PRINT MID(C$,1,4);" ";MID(C$,5,4);" ";MID(C$,9,2);" ";MID(C$,11,20)
1750 PRINT "*******************************************************"
1752	PRINT :PRINT
1835		FOR I5%=B1% TO B2%
1840	Q%=Z%(I5%) : S9$=S$(Q%)
1842	PRINT MID(S9$,1,20); :INPUT G$ ! ENTER GRAE
1844 IF G$="BACK" THEN INPUT "***HOW MANY";I7% : I5%=I5%-I7%: GOTO 1840
1846	IF G$="GOOF" THEN RETURN   ! THEY MADE A MISTAKE STOP
1847  G2$=MID(G$,1,1) : X=LEN(G$)
1848 IF  X>1 AND MID(G$,2,1)<>"F" GOTO 1860
1849	IF G2$="S" THEN RETURN
1850	G1%=INSTR(1,G1$,G2$)
1855	  IF G1%<>0% THEN 1865%
1860 INPUT "INVALID GRADE RE-ENTER***";G$ : GOTO 1847
1865	IF X>1 THEN G1%=8 ! WF IS THE GRADE
1875	!FIND CLASS IN STD FILE
1880	R%=S%(Q%,1)/100%	!R% IS # OF COURSES
1881 K8%=8% : K2%=1
1885	IF R%<=8% THEN K8%=R% :K2%=0
1890		FOR W%=1% TO K8%
1895		H4%=S%(Q%,W%+2)/10% : H3%=S%(Q%,W%+2)-H4%*10%
1900		IF H4%=I1% THEN 1945
1905		NEXT W%
1910 	IF K2%=0% THEN 1936
1915	R1%=R%-8%  :J9%=S%(Q%,2)
1920		FOR W%=1% TO R1%
1925	H4%=S0%(J9%,W%+1)/10% : H3%=S0%(J9%,W%+1)-H4%*10%
1930 IF H4%=I1% THEN 1940
1935		NEXT W%
1936 PRINT "CLASS#";I1%;" NOT FOUND IN STUDENT REC#";Q%
1937 PRINT "MAKE NOTE" : GOTO 1960
1940	G0%(J9%,W%+1)=G1%
1942 GOTO 1960
1945	G%(Q%,W%)=G1%
1960		NEXT I5%
1965 J5$=MID(S$(Q%),32,1) : J6$=J1$
1970 IF K%<B2%+46% THEN B2%=K% ELSE B2%=B2%+46%
1975 B1%=B1%+46%
1980		NEXT I%
1981 X%(0)=X%(0)+1 ! ONE MORE CLASS
1982 PRINT "*****************************************************"
1985	RETURN
1990	!  SUBROUTINE TO BLANK BUFFER
2985 !
2995	RETURN
9000	!END
9002	PRINT C%(0);" CLASSES HAVE BEEN RECORDED"
9005	CLOSE 1,2,3,4,5,6,7,12
9006 CLOSE 10
9007 CLOSE 9
9015	END