1! Program GEN5A.BAS Version 1 June, 1976
This is the data generator for Unit 5A: Repeated Measures, Acoustic
2! Department of Psychology
Lawrence University
Appleton, Wisconsin, 54911
(414) 739-3681, Ext. 464
3! Copyright (C) 1975, 1976 by Francis Campos. General
permission to copy or modify, but not for profit, all or part of
this document or the software described herein is hereby
4! granted, provided that this copyright notice is given, and
reference is made to the fact that reproduction privileges were
granted by permission of Francis Campos, Lawrence University.
5! Although every effort has been made to insure the accuracy and
usefulness of this document and the software described herein,
neither the author(s), Lawrence University, nor its funding
6! sources make any warranty, expressed or implied, with respect to
the performance or features of same on equipment which Lawrence
neither owns nor controls.
7! This program is one of the twenty-one BASIC-PLUS programs and
eighteen virtual core files that comprise the CASANOVA
package for Computer ASsisted instruction in ANalysis Of
8! VAriance. The package is coded for use on a PDP 11/40, 45 or 70
computer operating under RSTS/E, V6A-02. Those who wish to adapt
the package to other systems and/or programming languages are
9! urged to consult the BASIC-PLUS Language Manual, published by the
Digital Equipment Corporation, Maynard, Massachusetts, 01754,
as well as the Instructor's Manual for CASANOVA, provided by Lawrence.
105 RANDOMIZE
110 &:INPUT"WHAT IS YOUR NAME";Z1$
115 Z1$=Z1$+".XDS"
120 OPEN Z1$ AS FILE 1
125 N=5:A=4
130 Q=11
135 DIM #1, A2(16),A2$(2)
140 DIM A(11),D(5,4),A1(4),N(5),S(5),T(4)
145 A2(0)=11: A2$(1)="5A"
150 A2$(0)=""
155 GOTO 500
160 A2(I)=A(I) FOR I=1 TO Q
165 CLOSE 1
170 CHAIN "INTXSM"
500 READ A1(J) FOR J=1 TO A
510 DATA .07,.06,.09,.2
520 FOR I=1 TO N:FOR J=1 TO A
530 X=0
540 FOR L=1 TO 72
550 IF RND>A1(J) THEN 560
555 X=X+1
560 NEXT L
570 D(I,J)=INT(X/72*100)
580 T=T+D(I,J)
590 T2=T2+D(I,J)^2
600 NEXT J:NEXT I
610 A(1)=T^2/N/A
620 A(2)=T2
630 A(3)=T2-A(1)
640 FOR I=1 TO N:FOR J=1 TO A
650 S(I)=S(I)+D(I,J)
660 T(J)=T(J)+D(I,J)
670 NEXT J:NEXT I
680 Y=Y+S(I)^2 FOR I=1 TO N
690 Z=Z+T(J)^2 FOR J=1 TO A
700 A(4)=Y/A
710 A(5)=A(4)-A(1)
720 A(6)=Z/N
730 A(7)=A(6)-A(1)
740 A(8)=A(3)-A(5)-A(7)
750 A(9)=(A(7)/(A-1))/(A(8)/(A-1)/(N-1))
760 A(10)=(A(5)/(N-1))/(A(8)/(A-1)/(N-1))
770 A(11)=1
780 &:&,,"TREATMENTS":&
790 &,"A1","A2","A3","A4"
800 FOR I=1 TO 5
810 &"SUBJECT";I,D(I,1),D(I,2),D(I,3),D(I,4)
820 NEXT I
9998 GOTO 160
9999 END