10 ! JOURNAL, LEDGER, TRIAL BALANCE, INCOME STATEMENT
20 DEF FNK$=NUM$(ASCII(RIGHT(SYS(CHR$(6)+CHR$(9)),2%))/2%)
29!
   ROUNDING AND PRINTING FUNCTION

30 DEF FNR$(X,N)
40 X9$=MID(NUM$(X/100),2%,LEN(NUM$(X/100))-2%)
45 IF INSTR(1,X9$,".")=0% THEN X9$=X9$+".00" ELSE
	X9$=LEFT(X9$+"00",INSTR(1,X9$,".")+2%)
50 FNR$=SPACE$(N-LEN(X9$))+X9$
60 FN END
69!
   CHAINING TO ATG5

70 OPEN "Z."+FNK$ FOR OUTPUT AS FILE 1:CLOSE 1
80 CHAIN"$ATG5"
89!
   RETURNING FROM ATG5

90 OPEN"SAVE."+FNK$AS FILE7: DIM#7,S(40)
100 V$=SYS(CHR$(7))
110 &"INCOME STATEMENT IS BEING GENERATED"
120 I%=INSTR(1%,V$,"/"):N$=LEFT(V$,I%-1%)
130 V$=RIGHT(V$,I%+1%):I%=INSTR(1%,V$,"/")
140 C1$=LEFT(V$,I%-1%):D1$=RIGHT(V$,I%+1%)
149!
    CREATING OF THE INCOME FILE

150 OPEN"INCOME."+FNK$ FOR OUTPUT AS FILE 2
160 &#2,CHR$(12);
170 &#2 SPACE$(10);N$:&#2FORI%=1%TO4%
180 &#2 TAB(16);C1$:&#2
190 &#2 TAB(20);"INCOME STATEMENT":&#2
200 &#2TAB(12)"FOR PERIOD ENDING ";D1$:&#2:&#2:&#2
210 &#2 TAB(5)"INCOME"
220 &#2 TAB(5)"------":&#2
230 &#2 TAB(10)"FEES INCOME";TAB(61);"$";FNR$(S(20),12):&#2:&#2
240 &#2 TAB(5)"EXPENSES"
250 &#2 TAB(5)"--------":&#2:&#2
260 &#2 TAB(49);"$";CHR$(13);
270 FOR J%=27% TO 37%
280 IF S(J%)=0% THEN 340
290 OPEN "$CHART" AS FILE 3: INPUT #3,N1$ FOR I9%=1% TO J%
300 CLOSE 3
310 S(J%)=-S(J%)
320 &#2 TAB(10);N1$;TAB(50);FNR$(S(J%),12)
330 T=T+S(J%)
340 NEXT J%
350 Z=S(20)-T
360 &#2 TAB(50)"------------"
370 &#2 TAB(10)"TOTAL EXPENSES";TAB(62);FNR$(T,12)
380 &#2 TAB(62);"------------":&#2
390 IF Z>=0 THEN 430
400 Z=ABS(Z)
410 &#2 TAB(5)"NET LOSS";TAB(61);"$";FNR$(Z,12)
420 GOTO 440
430 &#2 TAB(5)"NET INCOME";TAB(61);"$";FNR$(Z,12)
440 &#2 TAB(62)"------------"FORI9%=1%TO2%
450 CLOSE 2,7
455 KILL "SAVE."+FNK$
460 &:&"OUTPUT FILE FOR KB:";FNK$;"IS READY FOR DUMPING":&
470 END