10 ! GENERAL JOURNAL ENTRY SUBROUTINE
20 DEF FNK$=NUM$(ASCII(RIGHT(SYS(CHR$(6)+CHR$(9)),2%))/2%)
30 OPEN"ENTRY."+FNK$AS FILE4:DIM#4,A1(63,1)
39!
	ROUNDING AND PRINTING FUNCTION

40 DEF FNR$(X,N)
50 X9$=MID(NUM$(X/100),2%,LEN(NUM$(X/100))-2%)
55 IF INSTR(1,X9$,".")=0% THEN X9$=X9$+".00" ELSE
	X9$=LEFT(X9$+"00",INSTR(1,X9$,".")+2%)
60 FNR$=SPACE$(N-LEN(X9$))+X9$
70 FNEND
79!
	GET FROM COMMON CORE

80 V$=SYS(CHR$(7))
90 C9$=LEFT(V$,4)
100 R9%=CVT$%(MID(V$,5,2))
110 K1%=CVT$%(MID(V$,7,2))
120 K2%=CVT$%(MID(V$,9,2))
130 N1%=CVT$%(MID(V$,11,2))
140 N2%=CVT$%(MID(V$,13,2))
150 V$=RIGHT(V$,15):I%=INSTR(1%,V$,"/"):N9$=LEFT(V$,I%-1%):
   V$=RIGHT(V$,I%+1%)
160 I%=INSTR(1%,V$,"/"):C1$=LEFT(V$,I%-1%):V$=RIGHT(V$,I%+1%)
170 D1$=V$
180 ONK1% GOTO 190,270,330
189!
	TRANSACTION JOURNAL

190OPEN"JRNLT."+FNK$ FOR OUTPUT AS FILE12%
200 &#12%,SPACE$(10%);N9$:&#12%FORI%=1%TO4%
210 &#12%,SPACE$(20%);C1$:&#12%
220 &#12%,SPACE$(16%);"JOURNAL OF FINANCIAL TRANSACTIONS":&#12%
230 &#12%,SPACE$(16%);"FOR PERIOD ENDED ";D1$:&#12%:&#12%
240 &#12%:&#12%
250 &#12%,SPACE$(9);"NAME OF ACCOUNT";SPACE$(25);"DEBIT";SPACE$(7);"CREDIT"
260 &#12%:GOTO 380
269!
	ADJUSTING ENTRY JOURNAL

270 OPEN"JRNLA."+FNK$ FOR OUTPUT AS FILE 12%
280 &#12% FOR I%=1%TO5%
290 &#12%,SPACE$(16);"ADJUSTING ENTRIES"
300 &#12%,SPACE$(16);"--------- -------"
310 &#12%
320 GOTO 380
329!
	CLOSING ENTRY JOURNAL

330 OPEN"JRNLC."+FNK$ FOR OUTPUT AS FILE 12%
340 &#12% FOR I%=1% TO 5%
350 &#12%,SPACE$(17);"CLOSING ENTRIES"
360 &#12%,SPACE$(17);"------- -------"
370 &#12%
379!
	GENERATE JOURNAL

380 FOR J%=N1% TO N2%
390 OPEN "$CHART" AS FILE 3
400 A%=A1(J%,0%)
410 K3%=(A%+1%)/2%
420 INPUT#3,N$ FOR I%=1% TO K3%:CLOSE3
430 A1=A1(J%,1%)
440 IF A%=A%/2%*2% THEN 480
450 &#12%, SPACE$(1);N$;TAB(44);FNR$(A1,10)
460 D=D+A1
470 GOTO 510
480 &#12%,SPACE$(4);N$;TAB(57);FNR$(A1,10)
490 C=C+A1
500 &#12%
510 NEXT J%
520 A1(0%,0%)=A1(0%,0%)+C
530 A1(0%,1%)=A1(0%,1%)+D
540 ON K2% GOTO 600,550
550 &#12% FOR I%=1% TO 3%
560 &#12%,"TOTALS FOR THIS DATE";SPACE$(24);FNR$(A1(0%,1%),10);SPACE$     (3);FNR$(A1(0%,0%),10)
570 IF C==D THEN 600
580 &#12% FOR I%=1% TO 4%
590 &"*** TOTAL DEBITS AND TOTAL CREDITS ARE NOT EQUAL ***":&#12%,"*** TOTAL DEBITS AND CREDITS ARE NOT EQUAL ***"
600 CLOSE4:V$=SYS(CHR$(8)+CVT%$(N2%)+N9$+"/"+C1$+"/"+D1$)
610 &#12% CHR$(26); : CLOSE 12%
620 CHAIN "$"+C9$R9%
630 END