5	! TALLY2- PRINT ENROLLMENTS CHAINED FROM TALLY OR STAND ALONE
50	INPUT "HOW MANY PRINTOUTS DO YOU WANT";X9%
55		IF X9%=0 THEN STOP
90 OPEN "**MASTER" AS FILE  1  : DIM# 1 ,M%(100)
100 OPEN "**SCLINF" AS FILE  2  : DIM# 2 ,C$( 2222 )=16
110 OPEN "**PRESTS" AS FILE  10  : DIM# 10 ,E6%( 2222 ,2)
120 OPEN "**STATUS" AS FILE  7  : DIM# 7 ,E9%( 2222 ,2)
130 OPEN "**ESTAT" AS FILE  3  : DIM# 3 ,E8%( 2222 ,2)
140	OPEN "LP:" FOR OUTPUT AS FILE 12,RECORDSIZE 4000
200	!!*****START WORK********************
205		FOR X8%=1% TO X9%
210	N=E8%(0,0)	!***N=# OF CLASSES
250	E$=CHR$(13)+CHR$(10) ! INIT STRING WITH CR & LF
260	F$=CHR$(12)          ! INIT STRING WITH FORMFEED CHAR
270	X%=153% ! PRINT MAX RECORD--VARIES WITH BUFFERSIZE
600	!******TOTALS MADE-PRITN RESULTS********
610		FOR Y1%=1% TO 2%
620 FIELD #12,300 AS A$,26 AS B$(1),26 AS B$(2),26 AS B$(3),2 AS A4$,26 AS D$(1),26 AS D$(2),26 AS D$(3),2 AS A5$
625	N$=NUM$(E6%(0%,0%)+E6%(0%,1%)) ! # OF STUDENTS ENROLLED
626	!+++++++ PRINT HEADINGS ++++++++++++++++++++++++++++++++++
630		IF Y1%=1% THEN T$="OPEN CLASSES" ELSE T$="CLOSED CLASSES"
640	A7$="    COURSE       MAX PRES" ! HEADING STRING
650	A8$="    ------      ---- ----" ! UNDERLINE HEADING
660 RSET A$=F$+N$+" STUDENTS HAVE BEEN ENROLLED AS OF "+DATE$(0)+" "+TIME$(0)+E$+E$+SPACE$(30)+T$+E$+SPACE$(30)+"................."+E$+E$
670	LSET B$(I%)=A7$ FOR I%=1% TO 3%
675	LSET D$(I%)=A8$ FOR I%=1% TO 3%
680	LSET A4$=E$ : LSET A5$=E$
690	PUT #12,COUNT 460
700	C%=0%  ! SET BUFFER CLASS COUNT (VARIES: 1 TO X%)
710	C1%=0% ! SET COLUMN COUNT (VARIES : 1,2,3)
720	K%=M%(93%) ! FIRST CLASS
750		FOR K1%=1% TO M%(1%)
755	IF E8%(K%,1)=0% THEN 900 ! NO ROOM FOR STUDENTS --DROPPED
760		IF E9%(K%,1%)<5% THEN Y%=1% ELSE Y%=2% !1:OPEN 2:CLOSEED
770			IF Y%<>Y1% THEN 900 !IS HE THE RIGHT KIND?
780	!############ FOUND A PRINTER ###########
790	FIELD #12,C%*26% AS Z$,16 AS Q1$,4 AS Q2$,4 AS Q3$,2 AS Q4$
800	LSET Q1$=C$(K%) : RSET Q2$=NUM$(E8%(K%,1%)) : RSET Q3$=NUM$(E8%(K%,2%))
810	C1%=C1%+1% : C%=C%+1% ! INCREMENT COUNTS
820	IF C1%<3% THEN LSET Q4$="  " ELSE LSET Q4$=E$ !END OF LINE?
830		IF C1%=3% THEN C1%=0% ! RESET 3 COLUMN COUNT
840	IF C%=X% THEN GOSUB 2000 ! TIME TO PRINT THE BUFFER
900		K%=E9%(K%,2%) ! NEXT CLASS POINTER
905		NEXT K1%
910	GOSUB 2000 ! GOT PRINT LAST BUFFER
920	FIELD #12,4 AS Z$
1000		NEXT Y1%
1005		NEXT X8%
1010	GOTO 9000 ! ALL THRU GO HOME
2000	!____________________________________________
2001	!       PRINT SUBROUTINE
2002	!--------------------------------------------
2010	FIELD #12,26%*C% AS Z$,4 AS Q6$
2020	IF C1%=0% THEN RSET Q6$=CHR$(13) ELSE RSET Q6$=E$
2030	PUT #12,COUNT C%*26+4%
2040	C%=0% ! RESET RECORD COUNT
2050	RETURN
9000	!****CLOSE FILE S AND GO HOME
9010	CLOSE 1,2,3,7,10,12
9999	END