10 ! TERMAD- ADD TERMINAL ENROLLMENT TO FILES
12 OPEN "**STINF" AS FILE  8  : DIM# 8 ,S1$( 1111 )=32
13 OPEN "**VISOR" AS FILE  6  : DIM# 6 ,A1%( 1111 ),M7%( 1111 )
15 OPEN "**MASTER" AS FILE  1  : DIM# 1 ,M%(100)
16 OPEN "**STUDF" AS FILE  9  : DIM# 9 ,L%( 1111 ,2),S%( 1111 ,10),N1( 1111 )
18 OPEN "**OVERF" AS FILE  10  : DIM# 10 ,S0%( 33 ,5)
19 OPEN "**PRESTS" AS FILE  11  : DIM# 11 ,E6%( 2222 ,2)
20	INPUT "KEYBOARD#";I$
30		IF I$="END" THEN 200
35	A%=VAL(I$)  ! GET KEYBOARD #
40 OPEN "**STINF.KB"+NUM$(A%) AS FILE  5  : DIM# 5 ,S9%(500,13),N(500),S$(500)=32
50 OPEN "**CLASF.KB"+NUM$(A%) AS FILE  3  : DIM# 3 ,C9%( 2222 )
55	E6%(0,0)=E6%(0,0)+C9%(0)
56	E6%(I2,2)=E6%(I2,2)+C9%(I2) FOR I2=1 TO 1000
61	C9%(I)=0% FOR I=0 TO M%(99)
67	J%=M%(2) !# OF STUDENTS
70     FOR I= 1 TO S9%(0,0)
71	IF N(I)=0 AND S9%(I,1)=0 THEN 100 ! HE HAS BEEN BLANKED OUT
75	J%=J%+1 ! INCREMENT # OF STUDENTS
76	A1%(J%)=INT(S9%(I,0)/100) : M7%(J%)=S9%(I,0)-A1%(J%)*100
77	S%(J%,1)=S9%(I,1)
80	S%(J%,J+1)=S9%(I,J) FOR J=2 TO 9
81	IF S9%(I,1)-INT(S9%(I,1)/100%)*100%<=8% THEN 90
82	Z2%=M%(96) : M%(96)=M%(96)+1% : S%(J%,2)=Z2% : S0%(Z2%,1)=J%
84	S0%(Z2%,J)=S9%(I,J+8) FOR J=2 TO 5
90	S1$(J%)=S$(I) !MOVE NAME STRING
95	N1(J%)=N(I)  !STUDENT # IS MOVED HERE
100 	NEXT I
105  S9%(0,0)=0
110	CLOSE 3,5
115	& "STARTING DP#=";M%(2%)+1%;" ENDING DP#=";J%
120	M%(2)=J%   !RESET STUDENT COUNT
140	GO TO 20
200	INPUT "HAVE ALL THE TERMINAL FILES BEEN ADDED";A$
201	  IF A$="YES" THEN M%(94)=0% ! RESET COUNT OF TERMINALS
202	GOTO 250 ! REMOVE TO GET PRINTOUT
204	OPEN "LP:" AS FILE 12
205		FOR I=1 TO M%(2)
210	PRINT #12,"****";I;"***********************"
220	PRINT#12,N1(I);TAB(10);S1$(I)
230	PRINT#12, S%(I,J); FOR J=1 TO 10 :PRINT #12
240		NEXT  I
244	FOR I=1 TO M%(96)
245	PRINT #12,"***OVERF ";I
246	PRINT #12,S0%(I,J), FOR J=1 TO 5 : PRINT #12
247	NEXT I
250	CLOSE 1,8,9,10,11,6
9999			END