5	! HONPRO- HONOR AND PROBATION LIST PRINTER
10 OPEN "**MASTER" AS FILE  1  : DIM# 1 ,M%(100)
20 OPEN "**STUDF" AS FILE  5  : DIM# 5 ,L%( 1111 ,2),S%( 1111 ,10),N( 1111 )
30 OPEN "**STINF" AS FILE  3  : DIM# 3 ,S$( 1111 )=32
40 OPEN "**GRADES" AS FILE  10  : DIM# 10 ,G%( 1111 ,10),G0%( 33 ,5),C%( 2222 )
50	F6$="\    \###\          \####\    \##.####"
70 OPEN "**OVERF" AS FILE  6  : DIM# 6 ,S0%( 33 ,5)
80 OPEN "**VISOR" AS FILE  9  : DIM# 9 ,A%( 1111 ),M7%( 1111 )
85 OPEN "**MAILER" AS FILE  8  : DIM# 8 ,M$( 1111 )=32
90 OPEN "**ADVISR" AS FILE  7  : DIM# 7 ,A$(300),M7$(200)=32
145	A$(0)=SPACE$(16)
150	PRINT "ENTER THE TITLE OF THE LIST"; : INPUT Z$
160	INPUT "ENTER THE OUTPUT DEVICE";Z1$
170		OPEN Z1$ AS FILE 12
180	PRINT "ENTER SEMESTER YEAR"; : INPUT A$
190	PRINT "ENTER MINIMUM HOURS REQUIRED,AVE TO CHECK FOR"; : INPUT Z1%,Z2%
200	PRINT "ENTER THE TYPE OF COMPARISION: 1-GREATER THAN OR EQUAL"
205	INPUT "2-LESS THAN ,3-LESS THAN OR EQUAL, 4-NO GRADE BELOW";T%
210	INPUT "DO YOU WANT ADDRESSES";B$
220		IF B$="YES" THEN T1%=1 ELSE T1%=0
230	DIM R%(10,2)
240		FOR I%=1 TO 10%
245		INPUT "ENTER RANGE OF CLASSIFICATIONS";R%(I%,1),R%(I%,2)
250			IF R%(I%,1)=0 THEN 260
255		NEXT I%
260	R1%=I%-1%   !# OF RANGES
300	PRINT #12,DATE$(0),TIME$(0)
305	PRINT #12 FOR I%=1% TO 4%
310	PRINT #12,TAB(20);Z$;"  ";A$
320	PRINT #12,TAB(20);"---------------------------"
330	PRINT #12 : PRINT#12
399	!*****START LOOKING THRU STUDENT FILE**********
400	J%=M%(3)  !POINTER TO THE FIRST STUDENT
410		FOR I%=1% TO M%(2)
420	GOSUB 5000 ! SUBROUTINE TO FIGURE AVE
430		J%=L%(J%,1) ! NEXT POINTER
440		IF J%=0% THEN 9000
450		NEXT I%
460	GOTO 9000 ! FINISHED GOT  CLOSE ROUTINE
5000	!*******SUBROUTINE TO PLAY WITH GRADES****************
5005	GOSUB 7000 ! CHECK CLASSIFICATION
5006		IF W1%=0% THEN RETURN !WRONG CLASSFIC.
5010	I2%=S%(J%,1)/100% : I1%=S%(J%,1)-I2%*100%
5015		IF I1%=0 THEN RETURN !NO CLASSES SO RETURN
5020	F%=0% !FLAG FOR ELIGIABLITY ON ROLLS
5030	H9=0  !ZERO HOURS COUNT
5035	H9%=0
5040	P9=0 !ZERO POINT COUNT
5130		FOR K%=1 TO I1% !LOOP THRU CLASSES
5140		IF K%<9% THEN 5200
5150	Q1%=S%(J%,2): C1%=S0%(Q1%,K%-7%)/10% ! OVERFLOW ST
5160	H1%=S0%(Q1%,K%+2%)-C1%*10% ! HOURS
5170		GOTO 5300  ! READY TO ADD HOURS AND GRADE SO BRANCH
5200	!NORMAL STUSENT RECORD
5210	C1%=S%(J%,K%+2%)/10% : H1%=S%(J%,K%+2%)-C1%*10%
5300	G9%=G%(J%,K%)   ! PICK UP THE GRADE
5302	IF G9%=0 OR G9%=6 THEN H9%=H9%+H1%
5305	IF G9%=0% THEN 5600  ! HELD GRADE BRANCH AROUND
5310		IF G9%>5% THEN 5600   ! NO COUNT
5320	H9=H9+H1%   	!ADD HOURS
5330	P9=P9+H1%*(5%-G9%) 	!ADD POINTS
5335	G8%=5%-G9%
5340	IF T%=4 THEN IF G8%<Z2% THEN RETURN ! GRADE TO LOW FOR TYPE 4
5600		NEXT K%
5610	!***DETERMINE IF HE IS A PRINTER
5620	IF H9+H9%<Z1% THEN RETURN
5640	A9=P9/H9   ! CALCULATE THE AVE
5645	IF T%=4 THEN 5800 ! TYPE 4 HAS MADE IT
5650	IF T%=1% AND A9>=Z2% THEN 5800 !TYPE 1 CHECK
5660	IF T%=2% AND A9<Z2%  THEN 5800 !TYPE 2 CHECK
5670	IF T%=3% AND A9<=Z2% THEN 5800 !TYPE 3 CHECK
5680	RETURN !****THIS WAS NOT A PRINTER
5800	PRINT #12,"........" : PRINT #12
5810	PRINT #12,LEFT(S$(J%),20);"   ADVISOR: ";A$(A%(J%));"  STUDENT#";N(J%)
5820	PRINT #12
5830	PRINT #12USING F6$,"HOURS:",H9,"   GRADE PTS:",P9,"  AVE:",A9
5840		IF T1%=0% THEN RETURN ! NO ADDRESS
5850	!***PRINT ADDRESS
5855 PRINT #12
5860	PRINT #12,"ADDRESS:",LEFT(M$(J%),15)
5865 PRINT #12," ",
5870	PRINT #12,MID(M$(J%),16,10);", ";MID(M$(J%),26,2);" ";MID(M$(J%),28,5)
5880	PRINT #12
6000	RETURN !**ALL THRU WITH THIS STUDENT***
7000	!****SUBROUTINE TO CHECK CLASSIFICATION
7010	W%=VAL(MID(S$(J%),30,1))
7020		W1%=0% !SET FOR NOT FOUND
7030			FOR W2%=1 TO R1%
7040		IF R%(W2%,1)<=W% AND R%(W2%,2)>=W% THEN W1%=1 : RETURN
7050			NEXT W2%
7055	!REACHING HERE MEANS NOT RIGHT CLASS
7060	RETURN
9000	! *****CLOSE ROUTINE
9010	CLOSE 1,5,3,10,12,11,6,9,8,7
9999	END