10 ! JOURNAL, LEDGER, BALANCE SHEET
11 GOTO 20
12!
   SUBROUTINE FOR REMOVING INFORMATION FROM COMMON CORE

13 V$=SYS(CHR$(7))
14 K%=CVT$%(LEFT(V$,2))
15 V$=RIGHT(V$,3): I%=INSTR(1%,V$,"/")
16 N$=LEFT(V$,I%-1%): V$=RIGHT(V$,I%+1%)
17 I%=INSTR(1%,V$,"/")
18 C1$=LEFT(V$,I%-1%): D1$=RIGHT(V$,I%+1%)
19 RETURN
20 DEF FNK$=NUM$(ASCII(RIGHT(SYS(CHR$(6)+CHR$(9)),2%))/2%)
29!
	ROUNDING AND PRINTING FUNCTION

30 DEF FNR$(X,N)
40 X9$=MID(NUM$(X/100),2%,LEN(NUM$(X/100))-2%)
45 IF INSTR(1,X9$,".") =0% THEN X9$=X9$+".00" 
	ELSE X9$=LEFT(X9$+"00",INSTR(1,X9$,".")+2%)
50 FNR$=SPACE$(N-LEN(X9$))+X9$
60 FNEND
69!
	HEADER INFORMATION

70 OPEN "$CHART" AS FILE 3
80 DIM B(40)
90 INPUT"NAME";N$
100 INPUT"COMPANY";C1$
110 &"DATE";:INPUT LINE D1$
120 V$=SYS(CHR$(8)+"ATG4"+CVT%$(140)+CVT%$(1%)+
	N$+"/"+C1$+"/"+D1$)
130 CHAIN "$RDCRD"
139!
	RETURN FROM RDCRD

140 GOSUB 13
219!
	GENERATE JOURNAL

220 V$=SYS(CHR$(8)+"ATG4"+CVT%$(250)+CVT%$(1%)+CVT%$(2%)+CVT%$(1%)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
230 &"JOURNAL IS BEING GENERATED"
240 CHAIN "$GENJE"
249!
	RETURN FROM GENJE

250 GOSUB 13
299!
	GENERATE LEDGER

300 V$=SYS(CHR$(8)+"ATG4"+CVT%$(330)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
310 &"LEDGER IS BEING GENERATED"
320 CHAIN "$LEDGR"
329!
	RETURN FROM LEDGR

330 GOSUB 13: N5%=K%
409!
	GENERATE BALANCE SHEET

410 OPEN"ENTRY."+FNK$AS FILE4:DIM#4,A(63,1)
420 DIM A2(80)
430 N1%=4%:N2%=2%
440 OPEN "BALSHT."+FNK$ FOR OUTPUT AS FILE 2%
450 &"BALANCE SHEET IS BEING GENERATED"
460 &#2,SPACE$(10);N$
470 &#2:&#2:&#2:&#2
480 &#2,SPACE$(25);C1$:&#2
490 &#2,SPACE$(31);"BALANCE SHEET":&#2
500 &#2,SPACE$(28);D1$
510 &#2:&#2:&#2
520 FOR I9%=1% TO N5%
530 L%=A(I9%,0%)
540 A2(L%)=A2(L%)+A(I9%,1%)
550 NEXT I9%:CLOSE4
560 &#2SPACE$(33);"ASSETS"
570 &#2,SPACE$(33);"------":&#2:&#2
580 M=1
590 FOR K9%=1% TO 25% STEP 2%
600 B(M)=A2(K9%)-A2(K9%+1%)
610 IF B(M)-.01>=0 THEN 630
620 IF B(M)+.01>0 THEN 690
630 K3%=(K9%+1%)/2%
640 OPEN "$CHART" AS FILE 3
650 INPUT #3,N1$ FOR I%=1% TO K3%
660 CLOSE 3
670 &#2 SPACE$(10);N1$;TAB(50);FNR$(B(M),12)
680 B1=B1+B(M)
690 M=M+1
700 NEXT K9%
710 &#2 SPACE$(51);"------------":&#2
720 &#2 SPACE$(10);"TOTAL ASSETS";SPACE$(27);"$";FNR$(B1,12):&#2
730 &#2 SPACE$(51);"------------"
740 &#2 SPACE$(51)"------------":&#2:&#2
750 &#2 SPACE$(25);"LIABILITIES AND CAPITAL"
760 &#2 SPACE$(25);:&#2"-";FOR I%=1% TO 23%:&#2:&#2
770 &#2 SPACE$(10);"LIABILITIES"
780 &#2 SPACE$(10);"-----------":&#2
790 FOR K9%=27% TO 31% STEP 2%
800 B(M)=A2(K9%+1%)-A2(K9%)
810 IF B(M)-.01>=0 THEN 830
820 IF B(M)+.01>0 THEN 890
830 K3%=(K9%+1%)/2%
840 OPEN "$CHART" AS FILE 3
850 INPUT#3,N1$ FOR I%=1% TO K3%
860 CLOSE 3
870 &#2 SPACE$(10);N1$;TAB(50);FNR$(B(M),12)
880 B2=B2+B(M)
890 M=M+1
900 NEXT K9%
910 &#2,SPACE$(51);"------------":&#2
920 &#2SPACE$(10);"TOTAL LIABILITIES";SPACE$(23);FNR$(B2,12):&#2
930 &#2 SPACE$(10);"CAPITAL"
940 &#2 SPACE$(10);"-------":&#2
950 B(M)=A2(34)-A2(33)
960 IF B(M)-.01>=0 THEN 980
970 IF B(M)+.01>0 THEN 1040
980 OPEN "$CHART" AS FILE 3
990 INPUT#3,N1$ FOR I%=1% TO 17%
1000 CLOSE3
1010 &#2 SPACE$(10);N1$;TAB(50);FNR$(B(M),12)
1020 B2=B2+B(M)
1030 &#2 SPACE$(51);"------------":&#2
1040 &#2SPACE$(10);"TOTAL LIABILITIES AND CAPITAL";SPACE$(10);
     "$";FNR$(B2,12)
1050 &#2,SPACE$(51);"------------"
1060 &#2 SPACE$(51);"------------"
1070 IF B1=B2 THEN 1090
1080 &#2 SPACE$(10);"***** TOTALS DO NOT BALANCE":&#2:&#2
1090 FOR K9%=35% TO 80% STEP 2%
1100 M=M+1
1110 B(M)=A2(K9%+1%)-A2(K9%)
1120 NEXT K9%
1130 &#2 CHR$(26);
1140 &:&"OUTPUT FILE FOR KB: ";FNK$;" IS READY FOR DUMPING":&
1150CLOSE2:END