1!
  JOURNALS OF TRANSACTIONS,ADJUSTMENTS,CLOSING ENTRIES --
	LEDGER AND POST-CLOSING TRIAL-BALANCE

5 DEF FNK$=NUM$(ASCII(RIGHT(SYS(CHR$(6)+CHR$(9)),2%))/2%)
10!
	HEADER INFORMATION

100 INPUT"NAME";N$
110 INPUT"COMPANY";C1$
120 &"DATE";:INPUT LINE D1$
125!
	CHAIN TO RDCRD FOR TRANSACTIONS

130 V$=SYS(CHR$(8)+"ATG9"+CVT%$(192)+CVT%$(1)+N$+"/"+C1$+"/"+D1$)
135 &:&"ENTER YOUR TRANSACTION ENTRIES":&
140 CHAIN"$RDCRD"
150!
	SUBROUTINE TO EXTRACT INFO FROM COMMON CORE

155 V$=SYS(CHR$(7))
160 K%=CVT$%(LEFT(V$,2)):V$=RIGHT(V$,3)
170 I%=INSTR(1%,V$,"/"):N$=LEFT(V$,I%-1%):V$=RIGHT(V$,I%+1%)
180 I%=INSTR(1%,V$,"/"):C1$=LEFT(V$,I%-1%):D1$=RIGHT(V$,I%+1%)
190 RETURN
192 GOSUB 155
195!
	CHAIN TO RDCRD FOR ADJUSTING ENTRIES

200 V$=SYS(CHR$(8)+"ATG9"+CVT%$(220)+CVT%$(2)+N$+"/"+C1$+"/"+D1$)
205 &:&"ENTER YOUR ADJUSTING ENTRIES":&
210 CHAIN"$RDCRD"20
220 GOSUB 155
290!
	CHAIN TO RDCRD FOR CLOSING ENTRIES

300 V$=SYS(CHR$(8)+"ATG9"+CVT%$(320)+CVT%$(3)+N$+"/"+C1$+"/"+D1$)
305 &:&"ENTER YOUR CLOSING ENTRIES":&
310 CHAIN"$RDCRD"20
320 GOSUB 155
410!
	CHAIN TO GENJE FOR JOURNAL OF TRANSACTIONS

420 OPEN "ENTRY." + FNK$ AS FILE4:DIM#4,A(63,1)
430 K1%=A(61,0):A(61,0)=K%:CLOSE 4
440V$=SYS(CHR$(8)+"ATG9"+CVT%$(460)+CVT%$(1%)+CVT%$(1%)+CVT%$(1%)+CVT%$(K1%)+N$+"/"+C1$+"/"+D1$)
445 &"JOURNAL OF TRANSACTIONS IS BEING GENERATED"
450CHAIN"$GENJE"
460 GOSUB 155:K1%=K%
490!
	CHAIN TO GENJE FOR JOURNAL OF ADJUSTING ENTRIES

500 OPEN "ENTRY." + FNK$ AS FILE 4
510 K2%=A(62,0):A(62,0)=K%
520 V$=SYS(CHR$(8)+"ATG9"+CVT%$(540)+CVT%$(2%)+CVT%$(1%)+CVT%$(K1%+1%)+CVT%$(K2%)+N$+"/"+C1$+"/"+D1$)
525 &"JOURNAL OF ADJUSTING ENTRIES IS BEING GENERATED"
530 CHAIN"$GENJE"
540 GOSUB 155 :K2%=K%
570!
	CHAIN TO GENJE FOR JOURNAL OF CLOSING ENTRIES

580 OPEN "ENTRY." + FNK$ AS FILE 4:K%=A(61,0):CLOSE 4
590 V$=SYS(CHR$(8)+"ATG9"+CVT%$(610)+CVT%$(3%)+CVT%$(2%)+CVT%$(K2%+1%)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
595 &"JOURNAL OF CLOSING ENTRIES IS BEING GENERATED"
600 CHAIN"$GENJE"
610 GOSUB 155
640!
	CHAIN TO LEDGR FOR LEDGER

650 V$=SYS(CHR$(8)+"ATG9"+CVT%$(670)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
655 &"LEDGER IS BEING GENERATED"
660 CHAIN"$LEDGR"
670 GOSUB 155
700!
	CHAIN TO TRBAL FOR POST-CLOSING TRIAL BALANCE

710 V$=SYS(CHR$(8)+"ATG9"+CVT%$(730)+CVT%$(2%)+CVT%$(K%)+N$+"/"+C1$+"/"+D1$)
719 &"POST-CLOSING TRIAL BALANCE IS BEING GENERATED"
720 CHAIN"$TRBAL"4
725 KILL "SAVE."+FNK$
730 KILL"ENTRY." + FNK$
740 &:&"OUTPUT FOR KB:";FNK$;"IS READY FOR DUMPING":&
750END