!SLIST -- LIST SPLIT S1401 FILES.
!
!(A VARIATION ON "POVBLD.BAS"
!
! ASKS FOR NAME OF INPUT FILE. (GIVE IT "DEV:FILNAM.EXT")
!
!
! 12-NOV-74 --- E GIEGLER
!
2 PRINT "SLIST - LIST S1401 SPLIT FILES"
5 O$="LP:"
22	PRINT "INPUT FILE";:INPUT I$:
	OPEN I$ FOR INPUT AS FILE 1%
30 OPEN O$ FOR OUTPUT AS FILE 2%
40 B1%=BUFSIZ(1%) : B2%=BUFSIZ(2%)
50 I0%=B1% : O0%=0%		!SET FOR FORCED INPUT, NO OUTPUT
60 ON ERROR GOTO 900
!
! MAIN LOOP....
!
!	I0% IS NUMBER OF "USED" CHARS OF INPUT BUFFER
!	O0% IS NUMBER OF "USED" POSITIONS OF OUTPUT BUFFER
!
100	GOSUB 300 IF O0%=B2%	!OUTPUT IF FULL OUTPUT BUFFER
110	GOSUB 200 IF I0%=B1%	!INPUT IF EMPTY INPUT BUFFER
120	T%=(B1%-I0%):
	S%=(B2%-O0%):
	T%=S% IF S%<T%		! T%=MIN((B1%-I0%),(B2%-O0%))
130	FIELD #1, I0% AS B1$, T% AS B1$
140	FIELD #2, O0% AS B2$, T% AS B2$
150	LSET B2$=B1$		! THE TRANSFER !!!!!!!!!!!!!!
160	I0%=I0%+T%:
	O0%=O0%+T%
170	GOTO 100
!
! SUBROUTINES
!
200	GET #1: I0%=0%: RETURN	!INPUT
!
300	PUT #2: O0%=0%: RETURN	!OUTPUT
!
! ERRORS
!
900	ON ERROR GOTO 0 IF ERL<>200% OR ERR<>11%
902	PRINT "MORE INPUT (Y/N)";:INPUT A$:
	GOTO 910 UNLESS ASCII(A$)=ASCII("Y")
904	PRINT "INPUT FILE";:INPUT I$:
	OPEN I$ FOR INPUT AS FILE 1%: B1%=BUFSIZ(1%): RESUME 200
910	FIELD #2, O0% AS B2$, (B2%-O0%) AS B2$
920	LSET B2$=STRING$((B2%-O0%),0%)			!NULL FILL
930	GOSUB 300 : CLOSE 2%, 1%
940	PRINT "EOJ" : GOTO 32767
32767 END