1!
	TRANSACTION AND CLOSING JOURNALS.LEDGER,TRIAL BALANCE

5 DEF FNK$=NUM$(ASCII(RIGHT(SYS(CHR$(6)+CHR$(9)),2%))/2%)
90!
	HEADER INFORMATION

100 INPUT"NAME";N$
110 INPUT"COMPANY";C1$
120 &"DATE";:INPUTLINE D1$
125!
	CHAIN TO RDCRD FOR TRANSACTIONS

129 &:&"ENTER YOUR TRANSACTION ENTRIES":&
130 V$=SYS(CHR$(8)+"ATG7"+CVT%$(195)+CVT%$(1%)+N$+"/"+C1$+"/"+D1$)
140 CHAIN"$RDCRD"
155!
	SUBROUTINE TO EXTRACT INFO FROM COMMON CORE

160 V$=SYS(CHR$(7)):K%=CVT$%(LEFT(V$,2)):V$=RIGHT(V$,3)
170 I%=INSTR(1%,V$,"/")
180 N$=LEFT (V$,I%-1%): V$=RIGHT(V$,I%+1%)
190 I%=INSTR(1%,V$,"/"):C1$=LEFT(V$,I%-1%):D1$=RIGHT(V$,I%+1%)
192 RETURN
195 GOSUB 155
199!
	CHAIN TO RDCRD FOR CLOSING ENTRIES

200 V$=SYS(CHR$(8)+"ATG7"+CVT%$(212)+CVT%$(2%)+N$+"/"+C1$+"/"+D1$)
205 &:&"ENTER YOUR CLOSING ENTRIES":&
210 CHAIN"$RDCRD"20
212 GOSUB 155
215!
	CHAIN TO GENJE FOR JOURNAL OF TRANSACTIONS

220 OPEN "ENTRY." + FNK$ AS FILE 4:DIM#4,A(63,1)
225 N4%=A(61,0):CLOSE 4
230 V$=SYS(CHR$(8)+"ATG7"+CVT%$(260)+CVT%$(1%)+CVT%$(1%)+CVT%$(1%)+
    CVT%$(N4%)+N$+"/"+C1$+"/"+D1$)
249 &"JOURNAL IS BEING GENERATED"
250 CHAIN"$GENJE"
260 GOSUB 155:N4%=K%
300!
	CHAIN TO GENJE FOR JOURNAL OF CLOSING ENTRIES

305 OPEN "ENTRY." + FNK$ AS FILE 4:K%=A(62,0):CLOSE 4
310 V$=SYS(CHR$(8)+"ATG7"+CVT%$(330)+CVT%$(3%)+CVT%$(2%)+CVT%$(N4%+1%)+
    CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
319 &"CLOSING ENTRIES ARE BEING GENERATED"
320 CHAIN"$GENJE"
330 GOSUB 155
350!
	CHAIN TO LEDGR FOR LEDGER

360 V$=SYS(CHR$(8)+"ATG7"+CVT%$(380)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
369 &"LEDGER IS BEING GENERATED"
370 CHAIN"$LEDGR"
380 GOSUB 155
450!
	CHAIN TO TRBAL FOR TRIAL BALANCE

460 OPEN "ENTRY." + FNK$ AS FILE 4:N4%=A(61,0):CLOSE 4
470 V$=SYS(CHR$(8)+"ATG7"+CVT%$(490)+CVT%$(1%)+CVT%$(N4%)+N$+"/"+C1$+"/"+D1$)
479 &"TRIAL BALANCE IS BEING GENERATED"
480 CHAIN"$TRBAL"
490 V$=SYS(CHR$(7)):GOSUB 170
510!
	CHAIN TO TRBAL FOR POST-CLOSING TRIAL BALANCE

520 OPEN "ENTRY." + FNK$ AS FILE 4:K%=A(62,0):CLOSE 4
530 V$=SYS(CHR$(8)+"ATG7"+CVT%$(550)+CVT%$(2%)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
539 &"POST-CLOSING TRIAL BALANCE IS BEING GENERATED"
540 CHAIN "$TRBAL"4
550!
560 KILL"ENTRY." + FNK$
570 &:&"OUTPUT FILE FOR KB:";FNK$;"IS READY FOR DUMPING"
32767 END