10 &"            C R O S S  R E F E R E N C E R":&:&
20 !WRITTEN FOR CONNECTS/11 BY JEFF MOGUL!
30 DEFFNL%(A1$):P%=0%
40 P%=P%+1% WHILEINSTR(1%,N$,MID(A1$,P%,1%))
50 FNL%=VAL(LEFT(A1$,P%-1%))
60 FNEND
80 DIM C%(300%),C$(300%),C1%(300%)
90 N$="0123456789 "
100 ON ERROR GOTO 8000:&"FILE--";
110 INPUT LINE A$:N8%=INSTR(1%,A$,"/"):IF N8%=0% THEN
        O$="KB:" ELSE O$=RIGHT(A$,N8%+1%):A$=LEFT(A$,N8%-1%):
        GOTO 113
111 A$=LEFT(A$,LEN(A$)-2)
113 IF INSTR(1%,A$,":")=0% THEN A$="DK1:"+A$
116 IF INSTR(1%,A$,".")=0% THEN A$=A$+".BAS"
120 OPEN A$ FOR INPUT AS FILE 1
122 INPUT"SHOULD I CHECK FOR MISSING LINES (Y/N)";Y9$:Y9$=LEFT(Y9$,1)
125 &"PLEASE STAND BY"
130 INPUT LINE #1,A1$
131 IF INSTR(1%,A1$,CHR$(10%))<INSTR(1%,A1$,CHR$(13%)) THEN 140
135 GOTO 162
140 INPUT LINE #1, B1$
145 A1$=LEFT(A1$,LEN(A1$)-3%)+B1$:GOTO 131
159 DATAREM,!,DATA
160 DATA THEN,GOTO,GOSUB,RESUME,ELSE,ERL=,ERL<,ERL>,ERL<>,ERL<=,ERL>=
162 A%=INSTR(1,A1$," "):IF A% THEN A1$=LEFT(A1$,A%-1%)+RIGHT(A1$,A%+1%):GOTO 162
163 GOSUB 490
164 RESTORE
165 FOR X5%=1% TO 3%:READ A7$
170 A%=INSTR(1%,A1$,A7$):IF A% THEN A1$=LEFT(A1$,A%)
180 NEXT X5%
214 L=FNL%(A1$):IF Y9$="Y" THEN C1%(I3%)=L:I3%=I3%+1%
215 A9=11
216 A%=INSTR(1%,A1$,"ON"):IF A% THEN GOSUB 600
220 FOR A2=0 TO A9-1:READ A2$:A%=1%
230 A%=INSTR(A%,A1$,A2$):IF A%=0% THEN 280
240 P=A%+LEN(A2$):P=P+1 WHILEINSTR(1%,N$,MID(A1$,P,1%))
250 N=VAL(MID(A1$,A%+LEN(A2$),P-A%-LEN(A2$)))
255 IF N=0 THEN 285
260 FOR I2=0 TO I:IF C%(I2)=N THEN C$(I2)=C$(I2)+CHR$(9%)+NUM$(L):GOTO 285
270 NEXT I2:I=I+1:C%(I)=N:C$(I)=NUM$(L):GOTO 285
280 NEXT A2:GOTO 130
285 A%=A%+LEN(A2$):GOTO 230
289 OPEN O$ AS FILE 2
290 &#2:&#2:&#2,CHR$(14);"CROSS-REFERENCE OF ";A$,DATE$(0),TIME$(0):&#2:&#2:&#2:&#2
295 &#2,"LINE #","IS REFERENCED AT "
296 &#2,"======","================"
300 FOR M%=0% TO I:S%=0%
305 IF C%(S%)<0% THEN S%=S%+1%:GOTO305
310 FOR T%=0% TO I
320 IF C%(T%)<0% THEN 340
330 IF C%(T%)<C%(S%) THEN S%=T%
340 NEXT T%
345 IF C%(S%)<1% THEN 360
346 GOSUB 2000:&#2;C%(S%),
347 IF INSTR(30,C$(S%),CHR$(9%)) THEN 1000
350 &#2,C$(S%):&#2
360 C%(S%)=-1%:NEXT M%:&#2:&#2:&#2
370 IF Y9$<>"Y" OR Y8%=0 THEN 390
380 &#2;"** INDICATES LINE DOES NOT EXIST"
385 &#2:&#2:&#2
390 CLOSE1,2
400 GOTO 32767
490!
500 A%=INSTR(1%,A1$,"'"):A1%=INSTR(1%,A1$,'"'):IF A%+A1%=0% THEN RETURN
505 A7$="'"
510 IF A%=0% THEN A0%=A1%:A7$='"':GOTO 520
512 IF A1%=0% THEN A0%=A%:GOTO 520
514 IF A1%<A% THEN A0%=A1%:A7$='"':GOTO 520
516 A0%=A%
520 IF INSTR(1%+A0% , A1$,A7$)=0% THEN 550
530 A1$=LEFT(A1$,A0%-1%)+RIGHT(A1$,1%+INSTR(1%+A0%,A1$,A7$)):GOTO 490
550 A1$=LEFT(A1$,A0%-1%)
555 GOTO 490
600 A%=A%+2%:A8%=INSTR(A%,A1$,"GO"):IF A8%=0% THEN RETURN ELSE IF INSTR(A%,A1$,"ERROR")=0% THEN 602
601 IF INSTR(A%,A1$,"ERROR")<INSTR(A%,A1$,"GO") THEN 800
602 IF MID(A1$,A8%+2%,1%)="S" THEN A%=A8%+5% ELSE A%=A8%+4%
620 P=A%:P=P+1 WHILEINSTR(1%,N$,MID(A1$,P,1))
625 P5=P+1
630 IFMID(A1$,P,1%)="," THEN 640 ELSE 800
640 P=P+1:P=P+1 WHILEINSTR(1%,N$,MID(A1$,P,1%))
650 N=VAL(MID(A1$,P5,P-P5))
660 IF N=0 THEN 800
670 FOR I2=0 TO I:IF C%(I2)=N THEN C$(I2)=C$(I2)+CHR$(9%)+NUM$(L):GOTO 690
680 NEXT I2:I=I+1:C%(I)=N:C$(I)=NUM$(L)
690 GOTO 625
800 A%=INSTR(A%,A1$,"ON"):IF A%=0% THEN RETURNELSE600
1000 T1%=INSTR(30,C$(S%),CHR$(9%))
1010 &#2 LEFT(C$(S%),T1%-1%):&#2,,
1020 C$(S%)=RIGHT(C$(S%),T1%+1%)
1030 GOTO 347
2000 IF Y9$<>"Y" THEN RETURN  !ROUTINE FOR LINE-CHECKING!
2010IF C%(S%)=C1%(I6%) THEN RETURN
2020 IF C%(S%)<C1%(I6%) THEN &#2;"**";:Y8%=-1%:RETURN
2030 IF I6%=I3% THEN RETURN
2040 I6%=I6%+1%:GOTO 2010
8000 A1$=SYS(CHR$(0)):&:&:CLOSE 1,2
8010 IF ERL=130 AND ERR=11 THEN RESUME 289
8020 IF ERL=140 THEN RESUME 162
8040 S$=SYS(CHR$(6)+CHR$(9)+CHR$(ERR)):&MID(S$,3%,INSTR(3%,S$,CHR$(0%))-3%)
32767 END