10	!TIMER - TIME PRINT OUT PROGRAM
20	!WRITTEN MARCH 21,1973       BY     BB
30 OPEN "**CLINF" AS FILE  1  : DIM# 1 ,C$( 2222 )=128
40 OPEN "**TIME" AS FILE  2  : DIM# 2 ,T3%( 2222 )
45 OPEN "LP:" AS FILE 12 RECORDSIZE 3000
50 OPEN "**CK" AS FILE  4  : DIM# 4 ,T%( 2222 ),C2$( 2222 )=4
55	R$=CHR$(10)+CHR$(13)
60 OPEN "**MASTER" AS FILE  5  : DIM# 5 ,M%(100)
70 INPUT"# OF CLASSES";C%
75	T%(I%)=0% FOR I%=0% TO M%(99)
80 C2$(I%)=MID(C$(I%),56,4)	FOR I%=1%TOC%
90 PRINT "ENTER TIME, 1-FOR PM, 0-OTHERWISE, PRINT TIME"
100 INPUT T$,F%,T1$
110		IF T$="END" THEN 1000
120 FIELD#12, 50 AS X$
130	LSET X$=CHR$(12)+"CLASSES STARTING AT "+T1$+R$+R$
135		IF T$="ARR" THEN LSET X$=CHR$(12)+"ARRANGED CLASSES"+R$+R$
140 PUT#12, COUNT 50
210	K%=1
220  T=LEN(T$)
300 		FOR I% = 1% TO C%
310	IF T%(I%)=1% THEN 490
315	IF T3%(I%)=1% AND F%=0% THEN IF MID(C$(I%),97,1)="P" THEN 490
320	  IF T$<>LEFT(C2$(I%),T) THEN 490
330 IF F% = 1% THEN  IF MID(C$(I%),97,1)<>"P" THEN 490
340   T%(I%)=1%
345 FIELD#12, 20*K% AS Z$, 5 AS E1$, 5 AS E2$, 3 AS E3$, 5 AS E4$, 2 AS E5$
346		IF K%=1% THEN RSET Z$=R$
350 LSET E1$=MID(C$(I%),1,4) : LSET E2$=MID(C$(I%),5,4)
370 LSET E3$=MID(C$(I%),9,2) : LSET E4$=MID(C$(I%),60,5)
390	LSET E5$=R$
400   K%=K%+1%
410	IF K%=150% THEN PUT #12,COUNT K%*20% : K%=1%
490		NEXT I%
495!**************************************************************
496!
497!
500	PUT #12,COUNT 20*K%
600   GOTO 100	!KRUNCH**KRUNCH**KRUNCH::::::::!!!!
610!
620!
630!*************************************************************
1000 FIELD#12, 50 AS P$, 2 AS Y$
1005 LSET P$=" " : LSET Y$=CHR$(12) : PUT #12,COUNT 52
1010 LSET Y$=CHR$(13)+CHR$(10)
1100	  FOR I% = 1% TO C%
1110   IF T%(I%) = 1% THEN 1200
1120 LSET P$=LEFT(C$(I%),10)+SPACE$(2)+MID(C$(I%),56,4)+MID(C$(I%),97,5)
1130  PUT#12, COUNT 52
1200	  NEXT I%
1300	CLOSE 1,2,4,5,12
9999	END