5	! NOSHOW- DELETE NONPAYERS FROM ENROLLMENT FILES
6	! WRITTEN NOV 20,1972 BY R . BRANTON
80	Q=0
90	INPUT "WILL YOU BE ENTERING STUDENT #'S";I$
95		IF I$="YES" THEN Q=1
100	INPUT "KEYBOARD# OR END";I$ : IF I$="END" THEN 9999
110	A%=VAL(I$)
120 OPEN "**STINF.KB"+NUM$(A%) AS FILE  1  : DIM# 1 ,S%(500,13),N(500),S$(500)=32
130 OPEN "**CLASF.KB"+NUM$(A%) AS FILE  2  : DIM# 2 ,C9%( 2222 )
190	PRINT "ENTER # OR 0 TO STOP"
200	!***** START WORK *****
210	INPUT N1 : IF N1=0 THEN 1000
220	IF Q=0 THEN 300 ! NOT A STUDENT #
230		FOR I%=1 TO S%(0,0)
240		IF N(I%)=N1 THEN N1=I% : GOTO 300 !HERE HE IS
250		NEXT I%
260	PRINT "ST#";N1;" IS NOT IN THIS TERMINAL FILE" : GOTO 190
300	!***** WORK ON HIM *****
310	PRINT "WORKING ON: ";S$(N1);" OK"; : INPUT T$
320		IF T$="NO" THEN 190
323	PRINT S%(N1,W);FOR W=1 TO 13 :PRINT "******"
325	!*** HOW MANY CLASSES
330	C%=S%(N1,1)-INT(S%(N1,1)/100)*100
400		FOR J%=1 TO C%
410	C1%=S%(N1,J%+2)/10%  ! CLASS #
420	C9%(C1%)=C9%(C1%)-1% ! -1 FROM CLASS COUNT
430		NEXT J%
440	S%(N1,J%)=0% FOR J%=0% TO 13%
445	N(N1)=0 ! ZERO STUDENT NUMBER
450	PRINT "WITHDRAWN"
460	GOTO 200
1000	CLOSE 1,2
1010	GOTO 100
9999	END