100	! ****************** WESDMP *******************
	! **  DISPLAY PROGRAM FOR WESS MODEL DATA    **
	! **  ARRAY; VARIABLES, D VECTOR, Q MATRIX   **
120	! **  20-DEC-74  J. WARDEN  WABASH COLLEGE   **
	! *********************************************
140 INPUT"MODEL FILE";O$
160 OPEN O$ AS FILE 1%
180 DIM #1%,X%(48),A9(1),A1$(5)=128,A2$(24,4)=128,D2(24,12),X2(24,384)
200 !       \-----ID RECORD ------/ \-----24 MODEL RECORDS-----------/
220 DIM X(24),Y(24)
240 U1$="#####  \"+SPACE$(62%)+"\"
260 U2$="       \"+SPACE$(62%)+"\"
280 U3$="### \          \  "
300 INPUT"OUTPUT DEVICE (<CR>=KB:)";O2$ : IF O2$="" THEN O2$="KB:"
320 OPEN O2$ FOR OUTPUT AS FILE 2%
340 PRINT #2%,"DUMP OF WESS MODEL FILE ";O$;" ON ";DATE$(0%);
	" AT ";TIME$(0%)
360 PRINT #2%
380 INPUT"PRINT ID RECORD (Y/N)";W$ : IF ASCII(W$)<>89% THEN 740
400 PRINT #2%,"IDENTIFICATION RECORD:"
420 PRINT #2%,"-------------- -------"+CHR$(10%)
440 PRINT #2%,"X% ARRAY" : PRINT #2%
460 FOR I%=1% TO 5%
480 FOR J%=1% TO 5%
500 K%=I%+(J%-1%)*5%
520 PRINT #2%,USING"## ####     ",K%,X%(K%);
540 NEXT J% : PRINT #2%
560 NEXT I%
580 PRINT #2% : PRINT #2%,"MODEL ## OF NEXT AVAILABLE MODEL:";A9(1)
600 PRINT #2%
620 PRINT #2%,"A1$ ARRAY" : PRINT #2%
640 FOR I%=1% TO 5%
660 PRINT #2%,USING U1$,I%,LEFT(A1$(I%),64%)
680 PRINT #2%,USING U2$,RIGHT(A1$(I%),65%)
700 PRINT #2%
720 NEXT I%
740 INPUT"MODEL WANTED (1-24)";M% : IF M%<1% OR M%>24% THEN 1320
760 PRINT #2%,CHR$(12%);
780 PRINT #2%,"MODEL";M% : PRINT #2%,"--------"+CHR$(10%)
800 PRINT #2%,"A2$ ARRAY" : PRINT #2%
820 FOR I%=1% TO 4%
840 IF A2$(M%,I%)=" " THEN 920
860 PRINT #2%,USING U1$,I%,LEFT(A2$(M%,I%),64%)
880 PRINT #2%,USING U2$,RIGHT(A2$(M%,I%),65%)
900 PRINT #2%
920 NEXT I%
940 IF D2(M%,12%)=0. THEN PRINT #2%,"MODEL";M%;
	"HAS BEEN INITIALIZED" : PRINT #2% : GO TO 740
960 PRINT #2% : PRINT #2%,"D2 ARRAY" : PRINT #2%
980 FOR I%=1% TO 2%
1000 FOR J%=0% TO 5% : K%=I%+J%*2%
1020 PRINT #2%,USING"##>####    ",K%,D2(M%,K%);
1040 NEXT J% : PRINT #2%
1060 NEXT I%
1080 PRINT #2% : PRINT #2%,"X2 ARRAY" : PRINT #2%
1100 L1%=D2(M%,11%) : L2%=D2(M%,12%) : L3%=(L1%-1%)*128%+L2%
1120 L%=L3%/4% : IF L%*4%<L3% THEN L%=L%+1%
1140 IF L%*4%<D2(M%,12%) THEN L%=L%+1%
1160 FOR I%=1% TO L%
1180 FOR J%=0% TO 3%
1200 K%=I%+J%*L%
1220 PRINT #2%,USING U3$,K%,NUM$(X2(M%,K%));
1240 NEXT J% : PRINT #2%
1260 NEXT I%
1280 PRINT #2%:PRINT #2%
1300 GO TO 740
1320 CLOSE 1%,2%
1340 END